867553_zh-TW

liliconcom

按組進行流程篩選

我想要自動化過程篩選，從而將所有分組變數都包含在過程變數中。

我得到的流程篩選的典型腳本如下所示

Process Screening(
	Process Variables(
		Column Group( "ENG" ),
		Column Group( "REJ" )
	),
	Grouping( :WAFER, :LOT ),
	Control Chart Type( "Indiv and MR" )
);

我可以建立可用群組的列表，但不知道如何將它們新增到流程篩選中。

Names Default To Here(1);
dt = Current Data Table();

Grps = dt << Get Column Groups Names;

ps = dt << Process Screening(
	Process Variables(Column Group( Expr(Grps) )),
	Grouping(:LOT, :WAFER),
	Control Chart Type("Indiv and MR"),
	Within Sigma(0),
	Overall Sigma(0),
	Stability Index(0),
	Mean(0),
	Show Tests(0),
	Test 1(0),
	Out of Spec Rate(0),
	Latest Out of Spec(0),
	Cpk(0),
	Ppk(0)
);

上面的腳本運行失敗，因為它需要遍歷清單中的每個項目。

自動化和腳本回覆：按組進行流程篩選

我嘗試了幾種方法，但不得不恢復到 Eval(Parse()) 方法......雖然醜陋，但有效

Names Default To Here( 1 );
dt = Current Data Table();

Grps = dt << Get Column Groups Names;
Eval(
	Parse(
		"ps = dt << Process Screening(
	Process Variables(Column Group( \!"" || Grps[1] ||
		"\!" )),
	Grouping(:LOT, :WAFER),
	Control Chart Type(\!"Indiv and MR\!"),
	Within Sigma(0),
	Overall Sigma(0),
	Stability Index(0),
	Mean(0),
	Show Tests(0),
	Test 1(0),
	Out of Spec Rate(0),
	Latest Out of Spec(0),
	Cpk(0),
	Ppk(0)
)"
	)
);

回覆：按組進行流程篩選

我看過更醜的，我有一面鏡子。效果很好。我的根本目標是僅選擇應用了規格的列，在我的情況下這意味著分組列。隨後，我從另一個方向來解決這個問題，結果也同樣有效。我比較喜歡你的方法。

Names Default To Here( 1 );
dt = Current Data Table();
colList = dt << get column names( numeric, string );
SpecCols = {};
For Each( {colnames, index}, colList,
	spec = Column( dt, colnames ) << get property( "Spec Limits" );
	If( !Is Empty( spec ),
		Insert Into( SpecCols, colnames )
	);
);
ps = dt << Process Screening(
	Process Variables( Eval( SpecCols ) ),
	Grouping( :WAFER, :LOT ),
	Control Chart Type( "Indiv and MR" ),
	Within Sigma( 0 ),
	Overall Sigma( 0 ),
	Stability Index( 0 ),
	Mean( 0 ),
	Show Tests( 0 ),
	Test 1( 0 ),
	Out of Spec Rate( 0 ),
	Latest Out of Spec( 0 ),
	Cpk( 0 ),
	Ppk( 0 )
);