866764_it-IT

liliconcom

Come ottenere il valore delle colonne duplicate?

Ciao a tutti,

Come posso ottenere il valore di una colonna A e posizionarlo insieme al valore duplicato nella colonna B?

Ad esempio, questi sono i miei dati:

Colonna A	Colonna B
A	Mela
	Mela
B	Banana
	Mango
C	Mango

Questo è il risultato previsto:

Colonna A	Colonna B
A	Mela
A	Mela
B	Banana
C	Mango
C	Mango

Automazione e scriptingFinestreR: Come ottenere il valore delle colonne duplicate?

Ecco una soluzione

Names Default To Here( 1 );

// Create the sample data table
dt = New Table( "Example",
	Add Rows( 5 ),
	New Column( "Column A",
		Character,
		"Nominal",
		Set Values( {"A", "", "B", "", "C"} )
	),
	New Column( "Column B",
		Character,
		"Nominal",
		Set Values( {"Apple", "Apple", "Banana", "Mango", "Mango"} )
	)
);

// Sort the table to allow non black Column A rows to be first
dt << Data Table( "Example" ) << Sort(
	By( :Column B, :Column A ),
	Order( Ascending, Descending ),
	Replace Table( 1 )
);

// Modify the Column A 
Hold = "";
For Each Row(
	If( :Column A != "",
		Hold = :Column A,
		Show( Lag( :column b ), :column b );
		If( Lag( :Column B ) == :Column B,
			:Column A = Hold
		);
	)
);

R: Come ottenere il valore delle colonne duplicate?

Ecco un altro approccio che usa la piattaforma tabulare . L'ordinamento non è richiesto.

dt = New Table( "Test", Add Rows( 5 ),
	New Column( "Column A", Character, "Nominal",
		Set Values( {"A", "", "B", "", "C"} ) ),
	New Column( "Column B", Character( 16 ), "Nominal",
		Set Values( {"Apple", "Apple", "Banana", "Mango", "Mango"} ) )
);
dtab = dt << Tabulate(
	Show Control Panel( 0 ), invisible,
	Add Table( Row Table( Grouping Columns( :Column A, :Column B ) ) )
);
dt2 = dtab << Make Into Data Table (invisible);
dtab << close window;
for (i = 1, i <= nrows(dt2), i++,
	one_key = dt2:Column B[i];
	one_value = dt2:Column A[i];

	rowset = dt << get rows where(dt:Column B == one_key & dt:Column A == "");
	dt:Column A[rowset] = one_value;
);
close(dt2, nosave);