열에서 가장 자주 발생하는 항목을 계산합니다.JMP 열에서 행 개수를 기준으로 가장 자주 발생하는 항목을 쉽게 식별하고 싶습니다. 고유 항목은 쉽게 확인할 수 있는데, 이를 바탕으로 행 개수를 구하는 가장 좋은 방법은 무엇일까요?
dt = Current Data Table();
summarize( lotz = by(:LOT));
자동화 및 스크립팅Re: 열에서 가장 자주 발생하는 항목 계산이는 가장 빈번한 동점 가능성을 고려합니다.
Names Default To Here( 1 );
dt = Data Table( "Big Class" );
dt << Add Rows( {:name = "BARBARA", :age = 13, :sex = "F", :height = 100, :weight = 79} );
Summarize( namez = By( :name ) );
numberz = Transform Each( {v, i}, namez, Length( Where( dt, :name == v ) ) );
max_num = Max( numberz ); //2
big_name = namez[Where( numberz == max_num )]; //{"BARBARA", "ROBERT"}Re: 열에서 가장 자주 발생하는 항목 계산배포 플랫폼은 모드를 제공합니다.
요약 통계 단락의 빨간색 삼각형 아래에 있습니다.
요약 통계 사용자 정의
그런 다음 표시하려는 추가 통계를 선택합니다.
Re: 열에서 가장 자주 발생하는 항목 계산열 수식을 선호하는 경우:
Names Default to Here(1);
dt = Open( "$SAMPLE_DATA/Big Class Families.jmp" );
New Column( "N by age",
Formula( Col Number( 1, :age ) )
)
그리고 우승자를 확인하려면:
New Column( "max N by age",
Formula( Col Number( 1, :age ) == Col Max( Col Number( 1, :age ) ) )
)
또는 Summarize를 사용할 수 있습니다.
Summarize( namez = By( :age ), cnt = count(:age) );
또는 표/요약:
Data Table( "Big Class Families" ) << Summary(
Group( :age )
);
Re: 열에서 가장 자주 발생하는 항목 계산보기 좋은 스크립트지만 어떤 이유에서인지 모든 항목의 numberz가 5로 지정됩니다.
감사해요
Re: 열에서 가장 자주 발생하는 항목 계산요약 제안은 좋은 아이디어입니다. 두 개의 분리된 목록이 나오는데, 이 목록을 연관 배열로 만들 수 있다면 최대 "cnt" 값을 사용하여 연관된 "namez" 값을 식별할 수 있을 것 같습니다.
Re: 열에서 가장 자주 발생하는 항목 계산저는 이렇게 했고 효과가 있는 것 같습니다.
Summarize( namez = By( :LOT ), cnt = count(:LOT) );
keys = namez;
values = Eval List(cnt);
AA = Associative Array(keys, values);
For( g = 1, g <= N Items( AA ), g++,
If(values[g] == Max(cnt), mainLOT = keys[g]));Re: 열에서 가장 자주 발생하는 항목 계산요약 플랫폼은 일반적으로 이 작업에 사용합니다(사용 방법은 사용 사례에 따라 다름: 동점, 개수가 필요한지, 누락된 값을 어떻게 처리해야 하는지 등)
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
dt_summary = dt << Summary(
Group(:sex),
Freq("None"),
Weight("None"),
output table name("res"),
Private
);
// Using Loc Max
max_row = Loc Max(dt_summary[0, "N Rows"]);
max_val = dt_summary[max_row, 1];
show(max_val);
// Sorting
dt_summary << Sort(By(:N Rows), Replace Table, Order(Descending));
my_val = dt_summary[1, 1];
show(my_val);
Close(dt_summary, no save);
또한 모드 기능만 사용해도 충분할 수 있습니다.
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
val = Mode(dt[0, "sex"]);
그리고 (이미 이 스레드에서 볼 수 있듯이) 다른 옵션도 많이 있습니다.
Re: 열에서 가장 자주 발생하는 항목 계산자르모
훌륭해요! 이렇게 하면 효과가 있고 숫자가 아닌 값도 포함됩니다. 제가 원하는 건 누락된 데이터를 어떻게든 무시하도록 하는 것뿐입니다.
dt = Current Data Table();
val = Mode(dt[0, "process"]);
Re: 열에서 가장 자주 발생하는 항목 계산저는 이런 조정을 했고 성공적인 것 같습니다.
dt = Current Data Table();
full_proc_rows = dt << get rows where( !Is Missing( :process ) );
proc_val = Mode(dt[full_proc_rows, "process"]);
