도면에서 X축의 수직 구분선은 일부만 나타낼 수 있나요?전문가 여러분, 감사합니다!
dt=Open("$SAMPLE_DATA/Big Class.jmp");
p1=dt<< Graph Builder(
Size( 534, 455 ),
Show Control Panel( 0 ),
Variables(
X( Transform Column( "Row", Formula( Row() ) ) ),
Y( :height ),
Y( :weight )
),
Elements( Position( 1, 1 ), Line( X, Y, Legend( 5 ) ) ),
Elements( Position( 1, 2 ), Bar( X, Y, Legend( 7 ) ) ),
SendToReport(
Dispatch(
{},
"Row",
ScaleBox,
{Add Ref Line( 10.5, "Dotted", "Dark Red", "", 1 ),
Add Ref Line( 20.5, "Dotted", "Dark Red", "", 1 ),
Add Ref Line( 30.5, "Dotted", "Dark Red", "", 1 )}
)
)
);
자동화 및 스크립팅윈도우Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?나는 사용할 것이다
<< 그래픽 스크립트 추가()
그리고 JMP 그래픽 프리미티브를 사용하여 필요한 선을 그립니다.
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?매우 감사합니다!스크립트로 구현하는 방법을 알고 싶습니다.나는 당신의 도움을 받고 싶습니다
짐, 고맙습니다!
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?어쩌면 더 나은 방법: 문제를 반대로 바꿔보세요.
선이 필요 없는 플롯에 커다란 흰색 사각형을 그린 후, 이 레이어를 선 위로 옮깁니다.
이렇게 하면 GUI를 통해 줄을 조정할 수 있는 유연성이 제공됩니다.
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?
Names Default To Here( 1 );
dt =
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );
// New column: Column 6
Data Table( "Big Class" ) << New Column( "Column 6",
Numeric,
"Continuous",
Format( "Best", 12 )
);
// Change column name: Column 6 → row
Data Table( "Big Class" ):Column 6 << Set Name( "row" );
// Change column formula: row
Data Table( "Big Class" ):row << Set Formula( Row() );
Graph Builder(
Size( 534, 456 ),
Show Control Panel( 0 ),
Variables( X( :row ), Y( :height ), Y( :weight ) ),
Elements(
Position( 1, 1 ),
Line( X, Y, Legend( 11 ) ),
Smoother( X, Y, Legend( 10 ) )
),
Elements( Position( 1, 2 ), Bar( X, Y, Legend( 5 ) ) ),
SendToReport(
Dispatch( {}, "Graph Builder", FrameBox( 2 ),
{Add Graphics Script(
2,
Description( "" ),
Pen Color( "red" ):line style( "dashed" );
Line( {11, 0}, {11, 160} );
)}
),
Dispatch( {}, "400", LegendBox,
{Legend Position( {11, [2], 10, [0], 5, [1]} )}
)
)
);
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?짐, 고맙습니다!
dt = Open("$SAMPLE_DATA/Big Class.jmp");ca="row";New Column(ca);Column(ca)<
<FORMULA></FORMULA>
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?
AI는 grok3만 사용합니다.
다른 AI를 사용하여 JSL을 완성하는 것은 사실상 시간 낭비입니다.
dt = Open("$SAMPLE_DATA/Big Class.jmp");ca="row";New Column(ca);Column(ca)<
<FORMULA></FORMULA>
<BR />
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?이런 경우에는 X/Y Origin() 및 X/Y Range()를 활용하는 것이 좋습니다.
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
dt << new column("R", Numeric, Continuous, Formula(Row()));
ar4 = [12.5, 22.5, 33.5];
gb = dt << Graph Builder(
Size(534, 456),
Show Control Panel(0),
Variables(X(:R), Y(:height), Y(:weight)),
Elements(Position(1, 1), Line(X, Y, Legend(11))),
Elements(Position(1, 2), Bar(X, Y, Legend(14)))
);
Eval(EvalExpr(
Report(gb)[FrameBox(2)] << Add Graphics Script(
For Each({v}, Expr(ar4),
Pen Color("red");
Line Style("dashed");
Line({v, Y Origin()}, {v, Y Origin() + Y Range()});
);
)
));
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?
가혹한 발언.
저는 이틀마다 새로운 획기적인 발견이 있고, 오래된 발견은 수정되어야 한다는 느낌을 받습니다.
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?코드를 실행하면 차트는 나타나지만 오류 메시지가 표시됩니다. 로그:
이름 미해결: 'For Each'에 대한 접근 또는 평가에서 For Each(
{다섯},
[12.5, 22.5, 33.5],
펜 색상( "빨간색" );
선 스타일( "대시" );
선( {v, Y 원점()}, {v, Y 원점() + Y 범위()} );
) /*###*/
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?어떤 버전의 JMP를 사용하고 계신가요? For each()는 JMP 16에서 처음 구현되었습니다.
다음은 JMP 15 및 이전 버전에서 작동하는 코드 버전입니다.
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << New Column( "R", Numeric, Continuous, Formula( Row() ) );
ar4 = [12.5, 22.5, 33.5];
gb = dt << Graph Builder(
Size( 534, 456 ),
Show Control Panel( 0 ),
Variables( X( :R ), Y( :height ), Y( :weight ) ),
Elements( Position( 1, 1 ), Line( X, Y, Legend( 11 ) ) ),
Elements( Position( 1, 2 ), Bar( X, Y, Legend( 14 ) ) )
);
Eval(
Eval Expr(
Report( gb )[FrameBox( 2 )] << Add Graphics Script(
For( i = 1, i <= N Items( ar4 ), i++,
v = ar4[i];
Pen Color( "red" );
Line Style( "dashed" );
Line( {v, Y Origin()}, {v, Y Origin() + Y Range()} );
)
)
)
);
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?V14.3은 너무 오래됐어요...
Re: 도면에서 X축의 수직 구분선은 일부만 표시할 수 있나요?JMP 14는 2018년 3월에 출시되었습니다. 네, 꽤 오래된 버전입니다. 하지만 제가 제공한 코드는 JMP 14에서 작동합니다.
