Graph builder won't autoscale

BL1

Hello,

I am launching a graph builder and data filter from a dashboard. The graph is date on the x axis and count on the y axis. When I filter the date, the data outside of the date range disappears from the graph, but the graph does not autoscale the x axis to match the dates within the filtered range (instead, the x axis date range is the same as before filtering the date range).

I know that I can open the data table, then go to column properties, then axis, then removed the min and max, and then it works, but I need the autoscaling to happen automatically. 

The graph builder script looks like this:

SPC = Open("C:\blahblahblah.csv",invisible);

column(SPC,"blah")<<data type(Numeric)<<Modeling Type(Continuous)<<Format(Best,1);
column(SPC,"blah2")<<data type(Numeric)<<Modeling Type(Continuous)<<Format(Best,1);

plot_box=vlistbox(

SPC << Graph Builder(
Size( 1372, 867 ),
Show Control Panel( 0 ),
Automatic Recalc( 1 ),
Auto Stretching( 0 ),
Variables( X( :Date time ran ), Y( :blah ), Y( :blah2 ), Overlay( :blah3 ) ),

Elements(
Position( 1, 1 ),
Points( X, Y, Legend( 1 ), Jitter( 1 ) ),
),
Elements(
Position( 1, 2 ),
Points( X, Y, Legend( 4 ), Jitter( 1 ) ),
),
SendToReport(
Dispatch(
{},
"Date time ran",
ScaleBox,
{Interval( "Day" ),
Inc( 3 ), Minor Ticks( 1 ),

(then a bunch of reference lines)

...

 

Could someone please advise me?

Thank you.

gzmorgan0

I see the same behavior on GraphBuilder.  I noticed the option Lock Scales on GraphBuilder. However, If I specify Lock Scales(0) when GraphBuilder is created the x-axis still does not rescale.  If after the GraphBuilder is created you turn on Lock Scales and turn it off, the axis will scale, but it will not have any custom axis formatting. The example below uses yyyyQq. The script below will run in JMP 12, 13 and 14.

 

If you have JMP 14, remove the /* in line 52 and run the script.  In JMP 14, there is Data Filter Handler, a script that runs when the filter is changed. So if you have a special axis format you can specify it in the handler.   

 

Lock Scales(0) in the GraphBuilder calling function doesn't seem to work as described. But enabling and disabling seems to work.

Names Default to Here(1);

dt = Open("$sample_data/Australian Tourism.jmp");

gb = dt << Graph Builder(
	Show Control Panel( 0 ),
	Show Legend( 0 ),
	Lock Scales(0),
	Variables(
		X( :Date ),
		Y( :Name( "Revenue ($'000)" ) ),
		Y( :Name( "Bed occupancy rate (%)" ) ),
		Y( :Name( "Average length of stay (days)" ) )
	),
	Elements(
		Position( 1, 1 ),
		Points( X, Y, Legend( 4 ) ),
		Smoother( X, Y, Legend( 3 ) )
	),
	Elements(
		Position( 1, 2 ),
		Points( X, Y, Legend( 1 ) ),
		Smoother( X, Y, Legend( 2 ) )
	),
	Elements(
		Position( 1, 3 ),
		Points( X, Y, Legend( 6 ) ),
		Smoother( X, Y, Legend( 5 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"Date",
			ScaleBox,
			{Format( "yyyyQq", 6 ), Min( 2953282344.82759 ), Max( 3408220800 ),
			Interval( "Year" ), Inc( 1 ), Minor Ticks( 0 )}
		),
		Dispatch( {}, "graph title", TextEditBox, {Set Text( "Tourism Trends" )} )
	)
);

filter = gb <<  Local Data Filter(
		Add Filter(
			columns( :Year )
		)
	);
	
  gb << Lock Scales(1);
  wait(0);
  gb << Lock Scales(0);
	
/*
f = function({a}, 
     print(a);
	  gb << Lock Scales(1);
	  wait(0);
	  gb << Lock Scales(0);
	  gb << Dispatch(
			{},
			"Date",
			ScaleBox,
			{Format( "yyyyQq", 6 ),
			Interval( "Year" ), Inc( 1 ), Minor Ticks( 0 )}
		); 
);

rs = filter << Make Filter Change Handler( f );