849125_de-DE

liliconcom

Fügen Sie den Inhalt des Parse-Ausdrucks anstelle des Variablennamens in das neue Skript ein

Ich möchte die hervorragende Antwort von @Craige_Hales erweitern, indem ich Inhalte von Variablen/Ausdrücken anstelle von Variablennamen in ein neues Skript einfüge , indem ich Skripte kombiniere. Die Syntax ist mir aber noch nicht klar. Hat jemand eine Idee, wie das funktioniert?

Ich verwende JMP 18.1.2

Names Default To Here( 1 );

dt = New Table( "My Table" );

e1 = Expr(
	Print( "Run some code." )
);

e2 = Expr(
	Print( "Run some other code." )
);

e3 = Expr(
	Parse( Eval Insert( "\[
	^e1^;
	^e2^;
]\" ) )
);

// These work.
Eval( Eval Expr( dt << New Script( "Test 1", Expr( Name Expr( e1 ) ) ) ) );
Eval( Eval Expr( dt << New Script( "Test 2", Expr( Name Expr( e2 ) ) ) ) );

// This does not work.
Eval( Eval Expr( dt << New Script( "Test 3", Expr( Name Expr( e3 ) ) ) ) );

Automatisierung und SkriptingWindowsBetreff: Fügen Sie den Inhalt des Parse-Ausdrucks anstelle des Variablennamens in das neue Skript ein

Drucken Sie Ihr e3 aus, um zu sehen, was es enthält

Name Expr(e3) = Parse(Eval Insert("
	^e1^;
	^e2^;
"));

Dies macht möglicherweise das, was Sie suchen

Names Default To Here(1);

dt = New Table("My Table");

e1 = Expr(Print("Run some code."));

e2 = Expr(
	Print("Run some other code.")
);

e3 = Parse(Eval Insert("\[
	^Name Expr(e1)^;
	^Name Expr(e2)^;
]\"));

Eval(Eval Expr(dt << New Script("Test 3", Expr(Name Expr(e3)))));

Ich würde generell die Verwendung von Parse vermeiden, da das Debuggen ein Albtraum ist

Names Default To Here(1);

dt = New Table("My Table");

e1 = Expr(Print("Run some code."));

e2 = Expr(
	Print("Run some other code.")
);

e3 = EvalExpr(
	Expr(Name Expr(e1));
	Expr(Name Expr(e2));
);

Eval(Eval Expr(dt << New Script("Test 3", Expr(Name Expr(e3)))));

Betreff: Fügen Sie den Inhalt des Parse-Ausdrucks anstelle des Variablennamens in das neue Skript ein

Exzellent!