869988_de-DE

liliconcom

Wie kann ich aus einer in einer der Quelltabellen erstellten Listenvariablen einen Spaltenumschalter in einer endgültigen zusammengeführte Datentabelle erstellen?

Ich habe zwei Datenquellen, die regelmäßig aktualisiert werden, wodurch neue Spalten entstehen. Diese werden per JSL-Skript zusammengeführt, was gut funktioniert. Ich möchte jedoch ein Diagramm mit einem Spaltenumschalter einbetten, der mit dem Hinzufügen weiterer Spalten wächst.

Angenommen, die HPLC-Daten stammen von Instrument A und Instrument B. Jede Spalte stellt eine separate Probe dar, wobei im Laufe der Zeit weitere Proben hinzugefügt werden. Ich möchte in der finalen Datentabelle ein einfaches XY-Diagramm für meine „A“-Proben erstellen, sodass der Spaltenumschalter mit dem Hinzufügen weiterer Spalten ebenfalls wächst. (Ähnlich verhält es sich mit B und sogar C, wenn später ein drittes Instrument hinzugefügt wird.)

Ich habe eine Variable aus der Tabelle A erstellt, bevor ich die Daten mit B zusammenführe, aber wie kann ich die Liste übergeben (oder auswerten), damit die endgültige Tabelle die Variable erkennt oder explizite Spaltennamen hat?

A_columns = dt_A <<GET column="" names=""></GET><BR />//Merge A and B based on time column<BR /><BR />Final_Table =dt_B << Update(<BR />With(dt_A)),<BR />Match Columns( :Time = :Time)<BR />);<BR />Final_Table <<NEW script=""></NEW>Graph Builder(<BR />Size( 546, 565 ),<BR />Show Control Panel( 0 ),<BR />Variables( X( :Time ), Y( A_columns[1] ) ),<BR />Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) ),<BR />Column Switcher( A_columns[1], A_columns)<BR />);

Dies scheint gut zu funktionieren, wenn ich eine Liste von Spalten aus der endgültigen Tabelle erhalte, aber der Versuch, eine aus einer anderen Tabelle erstellte Variable zu verwenden, verursacht Probleme.

Automatisierung und SkriptingDatenexploration und -visualisierungWindowsBetreff: Wie kann ich aus einer in einer der Quelltabellen erstellten Listenvariablen einen Spaltenumschalter in einer endgültigen zusammengeführte Datentabelle erstellen?

Möchten Sie im Spaltenumschalter immer alle Werte außer der ersten Spalte (:Zeit) verwenden?

Betreff: Wie kann ich aus einer in einer der Quelltabellen erstellten Listenvariablen einen Spaltenumschalter in einer endgültigen zusammengeführte Datentabelle erstellen?

In diesem Fall ja – immer die erste Spalte, die immer denselben Namen hat.

Betreff: Wie kann ich aus einer in einer der Quelltabellen erstellten Listenvariablen einen Spaltenumschalter in einer endgültigen zusammengeführte Datentabelle erstellen?

In diesem Fall überlege ich, die Spaltenliste dynamisch innerhalb des Tabellenskripts zu erstellen.

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

table_script_expr = Expr(
	cols = Current Data Table() << Get Column Names();
	Remove From(cols, 1); // drop first column
	gb = Graph Builder(
		Size(528, 448),
		Show Control Panel(0),
		Variables(X(:lot_id), Y(Eval(cols[1]))),
		Elements(Points(X, Y, Legend(3)))
	);
	gb << Column Switcher(
		cols[1],
		Remove(cols, 1)
	)
);

Eval(EvalExpr(
	dt << New Script("Graph",
		Expr(NameExpr(table_script_expr))
	);	
));

Sie können die Auswertung vermeiden, indem Sie einfach das Diagramm erstellen und als Skript speichern (ich verwende diesen „Trick“ ziemlich oft).

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

cols = dt << Get Column Names();
Remove From(cols, 1); // drop first column

gb = dt << Graph Builder(
	Size(528, 448),
	Show Control Panel(0),
	Variables(X(:lot_id), Y(Eval(cols[1]))),
	Elements(Points(X, Y, Legend(3))),
	Column Switcher(
		cols[1],
		Remove(cols, 1)
	),
	Invisible
);
gb << Save Script to Data Table("Graph"); // this will remove the need for evaluation 
wait(0);
gb << close window;

und wenn Sie bewerten möchten

// If you wish to evaluate, this should work even though the script will look a bit weird due to lack of ":" in columns
// If it doesn't you for some reason, you will have to build the list in a bit different manner for evaluation
Eval(EvalExpr(
	dt << New Script("Graph2", 
		Graph Builder(
			Size(528, 448),
			Show Control Panel(0),
			Variables(X(:lot_id), Y(Expr(cols[1]))),
			Elements(Points(X, Y, Legend(3))),
			Column Switcher(
				Expr(cols[1]),
				Expr(Remove(cols, 1))
			)
		)
	)
));

Betreff: Wie kann ich aus einer in einer der Quelltabellen erstellten Listenvariablen einen Spaltenumschalter in einer endgültigen zusammengeführte Datentabelle erstellen?

Danke schön!