La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en montrer qu'une partie ?Merci les experts !
dt=Open("$SAMPLE_DATA/Big Class.jmp");
p1=dt<< Graph Builder(
Size( 534, 455 ),
Show Control Panel( 0 ),
Variables(
X( Transform Column( "Row", Formula( Row() ) ) ),
Y( :height ),
Y( :weight )
),
Elements( Position( 1, 1 ), Line( X, Y, Legend( 5 ) ) ),
Elements( Position( 1, 2 ), Bar( X, Y, Legend( 7 ) ) ),
SendToReport(
Dispatch(
{},
"Row",
ScaleBox,
{Add Ref Line( 10.5, "Dotted", "Dark Red", "", 1 ),
Add Ref Line( 20.5, "Dotted", "Dark Red", "", 1 ),
Add Ref Line( 30.5, "Dotted", "Dark Red", "", 1 )}
)
)
);
Automatisation et scriptsWindowsRe : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?J'utiliserais
<< Ajouter un script graphique()
et utilisez les primitives graphiques JMP pour dessiner les lignes dont vous avez besoin
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?Merci beaucoup!Je voudrais savoir comment l'implémenter avec un script ?J'aimerais recevoir votre aide
Merci Jim !
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?Peut-être mieux : inverser le problème :
placez un énorme rectangle blanc dans les parcelles où vous ne voulez PAS les lignes - et déplacez ce calque au-dessus des lignes.
Cela vous donne la flexibilité d'ajuster les lignes via l'interface graphique.
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?
Names Default To Here( 1 );
dt =
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );
// New column: Column 6
Data Table( "Big Class" ) << New Column( "Column 6",
Numeric,
"Continuous",
Format( "Best", 12 )
);
// Change column name: Column 6 → row
Data Table( "Big Class" ):Column 6 << Set Name( "row" );
// Change column formula: row
Data Table( "Big Class" ):row << Set Formula( Row() );
Graph Builder(
Size( 534, 456 ),
Show Control Panel( 0 ),
Variables( X( :row ), Y( :height ), Y( :weight ) ),
Elements(
Position( 1, 1 ),
Line( X, Y, Legend( 11 ) ),
Smoother( X, Y, Legend( 10 ) )
),
Elements( Position( 1, 2 ), Bar( X, Y, Legend( 5 ) ) ),
SendToReport(
Dispatch( {}, "Graph Builder", FrameBox( 2 ),
{Add Graphics Script(
2,
Description( "" ),
Pen Color( "red" ):line style( "dashed" );
Line( {11, 0}, {11, 160} );
)}
),
Dispatch( {}, "400", LegendBox,
{Legend Position( {11, [2], 10, [0], 5, [1]} )}
)
)
);
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?Merci Jim !
dt = Open("$SAMPLE_DATA/Big Class.jmp");ca="row";New Column(ca);Column(ca)<
<FORMULA></FORMULA>
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?
AI J'utilise uniquement grok3、
Utiliser d’autres AIS pour compléter JSL est fondamentalement une perte de temps.
dt = Open("$SAMPLE_DATA/Big Class.jmp");ca="row";New Column(ca);Column(ca)<
<FORMULA></FORMULA>
<BR />
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?Je suggérerais d'utiliser X/Y Origin() et X/Y Range() dans des cas comme celui-ci
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
dt << new column("R", Numeric, Continuous, Formula(Row()));
ar4 = [12.5, 22.5, 33.5];
gb = dt << Graph Builder(
Size(534, 456),
Show Control Panel(0),
Variables(X(:R), Y(:height), Y(:weight)),
Elements(Position(1, 1), Line(X, Y, Legend(11))),
Elements(Position(1, 2), Bar(X, Y, Legend(14)))
);
Eval(EvalExpr(
Report(gb)[FrameBox(2)] << Add Graphics Script(
For Each({v}, Expr(ar4),
Pen Color("red");
Line Style("dashed");
Line({v, Y Origin()}, {v, Y Origin() + Y Range()});
);
)
));
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?
déclaration dure.
J’ai le sentiment que chaque jour, une nouvelle avancée se produit et que les anciennes découvertes doivent être révisées.
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?Après l'exécution du code, le graphique apparaît, mais un message d'erreur s'affiche. Journal :
Nom non résolu : Pour chaque dans l'accès ou l'évaluation de « Pour chaque », Pour chaque(
{v},
[12,5, 22,5, 33,5],
Couleur du stylo( "rouge" );
Style de ligne( "pointillé" );
Ligne( {v, Origine Y()}, {v, Origine Y() + Plage Y()} );
) /*###*/
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?Quelle version de JMP utilisez-vous ? For each() a été implémenté pour la première fois dans JMP 16.
Voici une version du code qui fonctionnera pour JMP 15 et versions antérieures
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << New Column( "R", Numeric, Continuous, Formula( Row() ) );
ar4 = [12.5, 22.5, 33.5];
gb = dt << Graph Builder(
Size( 534, 456 ),
Show Control Panel( 0 ),
Variables( X( :R ), Y( :height ), Y( :weight ) ),
Elements( Position( 1, 1 ), Line( X, Y, Legend( 11 ) ) ),
Elements( Position( 1, 2 ), Bar( X, Y, Legend( 14 ) ) )
);
Eval(
Eval Expr(
Report( gb )[FrameBox( 2 )] << Add Graphics Script(
For( i = 1, i <= N Items( ar4 ), i++,
v = ar4[i];
Pen Color( "red" );
Line Style( "dashed" );
Line( {v, Y Origin()}, {v, Y Origin() + Y Range()} );
)
)
)
);
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?V14.3, c'est trop vieux...
Re : La ligne de séparation verticale de l'axe X dans le dessin peut-elle n'en afficher qu'une partie ?JMP 14 est sorti en mars 2018. Certes, il est assez ancien. Cependant, le code que j'ai fourni fonctionne sous JMP 14.
