868673_ja-JP

liliconcom

データベーススクリプト

こんにちは、みんな、

分析を行えるように、データ テーブルの変更を自動化しようとしています。

データ テーブルに列Ref、% 、 % UPDATED があり、スクリプトから列 A、B、...、J を構築したいと思います。

列Aを指定します:

- 行参照A（行1）の再開：% UPDATED列のデータ

- 他の行の再開: % 列のデータ

初期データベースでは、Ref 列に約 100 個の異なる行があるため、100 個の新しい列を作成するために「If」式を直接使用しません。

データベースが添付されています。

助けてくれてありがとう。

自動化とスクリプトデータベーススクリプトについて

例えばテーブルを分割することができます

次に、%列に基づいて欠損値を入力し、最後に元のテーブルの値を更新します。この入力方法は複数ありますが、JSLとデータテーブルの添え字を使用する方法があります。

Names Default To Here(1);

dt = Datatable("BD");

dt_split = dt << Split(
	Split By(:Ref),
	Split(:"% UPDATED"n),
	Group(:Ref, :"%"n),
	Output Table("Split of BD by Ref"),
	Sort by Column Property,
	Invisible
);

cont_cols = dt_split << Get Column Names("String", "Continuous");
Remove From(cont_cols, 1); // drop %

perc_vals = dt_split[0, "%"];

For Each({cont_col}, cont_cols,
	perc_vals_current = perc_vals;
	non_missing = dt_split << Get Rows Where(!IsMissing(As Column(dt_split, cont_col)));
	perc_vals_current[non_missing] = dt_split[non_missing, cont_col];
	
	dt_split[0, cont_col] = perc_vals_current
);

dt << Update(
	With(dt_split),
	Match Columns(:Ref = :Ref),
	Replace Columns in Main Table(None)
);

Close(dt_split, no save);