866764_ja-JP

liliconcom

重複した列の値を取得するにはどうすればよいですか?

こんにちは、みんな、

列 A の値を取得し、それを列 B の重複値と一緒に配置するにはどうすればよいですか?

たとえば、これが私のデータです:

列A	列B
A	りんご
	りんご
B	バナナ
	マンゴー
C	マンゴー

予想される出力は次のとおりです。

列A	列B
A	りんご
A	りんご
B	バナナ
C	マンゴー
C	マンゴー

自動化とスクリプトウィンドウズRe: 重複した列の値を取得するにはどうすればいいですか?

ここに一つの解決策があります

Names Default To Here( 1 );

// Create the sample data table
dt = New Table( "Example",
	Add Rows( 5 ),
	New Column( "Column A",
		Character,
		"Nominal",
		Set Values( {"A", "", "B", "", "C"} )
	),
	New Column( "Column B",
		Character,
		"Nominal",
		Set Values( {"Apple", "Apple", "Banana", "Mango", "Mango"} )
	)
);

// Sort the table to allow non black Column A rows to be first
dt << Data Table( "Example" ) << Sort(
	By( :Column B, :Column A ),
	Order( Ascending, Descending ),
	Replace Table( 1 )
);

// Modify the Column A 
Hold = "";
For Each Row(
	If( :Column A != "",
		Hold = :Column A,
		Show( Lag( :column b ), :column b );
		If( Lag( :Column B ) == :Column B,
			:Column A = Hold
		);
	)
);

Re: 重複した列の値を取得するにはどうすればいいですか?

これは、表形式プラットフォームを使用する別のアプローチです。並べ替えは必要ありません。

dt = New Table( "Test", Add Rows( 5 ),
	New Column( "Column A", Character, "Nominal",
		Set Values( {"A", "", "B", "", "C"} ) ),
	New Column( "Column B", Character( 16 ), "Nominal",
		Set Values( {"Apple", "Apple", "Banana", "Mango", "Mango"} ) )
);
dtab = dt << Tabulate(
	Show Control Panel( 0 ), invisible,
	Add Table( Row Table( Grouping Columns( :Column A, :Column B ) ) )
);
dt2 = dtab << Make Into Data Table (invisible);
dtab << close window;
for (i = 1, i <= nrows(dt2), i++,
	one_key = dt2:Column B[i];
	one_value = dt2:Column A[i];

	rowset = dt << get rows where(dt:Column B == one_key & dt:Column A == "");
	dt:Column A[rowset] = one_value;
);
close(dt2, nosave);