849125_es-ES

liliconcom

Insertar el contenido de la expresión de Parse en lugar del nombre de la variable en el nuevo script

Quiero ampliar la excelente respuesta de @Craige_Hales de "Insertar el contenido de la variable/expresión en lugar del nombre de la variable en un nuevo script mediante la combinación de scripts", pero no he entendido la sintaxis. ¿Alguna idea para que funcione?

Estoy usando JMP 18.1.2

Names Default To Here( 1 );

dt = New Table( "My Table" );

e1 = Expr(
	Print( "Run some code." )
);

e2 = Expr(
	Print( "Run some other code." )
);

e3 = Expr(
	Parse( Eval Insert( "\[
	^e1^;
	^e2^;
]\" ) )
);

// These work.
Eval( Eval Expr( dt << New Script( "Test 1", Expr( Name Expr( e1 ) ) ) ) );
Eval( Eval Expr( dt << New Script( "Test 2", Expr( Name Expr( e2 ) ) ) ) );

// This does not work.
Eval( Eval Expr( dt << New Script( "Test 3", Expr( Name Expr( e3 ) ) ) ) );

Automatización y scriptingVentanasRe: Insertar el contenido de la expresión Parse en lugar del nombre de la variable en el nuevo script

Imprime tu e3 para ver qué contiene

Name Expr(e3) = Parse(Eval Insert("
	^e1^;
	^e2^;
"));

Esto posiblemente haga lo que estás buscando.

Names Default To Here(1);

dt = New Table("My Table");

e1 = Expr(Print("Run some code."));

e2 = Expr(
	Print("Run some other code.")
);

e3 = Parse(Eval Insert("\[
	^Name Expr(e1)^;
	^Name Expr(e2)^;
]\"));

Eval(Eval Expr(dt << New Script("Test 3", Expr(Name Expr(e3)))));

Generalmente evitaría usar Parse ya que es una pesadilla depurarlo.

Names Default To Here(1);

dt = New Table("My Table");

e1 = Expr(Print("Run some code."));

e2 = Expr(
	Print("Run some other code.")
);

e3 = EvalExpr(
	Expr(Name Expr(e1));
	Expr(Name Expr(e2));
);

Eval(Eval Expr(dt << New Script("Test 3", Expr(Name Expr(e3)))));

Re: Insertar el contenido de la expresión Parse en lugar del nombre de la variable en el nuevo script

¡Excelente!