869988_it-IT

liliconcom

Come posso creare uno switcher di colonna in una tabella dati unita finale da una variabile di elenco creata in una delle tabelle di origine?

Ho due fonti dati che vengono aggiornate regolarmente, creando nuove colonne. Queste vengono unite tramite script JSL, che funziona bene, ma vorrei incorporare un grafico con un selettore di colonne che si espande man mano che vengono aggiunte altre colonne.

Ad esempio, supponiamo che i dati HPLC provengano dallo strumento A e dallo strumento B. Ogni colonna rappresenta un campione separato, a cui vengono aggiunti altri campioni nel tempo. Vorrei creare un semplice grafico XY nella tabella dati finale per i miei campioni "A", in modo che, aggiungendo più colonne, aumenti anche il numero di colonne che cambiano. (Lo stesso vale per B e persino per C, se in seguito viene aggiunto un terzo strumento).

Ho creato una variabile dalla tabella A prima di unire i dati con B, ma come posso passare l'elenco (o valutarlo) in modo che la tabella finale riconosca la variabile o abbia nomi di colonna espliciti?

A_columns = dt_A <<GET column="" names=""></GET><BR />//Merge A and B based on time column<BR /><BR />Final_Table =dt_B << Update(<BR />With(dt_A)),<BR />Match Columns( :Time = :Time)<BR />);<BR />Final_Table <<NEW script=""></NEW>Graph Builder(<BR />Size( 546, 565 ),<BR />Show Control Panel( 0 ),<BR />Variables( X( :Time ), Y( A_columns[1] ) ),<BR />Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),<BR />Column Switcher( A_columns[1], A_columns)<BR />);

Questo metodo sembra funzionare bene quando ottengo un elenco di colonne dalla tabella finale, ma se provo a utilizzare una variabile creata da un'altra tabella, i problemi si presentano.

Automazione e scriptingEsplorazione e visualizzazione dei datiFinestreR: Come posso creare uno switcher di colonne in una tabella dati unita finale da una variabile elenco creata in una delle tabelle di origine?

Vuoi sempre utilizzare tutto tranne che per la prima colonna (:Time) nello switcher di colonna?

R: Come posso creare uno switcher di colonne in una tabella dati unita finale da una variabile elenco creata in una delle tabelle di origine?

In questo caso sì, sempre la prima colonna che avrà sempre lo stesso nome.

R: Come posso creare uno switcher di colonne in una tabella dati unita finale da una variabile elenco creata in una delle tabelle di origine?

In tal caso, prendo in considerazione la creazione dinamica dell'elenco delle colonne all'interno dello script della tabella

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

table_script_expr = Expr(
	cols = Current Data Table() << Get Column Names();
	Remove From(cols, 1); // drop first column
	gb = Graph Builder(
		Size(528, 448),
		Show Control Panel(0),
		Variables(X(:lot_id), Y(Eval(cols[1]))),
		Elements(Points(X, Y, Legend(3)))
	);
	gb << Column Switcher(
		cols[1],
		Remove(cols, 1)
	)
);

Eval(EvalExpr(
	dt << New Script("Graph",
		Expr(NameExpr(table_script_expr))
	);	
));

Puoi evitare la valutazione se crei semplicemente il grafico e lo salvi come script (uso questo "trucco" abbastanza spesso)

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

cols = dt << Get Column Names();
Remove From(cols, 1); // drop first column

gb = dt << Graph Builder(
	Size(528, 448),
	Show Control Panel(0),
	Variables(X(:lot_id), Y(Eval(cols[1]))),
	Elements(Points(X, Y, Legend(3))),
	Column Switcher(
		cols[1],
		Remove(cols, 1)
	),
	Invisible
);
gb << Save Script to Data Table("Graph"); // this will remove the need for evaluation 
wait(0);
gb << close window;

e se vuoi valutare

// If you wish to evaluate, this should work even though the script will look a bit weird due to lack of ":" in columns
// If it doesn't you for some reason, you will have to build the list in a bit different manner for evaluation
Eval(EvalExpr(
	dt << New Script("Graph2", 
		Graph Builder(
			Size(528, 448),
			Show Control Panel(0),
			Variables(X(:lot_id), Y(Expr(cols[1]))),
			Elements(Points(X, Y, Legend(3))),
			Column Switcher(
				Expr(cols[1]),
				Expr(Remove(cols, 1))
			)
		)
	)
));

R: Come posso creare uno switcher di colonne in una tabella dati unita finale da una variabile elenco creata in una delle tabelle di origine?

Grazie!