How to get value of duplicate columns?

Question

Hi all,

How can I get the value of a Column A and place it with the duplicate value in Column B?

For example, this is my data:

Column AColumn BAApple AppleBBanana MangoCMango

This is the expected output:

Column AColumn BAAppleAAppleBBananaCMangoCMango

pmroz · Answer

Here's another approach that uses the tabulate platform.  Sorting is not requred.

dt = New Table( "Test", Add Rows( 5 ),
	New Column( "Column A", Character, "Nominal",
		Set Values( {"A", "", "B", "", "C"} ) ),
	New Column( "Column B", Character( 16 ), "Nominal",
		Set Values( {"Apple", "Apple", "Banana", "Mango", "Mango"} ) )
);
dtab = dt << Tabulate(
	Show Control Panel( 0 ), invisible,
	Add Table( Row Table( Grouping Columns( :Column A, :Column B ) ) )
);
dt2 = dtab << Make Into Data Table (invisible);
dtab << close window;
for (i = 1, i <= nrows(dt2), i++,
	one_key = dt2:Column B[i];
	one_value = dt2:Column A[i];

rowset = dt << get rows where(dt:Column B == one_key & dt:Column A == "");
	dt:Column A[rowset] = one_value;
);
close(dt2, nosave);

txnelson · Answer

If you sort your data where the non blank value of Column A is always first, and then select all Column A rows

You can right click on the value for row 1 for Column A and select

Here is a alternative JSL solution

Names Default To Here( 1 );

// Create the sample data table
dt = New Table( "Example",
	Add Rows( 5 ),
	New Column( "Column A",
		Character,
		"Nominal",
		Set Values( {"A", "", "B", "", "C"} )
	),
	New Column( "Column B",
		Character,
		"Nominal",
		Set Values( {"Apple", "Apple", "Banana", "Mango", "Mango"} )
	)
);

// Sort the table to allow non black Column A rows to be first
dt << Data Table( "Example" ) << Sort(
	By( :Column B, :Column A ),
	Order( Ascending, Descending ),
	Replace Table( 1 )
);

// Modify the Column A 
Hold = "";
For Each Row(
	If( :Column A != "",
		Hold = :Column A,
		Show( Lag( :column b ), :column b );
		If( Lag( :Column B ) == :Column B,
			:Column A = Hold
		);
	)
);