863641_es-ES

liliconcom

JMP 18: Seleccionar todas las columnas a la derecha de una columna especificada

Se buscan seleccionar todas las columnas a la derecha de la columna "Sumadores". El código a continuación se ejecuta, pero no selecciona visiblemente las columnas a la derecha de "Sumadores". El número de columnas a la izquierda y a la derecha de "Sumadores" puede variar.

<JSL> Names Default To Here(1);

dt = Data Table("Test Table");
dt << Bring Window To Front;

Show(dt << Get Name);

// Step 1: Get all column names and show them
colNames = dt << Get Column Names();
Show(colNames);

// Step 2: Find the index of the "Adders" column
targetColName = "Adders";
colIndex = Loc(colNames, targetColName);
Show(colIndex); // Should be > 0 if found

// Step 3: Try to visually select all columns to the right
If(colIndex > 0 & colIndex < N Cols(dt),

dt << Clear Column Selection;

For(i = colIndex + 1, i <= N Cols(dt), i++,
Column(dt, i) << Set Selected(1);
);

// Step 4: Show what JMP thinks is selected
selected = dt << Get Selected Columns;
Show(selected);

,
New Window("Error", Text Box("Column 'Adders' not found, or it's the last column."));
);</JSL>

Producción:

dt << Get Name = "Test Table";
colNames = {A, B, Adders, X, Y};
colIndex = [];

Automatización y scriptingVentanasRe: JMP 18: Seleccionar todas las columnas a la derecha de una columna especificada

Haría dos cambios aquí. Debe especificar "string" en el mensaje "Obtener nombres de columna". Luego, debe cambiar la función Loc() a "Contains()". Loc() devuelve una matriz, a veces vacía. "Contains()" devuelve un entero (0 si no se encuentra).

Names Default To Here(1);

dt = Data Table("Test Table");
dt << Bring Window To Front;

Show(dt << Get Name);

// Step 1: Get all column names and show them
colNames = dt << Get Column Names( "string" );
Show(colNames);

// Step 2: Find the index of the "Adders" column
targetColName = "Adders";
colIndex = Contains(colNames, targetColName);
Show(colIndex); // Should be > 0 if found

// Step 3: Try to visually select all columns to the right
If(colIndex > 0 & colIndex < N Cols(dt),

dt << Clear Column Selection;

For(i = colIndex + 1, i <= N Cols(dt), i++,
Column(dt, i) << Set Selected(1);
);

// Step 4: Show what JMP thinks is selected
selected = dt << Get Selected Columns;
Show(selected);

,
New Window("Error", Text Box("Column 'Adders' not found, or it's the last column."));
);

 

//Output:

//dt << Get Name = "Test Table";
//colNames = {"A", "B", "Adders", "X", "Y"};
//colIndex = 3;<BR />//selected = {:X, :Y};

Re: JMP 18: Seleccionar todas las columnas a la derecha de una columna especificada

Estoy seguro de que hay otras formas de hacer esto, pero el siguiente script encontrará la columna "Adders", luego la seleccionará y todas las columnas a la derecha:

names default to here(1);
dt = current data table();

targetCol = "Adders";
targetColNum = 0;

for( i = 1, i <= n cols( dt ), i++, 
	if( column( dt,i ) << get name == targetCol, targetColNum = i )
);
dt << select columns( targetColNum::n cols(dt) )

Re: JMP 18: Seleccionar todas las columnas a la derecha de una columna especificada

Edité su publicación inicial y moví el JSL y su salida a una ventana JSL y una ventana de Código respectivamente, usando los íconos de entrada en la parte superior de la ventana de entrada de edición.

También modifiqué su código para que << obtenga nombres de columnas, devuelva cadenas y, en lugar de usar Loc(), use Contiene() para devolver un solo valor en lugar de un valor de matriz.

Names Default To Here(1);

dt = Data Table("Test Table");
dt << Bring Window To Front;

Show(dt << Get Name);

// Step 1: Get all column names and show them
colNames = dt << Get Column Names(string);
Show(colNames);

// Step 2: Find the index of the "Adders" column
targetColName = "Adders";
// Loc() returns a matrix, contains returns a scaler value
colIndex = contains(colNames, targetColName );
Show( colIndex ); // Should be > 0 if found

// Step 3: Try to visually select all columns to the right
If( colIndex > 0 & colIndex < N Cols( dt ), 

	dt << Clear Column Selection;

	For( i = colIndex + 1, i <= N Cols( dt ), i++,
		Column( dt, i ) << Set Selected( 1 )
	);

// Step 4: Show what JMP thinks is selected
	selected = dt << Get Selected Columns;
	Show( selected );

,
	New Window( "Error", Text Box( "Column 'Adders' not found, or it's the last column." ) )
);

Re: JMP 18: Seleccionar todas las columnas a la derecha de una columna especificada

Gracias por las correcciones.

Re: JMP 18: Seleccionar todas las columnas a la derecha de una columna especificada

Jim: Gracias por las correcciones.

Re: JMP 18: Seleccionar todas las columnas a la derecha de una columna especificada

Scott: Gracias por el código que funciona.

Re: JMP 18: Seleccionar todas las columnas a la derecha de una columna especificada

Contiene + indexación que debería hacer que esto sea bastante simple

Names Default To Here(1);

dt = Data Table("Test Table");

collist = dt << Get Column Names("String");

adders_idx = Contains(collist, "Adders");
If(adders_idx == 0,
	Throw("No Adders column found");
);

dt << Select columns(collist[adders_idx + 1::N Items(collist)]);

Show(dt << Get Selected Columns);