849125_fr-FR

liliconcom

Insérer le contenu de l'expression d'analyse plutôt que le nom de la variable dans le nouveau script

Je cherche à étendre l'excellente réponse de @Craige_Hales à la question « Insérer le contenu d'une variable/expression plutôt que le nom de la variable dans un nouveau script en combinant le script », mais je n'ai pas encore déterminé la syntaxe. Auriez-vous des idées pour que cela fonctionne ?

J'utilise JMP 18.1.2

Names Default To Here( 1 );

dt = New Table( "My Table" );

e1 = Expr(
	Print( "Run some code." )
);

e2 = Expr(
	Print( "Run some other code." )
);

e3 = Expr(
	Parse( Eval Insert( "\[
	^e1^;
	^e2^;
]\" ) )
);

// These work.
Eval( Eval Expr( dt << New Script( "Test 1", Expr( Name Expr( e1 ) ) ) ) );
Eval( Eval Expr( dt << New Script( "Test 2", Expr( Name Expr( e2 ) ) ) ) );

// This does not work.
Eval( Eval Expr( dt << New Script( "Test 3", Expr( Name Expr( e3 ) ) ) ) );

Automatisation et scriptsWindowsRe : Insérer le contenu de l'expression d'analyse plutôt que le nom de la variable dans le nouveau script

Imprimez votre e3 pour voir ce qu'il contient

Name Expr(e3) = Parse(Eval Insert("
	^e1^;
	^e2^;
"));

Cela fait probablement ce que vous recherchez

Names Default To Here(1);

dt = New Table("My Table");

e1 = Expr(Print("Run some code."));

e2 = Expr(
	Print("Run some other code.")
);

e3 = Parse(Eval Insert("\[
	^Name Expr(e1)^;
	^Name Expr(e2)^;
]\"));

Eval(Eval Expr(dt << New Script("Test 3", Expr(Name Expr(e3)))));

J'éviterais généralement d'utiliser Parse car c'est un cauchemar à déboguer

Names Default To Here(1);

dt = New Table("My Table");

e1 = Expr(Print("Run some code."));

e2 = Expr(
	Print("Run some other code.")
);

e3 = EvalExpr(
	Expr(Name Expr(e1));
	Expr(Name Expr(e2));
);

Eval(Eval Expr(dt << New Script("Test 3", Expr(Name Expr(e3)))));

Re : Insérer le contenu de l'expression d'analyse plutôt que le nom de la variable dans le nouveau script

Excellent!