Copy Table Script vs Get Script

shampton82

Hey everyone,

I would like to copy the data table script from a summary table that was made and paste the code for it back into a Parent level table so that for later analysis I can call up the table without having to have saved the actual table somewhere else.  Basically trying to streamline the user experience of having to save multiple tables files and then reopen a bunch of files to use the analysis later.

 

I was thinking it would be along these lines but this is not working.  dt1 would be the summary table and dt2 would be the parent table.

So this would copy the data table script of dt1 and then place it as a table script in dt2.

source_script = dt1 << Copy Table Script();

Eval(EvalExpr(
	dt2 << New Script("SourceFromSummary",
		Expr(Name Expr(source_script))
	);
));

Any advice would be greatly appreciated!

 

Steve

jthi

In that case, << Get Script should work for you

Names Default To Here(1);

dt = New Table("ABC",
	Add Rows(10),
	New Column("A", Set Each Value(1)),
	New Column("B", Set Each Value(1)),
);

tablescript = dt << get script;

Eval(EvalExpr(
	dt << New Script("Create Copy", Expr(NameExpr(tablescript)));
));

If you really really wish to use Copy Table Script() (not sure why you would in case like this) use Get Clipboard() with Parse()

Names Default To Here(1);

dt = New Table("ABC",
	Add Rows(10),
	New Column("A", Set Each Value(1)),
	New Column("B", Set Each Value(1)),
);

dt << Copy Table Script();

Eval(EvalExpr(
	dt << New Script("Create Copy", Expr(Parse(Get Clipboard())));
));