849125_it-IT

liliconcom

Inserisci il contenuto dell'espressione Parse anziché il nome della variabile nel nuovo script

Vorrei estendere l'eccellente risposta di @Craige_Hales da Inserisci contenuto di variabile/espressione anziché nome variabile in Nuovo script combinando script, ma non ho elaborato la sintassi. Avete idee per farlo funzionare?

Sto utilizzando JMP 18.1.2

Names Default To Here( 1 );

dt = New Table( "My Table" );

e1 = Expr(
	Print( "Run some code." )
);

e2 = Expr(
	Print( "Run some other code." )
);

e3 = Expr(
	Parse( Eval Insert( "\[
	^e1^;
	^e2^;
]\" ) )
);

// These work.
Eval( Eval Expr( dt << New Script( "Test 1", Expr( Name Expr( e1 ) ) ) ) );
Eval( Eval Expr( dt << New Script( "Test 2", Expr( Name Expr( e2 ) ) ) ) );

// This does not work.
Eval( Eval Expr( dt << New Script( "Test 3", Expr( Name Expr( e3 ) ) ) ) );

Automazione e scriptingFinestreRe: Inserisci il contenuto dell'espressione Parse anziché il nome della variabile nel nuovo script

Stampa il tuo e3 per vedere cosa contiene

Name Expr(e3) = Parse(Eval Insert("
	^e1^;
	^e2^;
"));

Questo probabilmente fa quello che stai cercando

Names Default To Here(1);

dt = New Table("My Table");

e1 = Expr(Print("Run some code."));

e2 = Expr(
	Print("Run some other code.")
);

e3 = Parse(Eval Insert("\[
	^Name Expr(e1)^;
	^Name Expr(e2)^;
]\"));

Eval(Eval Expr(dt << New Script("Test 3", Expr(Name Expr(e3)))));

In genere eviterei di usare Parse perché è un incubo da eseguire il debug

Names Default To Here(1);

dt = New Table("My Table");

e1 = Expr(Print("Run some code."));

e2 = Expr(
	Print("Run some other code.")
);

e3 = EvalExpr(
	Expr(Name Expr(e1));
	Expr(Name Expr(e2));
);

Eval(Eval Expr(dt << New Script("Test 3", Expr(Name Expr(e3)))));

Re: Inserisci il contenuto dell'espressione Parse anziché il nome della variabile nel nuovo script

Eccellente!