실제 평균의 백분율로 나타낸 관리 차트 한계친애하는 커뮤니티 여러분,
저는 제약 업계에 종사하고 있으며 약전 지침 EP 2.9.5에 따라 관리도를 작성하고 싶습니다.
테스트는 다음과 같습니다.
- 중량 20정
- 2개 이상은 관찰된 평균에서 7.5% 이상 벗어나야 합니다.
- 관찰된 평균에서 15% 이상 벗어나서는 안 됩니다.
시그마를 기준으로 하는 대신 관리 차트에서 한계를 평균의 7.5%, 평균의 15%로 설정하는 방법이 있습니까?
대리모로서 데이터를 100%로 정규화하고 그래프 빌더에 고정 참조선을 추가할 수 있다는 것을 알고 있지만, 100%(목표)에서의 편차를 시각화하기 위해 원본 데이터를 정규화하지 않은 상태로 유지하고 싶습니다.
귀하의 지원에 감사드립니다.
온화한
데이터 탐색 및 시각화품질 및 공정 엔지니어링Re: 실제 평균의 백분율로 나타낸 관리도 한계예를 들어, 그래프 빌더에서 색상 평균 및 색상 표준 편차를 사용하여 그룹에 대한 통계를 계산하여 이러한 유형의 "그룹화된" 선을 작성할 수도 있습니다.
Re: 실제 평균의 백분율로 나타낸 관리도 한계평균에서 ±15%로 사양 한계를 설정하려면 다음 스크립트를 예로 들어 보겠습니다. 이렇게 하면 15%를 초과하는 지점을 쉽게 확인하고 보고할 수 있습니다.
// Based on txnelson's post from Nov 9, 2023.
// The usual frontmatter:
Open( "$SAMPLE_DATA/Quality Control/Diameter.jmp" );
Names Default To Here( 1 );
dt = Current Data Table();
// Change column property: DIAMETER
theMean = Col Mean(:DIAMETER);
Eval(
Substitute(
Expr(
dt:DIAMETER << set property(
"Spec Limits",
{LSL( _LSL_ ),
//Target( _Target_ ),
USL( _USL_ ),
Show Limits( 1 )}
)
),
Expr( _LSL_ ), 0.85*theMean,
//Expr( _Target_ ), theMean,
Expr( _USL_ ), 1.15*theMean
)
);
7.5%를 초과하는 지점과 15%를 초과하는 지점을 동시에 확인하는 것은 조금 더 까다롭습니다. 한 가지 방법은 7.5%를 프로세스의 알려진 "과거 시그마"로 설정하는 것입니다. 그런 다음 관리도구의 기본 제공 경고 함수를 사용하여 각각 1 시그마와 2 시그마를 초과하는 지점을 확인할 수 있습니다.
빨간색 삼각형 -> 시그마 설정 옵션을 사용하여 평균의 7.5%를 "과거" 시그마로 설정합니다. 그런 다음 그래프를 마우스 오른쪽 버튼으로 클릭하고 경고 -> 검정 사용자 지정을 선택한 후 검정 1을 변경하여 1시그마를 초과하는 지점을 확인할 수 있습니다(또는 아래 그림과 같이 이 단계를 스크립트로 작성).
그런 다음 KSigma를 2로 설정하면 이제 한계를 넘어서는 테스트가 15%를 넘는 포인트도 확인합니다.
이것은 일반적으로 통제 차트를 사용하는 방법은 아니지만, 필요한 작업을 처리하는 데에는 도움이 될 것입니다.
그렇게 하려면 위 스크립트에 다음을 추가하세요.
// Control chart builder with manually set historical sigma
Eval(
Substitute(
Expr(
Control Chart Builder(
Variables( Y( :DIAMETER ) ),
Set Sigma( _sigma_ ),
K Sigma( 2 ),
Customize Tests( Test 1( 1, "1" ) ),
Chart( Position( 1 ), Limits( Spec Limits( 1 ) ) )
);
),
Expr( _sigma_ ), 0.075*theMean,
)
);
Re: 실제 평균의 백분율로 나타낸 관리도 한계명확히 하자면, 당신이 하려는 것은 관리도가 아닙니다 . 관리도 한계값은 실제 공정 변동에서 독립적으로 도출되는 사양과는 아무런 관련이 없습니다. 사양을 마치 할당 가능하거나 특수 원인인 것처럼 반응하면 장기적으로 변동성이 커질 가능성이 높습니다(데밍과 슈하트 참조).
이는 사양에 맞춰 데이터를 표시할 수 없다는 뜻은 아니지만, 이것은 관리 차트가 아니며 이러한 한계에 대한 반응은 조심해야 합니다.
Re: 실제 평균의 백분율로 나타낸 관리도 한계저는 그래프 빌더에서 시도했고 그 정도까지는 갔습니다(통제 차트 플랫폼에서는 성공하지 못했습니다).
새로운 열 5개를 만들었습니다.
- 카테고리별 평균
- T2 음성 = :범주별 평균*0.85
- T2 pos = :범주별 평균*1.15
- T1 음성 = :범주별 평균*0.925
- T1 pos = :범주별 평균*1.075
그런 다음 다음 스크립트를 사용했습니다.
Graph Builder(
Spacing Borders( 1 ),
Variables(
Y( :Weight in % of target ),
Y( :T2 neg, Position( 1 ) ),
Y( :T2 pos, Position( 1 ) ),
//Y( :T1 neg, Position( 1 ) ),
//Y( :T1 pos, Position( 1 ) ),
Group X( :"Concatenate[Batch,Tray]"n )
),
Elements(
Points( Y( 1 ) ),
Line( Y( 2 ) ),
Line( Y( 3 ) ),
//Line(Y( 4 )),
//Line(Y( 5 ))
)
);
*참고: JSL은 txnelson에 의해 JSL Box로 이동되었습니다.
두 개의 라인만 활성화하면 잘 작동합니다.
하지만 4개의 줄을 활성화하면(스크립트에서 //를 제거하면) 이상한 그래프가 나타납니다.
어떤 생각 있으신가요?
Re: 실제 평균의 백분율로 나타낸 관리도 한계Y축에 여러 열이 있는 경우 JMP가 이를 수행할 수 있으므로 Y축이 함께 그룹화될 수 있습니다.
Graph Builder(
Size(788, 927),
Variables(
Y(:NPN1, Combine("Merged")),
Y(:neg1, Position(1), Combine("Merged")),
Y(:pos1, Position(1), Combine("Merged")),
Y(:neg2, Position(1), Combine("Merged")),
Y(:pos2, Position(1), Combine("Merged")),
Group X(:wafer)
),
Elements(Points(Y(1), Legend(40)), Line(Y(2), Y(3), Y(4), Y(5), Legend(41))),
SendToReport(
Dispatch({"Points"}, "", OutlineBox, {Close(0)}),
Dispatch({"Line"}, "", OutlineBox, {Close(0)})
)
);Re: 실제 평균의 백분율로 나타낸 관리도 한계완벽하네요. 답변해 주셔서 모두 감사합니다.
아주 잘 작동합니다.
좋은 하루 되세요.
온화한
