863641_it-IT

liliconcom

JMP 18: Seleziona tutte le colonne a destra di una colonna specificata

Cercando di selezionare tutte le colonne a destra della colonna denominata , Adders. Il codice seguente viene eseguito ma non seleziona visibilmente le colonne a destra di Adders. Il numero di colonne a sinistra e a destra di Adders può variare.

<JSL> Names Default To Here(1);

dt = Data Table("Test Table");
dt << Bring Window To Front;

Show(dt << Get Name);

// Step 1: Get all column names and show them
colNames = dt << Get Column Names();
Show(colNames);

// Step 2: Find the index of the "Adders" column
targetColName = "Adders";
colIndex = Loc(colNames, targetColName);
Show(colIndex); // Should be > 0 if found

// Step 3: Try to visually select all columns to the right
If(colIndex > 0 & colIndex < N Cols(dt),

dt << Clear Column Selection;

For(i = colIndex + 1, i <= N Cols(dt), i++,
Column(dt, i) << Set Selected(1);
);

// Step 4: Show what JMP thinks is selected
selected = dt << Get Selected Columns;
Show(selected);

,
New Window("Error", Text Box("Column 'Adders' not found, or it's the last column."));
);</JSL>

Produzione:

dt << Get Name = "Test Table";
colNames = {A, B, Adders, X, Y};
colIndex = [];

Automazione e scriptingFinestreRe: JMP 18: Seleziona tutte le colonne a destra di una colonna specificata

Farei due cambiamenti qui. Devi specificare "string" nel tuo messaggio Get Column Names. Dovresti quindi cambiare la funzione Loc() in Contains(). Loc() restituisce una matrice, a volte vuota. Contains() restituisce un intero (0 se non trovato).

Names Default To Here(1);

dt = Data Table("Test Table");
dt << Bring Window To Front;

Show(dt << Get Name);

// Step 1: Get all column names and show them
colNames = dt << Get Column Names( "string" );
Show(colNames);

// Step 2: Find the index of the "Adders" column
targetColName = "Adders";
colIndex = Contains(colNames, targetColName);
Show(colIndex); // Should be > 0 if found

// Step 3: Try to visually select all columns to the right
If(colIndex > 0 & colIndex < N Cols(dt),

dt << Clear Column Selection;

For(i = colIndex + 1, i <= N Cols(dt), i++,
Column(dt, i) << Set Selected(1);
);

// Step 4: Show what JMP thinks is selected
selected = dt << Get Selected Columns;
Show(selected);

,
New Window("Error", Text Box("Column 'Adders' not found, or it's the last column."));
);

 

//Output:

//dt << Get Name = "Test Table";
//colNames = {"A", "B", "Adders", "X", "Y"};
//colIndex = 3;<BR />//selected = {:X, :Y};

Re: JMP 18: Seleziona tutte le colonne a destra di una colonna specificata

Sono sicuro che ci siano altri modi per farlo, ma lo script seguente troverà la colonna "Adders", quindi selezionerà questa e tutte le colonne a destra:

names default to here(1);
dt = current data table();

targetCol = "Adders";
targetColNum = 0;

for( i = 1, i <= n cols( dt ), i++, 
	if( column( dt,i ) << get name == targetCol, targetColNum = i )
);
dt << select columns( targetColNum::n cols(dt) )

Re: JMP 18: Seleziona tutte le colonne a destra di una colonna specificata

Ho modificato il tuo post iniziale e ho spostato il JSL e il suo output rispettivamente in una finestra JSL e in una finestra Codice, utilizzando le icone di input nella parte superiore della finestra di modifica input.

Ho anche modificato il tuo codice in modo che << ottenga i nomi delle colonne, restituisca stringhe e, invece di usare Loc(), utilizzi Contains() per restituire un singolo valore anziché un valore di matrice.

Names Default To Here(1);

dt = Data Table("Test Table");
dt << Bring Window To Front;

Show(dt << Get Name);

// Step 1: Get all column names and show them
colNames = dt << Get Column Names(string);
Show(colNames);

// Step 2: Find the index of the "Adders" column
targetColName = "Adders";
// Loc() returns a matrix, contains returns a scaler value
colIndex = contains(colNames, targetColName );
Show( colIndex ); // Should be > 0 if found

// Step 3: Try to visually select all columns to the right
If( colIndex > 0 & colIndex < N Cols( dt ), 

	dt << Clear Column Selection;

	For( i = colIndex + 1, i <= N Cols( dt ), i++,
		Column( dt, i ) << Set Selected( 1 )
	);

// Step 4: Show what JMP thinks is selected
	selected = dt << Get Selected Columns;
	Show( selected );

,
	New Window( "Error", Text Box( "Column 'Adders' not found, or it's the last column." ) )
);

Re: JMP 18: Seleziona tutte le colonne a destra di una colonna specificata

Grazie per le correzioni.

Re: JMP 18: Seleziona tutte le colonne a destra di una colonna specificata

Jim: Grazie per le correzioni.

Re: JMP 18: Seleziona tutte le colonne a destra di una colonna specificata

Scott: Grazie per il codice che funziona.

Re: JMP 18: Seleziona tutte le colonne a destra di una colonna specificata

Contiene + indicizzazione usando questo dovrebbe rendere il tutto abbastanza semplice

Names Default To Here(1);

dt = Data Table("Test Table");

collist = dt << Get Column Names("String");

adders_idx = Contains(collist, "Adders");
If(adders_idx == 0,
	Throw("No Adders column found");
);

dt << Select columns(collist[adders_idx + 1::N Items(collist)]);

Show(dt << Get Selected Columns);