872785_ja-JP

liliconcom

図面のX軸の垂直分割線は、その一部だけを表示できますか?

専門家の皆様、ありがとうございます!

dt=Open("$SAMPLE_DATA/Big Class.jmp");
p1=dt<< Graph Builder(
	Size( 534, 455 ),
	Show Control Panel( 0 ),
	Variables(
		X( Transform Column( "Row", Formula( Row() ) ) ),
		Y( :height ),
		Y( :weight )
	),
	Elements( Position( 1, 1 ), Line( X, Y, Legend( 5 ) ) ),
	Elements( Position( 1, 2 ), Bar( X, Y, Legend( 7 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"Row",
			ScaleBox,
			{Add Ref Line( 10.5, "Dotted", "Dark Red", "", 1 ),
			Add Ref Line( 20.5, "Dotted", "Dark Red", "", 1 ),
			Add Ref Line( 30.5, "Dotted", "Dark Red", "", 1 )}
		)
	)
);

自動化とスクリプトウィンドウズRe: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

私は

<< グラフィックスクリプトを追加()

JMPのグラフィックプリミティブを使用して必要な線を描画します

Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

どうもありがとうございます！スクリプトで実装する方法を知りたいですか?あなたの助けをいただきたいです

ジム、ありがとう！

Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

もっと良い方法は、問題を逆転させることです。
線を描きたくないプロットに巨大な白い四角形を配置し、このレイヤーを線の上に移動します。

これにより、GUI を介して線を柔軟に調整できるようになります。

Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

Names Default To Here( 1 );
dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );
// New column: Column 6
Data Table( "Big Class" ) << New Column( "Column 6",
	Numeric,
	"Continuous",
	Format( "Best", 12 )
);


// Change column name: Column 6 → row
Data Table( "Big Class" ):Column 6 << Set Name( "row" );


// Change column formula: row
Data Table( "Big Class" ):row << Set Formula( Row() );
Graph Builder(
	Size( 534, 456 ),
	Show Control Panel( 0 ),
	Variables( X( :row ), Y( :height ), Y( :weight ) ),
	Elements(
		Position( 1, 1 ),
		Line( X, Y, Legend( 11 ) ),
		Smoother( X, Y, Legend( 10 ) )
	),
	Elements( Position( 1, 2 ), Bar( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch( {}, "Graph Builder", FrameBox( 2 ),
			{Add Graphics Script(
				2,
				Description( "" ),
				Pen Color( "red" ):line style( "dashed" );
				Line( {11, 0}, {11, 160} );
			)}
		),
		Dispatch( {}, "400", LegendBox,
			{Legend Position( {11, [2], 10, [0], 5, [1]} )}
		)
	)
);

Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

ジム、ありがとう！

dt = Open("$SAMPLE_DATA/Big Class.jmp");ca="row";New Column(ca);Column(ca)<
     <FORMULA></FORMULA>

Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

AI 私はgrok3のみを使用します、
他のAIを使用してJSLを完成させるのは、基本的に時間の無駄です。

dt = Open("$SAMPLE_DATA/Big Class.jmp");ca="row";New Column(ca);Column(ca)<
     <FORMULA></FORMULA>

<BR /> Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

このような場合には、X/Y Origin()とX/Y Range()を利用することをお勧めします。

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << new column("R", Numeric, Continuous, Formula(Row()));

ar4 = [12.5, 22.5, 33.5];

gb = dt << Graph Builder(
	Size(534, 456),
	Show Control Panel(0),
	Variables(X(:R), Y(:height), Y(:weight)),
	Elements(Position(1, 1), Line(X, Y, Legend(11))),
	Elements(Position(1, 2), Bar(X, Y, Legend(14)))
);

Eval(EvalExpr(
	Report(gb)[FrameBox(2)] << Add Graphics Script(
		For Each({v}, Expr(ar4),
			Pen Color("red");
			Line Style("dashed");
			Line({v, Y Origin()}, {v, Y Origin() + Y Range()});
		);
	)
));

Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

厳しい発言。

一日おきに新たな進歩があり、古い発見を修正しなければならないと感じています。

Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

コードを実行するとチャートは表示されますが、エラーメッセージが表示されます。ログ:

名前が解決されていません: 'For Each' のアクセスまたは評価における For Each、For Each(
{動詞},
[12.5、22.5、33.5],
ペンの色( "赤" );
線のスタイル( "破線" );
線( {v, Y原点()}, {v, Y原点() + Y範囲()} );
） /*###*/

Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

使用しているJMPのバージョンは何ですか？For each()はJMP 16で初めて実装されました。

JMP 15以前で動作するコードのバージョンは次のとおりです。

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dt << New Column( "R", Numeric, Continuous, Formula( Row() ) );

ar4 = [12.5, 22.5, 33.5];

gb = dt << Graph Builder(
	Size( 534, 456 ),
	Show Control Panel( 0 ),
	Variables( X( :R ), Y( :height ), Y( :weight ) ),
	Elements( Position( 1, 1 ), Line( X, Y, Legend( 11 ) ) ),
	Elements( Position( 1, 2 ), Bar( X, Y, Legend( 14 ) ) )
);

Eval(
	Eval Expr(
		Report( gb )[FrameBox( 2 )] << Add Graphics Script(
			For( i = 1, i <= N Items( ar4 ), i++,
				v = ar4[i];
				Pen Color( "red" );
				Line Style( "dashed" );
				Line( {v, Y Origin()}, {v, Y Origin() + Y Range()} );
			)
		)
	)
);

Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

V14.3、古すぎます…

Re: 図面のX軸の垂直分割線は、その一部だけを表示できますか?

JMP 14は2018年3月にリリースされました。確かにかなり古いバージョンですが、私が提供したコードはJMP 14でも動作します。