Loop with conditions

AlotaibiA

Hi

 

I have a dataset of students and I want to predict their allotment based on three conditions (Higher GPA, their five preferences, limited seating).  For example a person with a high GPA should be assigned to her 1st preferences till the seats are full then it should move to the next preferences.  

 

Year	Wish 1	Wish 2	Wish 3	Wish 4	Wish 5	GPA	Allotment
2016	Medicine	Pharmacy	Nursing	Dentistry	Physiotherapy	5
2016	Occupational Therapy	Pharmacy	Diagnostic Radiology	Epidemiology	Nursing	4.8
...etc

 

 

I have 12 programs and they have limited seating for each.

 

I looked into loop scripting but couldn't figure out how to include conditions in it.

Craige_Hales

something like this. Do a lot of testing before you mail out the assignments, this is bound to have some unhandled edge cases!

dtPrefs = New Table( "Preferences", 
	New Column( "Year", Set Values( [2016, 2016, 2016, 2016, 2016, 2016] ) ),
	New Column( "Wish 1",character, Set Values( {"Medicine", "Occupational Therapy", "Medicine", "Occupational Therapy", "Medicine", "Occupational Therapy"} )),
	New Column( "Wish 2",character, Set Values( {"Pharmacy", "Pharmacy", "Pharmacy", "Pharmacy", "Pharmacy", "Pharmacy"} ) ),
	New Column( "Wish 3",character, Set Values( {"Nursing", "Diagnostic Radiology", "Nursing", "Diagnostic Radiology", "Nursing", "Diagnostic Radiology"} ) ),
	New Column( "Wish 4",character, Set Values( {"Dentistry", "Epidemiology", "Dentistry", "Epidemiology", "Dentistry", "Epidemiology"} ) ),
	New Column( "Wish 5",character, Set Values( {"Physiotherapy", " Nursing", "Physiotherapy", " Nursing", "Physiotherapy", " Nursing"} ) ),
	New Column( "GPA", Set Values( [4, 4.8, 4.7, 4.6, 4.9, 4.3] ) ),
	New Column( "Allotment",character, Set Values( {"", "", "", "", "", ""} ) ),
	New Column( "ID", Format( "Best", 12 ), Set Values( [11, 12, 13, 14, 15, 16] ) )
);

dtSeats = New Table( "Seats Available",
	Add Rows( 8 ),
	New Column( "Program",character,Set Values({"Medicine", "Pharmacy", "Nursing", "Dentistry", "Physiotherapy", "Occupational Therapy", "Diagnostic Radiology", "Epidemiology"})	),
	New Column( "seats", Set Values( [1, 1, 1, 2, 2, 2, 2, 2] ) )
);

// sort the prefs, do the high GPAs first
dtPrefs << sort( by( GPA ), order( descending ), ReplaceTable );

// build a lookup table for the Program-to-Rownumber in the seats table
lookup = Associative Array();
For( iSeat = 1, iSeat <= N Rows( dtSeats ), iSeat += 1, 
	// use uppercase lookups, just in case 
	lookup[Uppercase( dtSeats:Program[iSeat] )] = iSeat
);

// assign the seats
For( iStudent = 1, iStudent <= N Rows( dtPrefs ), iStudent += 1, 
	// get the list of prefs for this student
	preflist = dtPrefs[iStudent, {Wish 1, Wish 2, Wish 3, Wish 4, Wish 5}];
	answer = "";
	While( answer == "" & N Items( preflist ) > 0,
		pref = Remove From( preflist, 1 );
		pref = pref[1]; // get first item from list of one item
		pref = Uppercase( pref );
		seatrow = Try( lookup[pref], -1 ); // handle unknown preference?
		If( dtSeats:seats[seatrow] > 0,
			dtPrefs:Allotment[iStudent] = answer = pref;
			dtSeats:seats[seatrow] -= 1;
		);
	);
);

Notes:

• the sort could use a second variable to break ties in GPAs. (Application date?)
• the -1 for the unknown pref is not handled
• there might be a better strategy involving more 2nd choices and fewer 3rd choices