849125_zh-CN

liliconcom

将解析表达式的内容（而不是变量名）插入到新脚本中

我希望通过合并脚本来扩展@Craige_Hales 的优秀答案，即在“将变量/表达式的内容而不是变量名称插入新脚本”中，但尚未弄清楚语法。有什么想法可以让它发挥作用吗？

我正在使用 JMP 18.1.2

Names Default To Here( 1 );

dt = New Table( "My Table" );

e1 = Expr(
	Print( "Run some code." )
);

e2 = Expr(
	Print( "Run some other code." )
);

e3 = Expr(
	Parse( Eval Insert( "\[
	^e1^;
	^e2^;
]\" ) )
);

// These work.
Eval( Eval Expr( dt << New Script( "Test 1", Expr( Name Expr( e1 ) ) ) ) );
Eval( Eval Expr( dt << New Script( "Test 2", Expr( Name Expr( e2 ) ) ) ) );

// This does not work.
Eval( Eval Expr( dt << New Script( "Test 3", Expr( Name Expr( e3 ) ) ) ) );

自动化和脚本视窗回复：将解析表达式的内容（而不是变量名称）插入到新脚本中

打印你的 e3 以查看其包含的内容

Name Expr(e3) = Parse(Eval Insert("
	^e1^;
	^e2^;
"));

这可能就是你正在寻找的

Names Default To Here(1);

dt = New Table("My Table");

e1 = Expr(Print("Run some code."));

e2 = Expr(
	Print("Run some other code.")
);

e3 = Parse(Eval Insert("\[
	^Name Expr(e1)^;
	^Name Expr(e2)^;
]\"));

Eval(Eval Expr(dt << New Script("Test 3", Expr(Name Expr(e3)))));

我一般会避免使用 Parse，因为它的调试非常困难

Names Default To Here(1);

dt = New Table("My Table");

e1 = Expr(Print("Run some code."));

e2 = Expr(
	Print("Run some other code.")
);

e3 = EvalExpr(
	Expr(Name Expr(e1));
	Expr(Name Expr(e2));
);

Eval(Eval Expr(dt << New Script("Test 3", Expr(Name Expr(e3)))));

回复：将解析表达式的内容（而不是变量名称）插入到新脚本中

出色的！