848462_it-IT

liliconcom

Funzione loop elemento costruttore grafico

Come posso usare la funzione loop per la definizione di più posizioni?

Se separato come di seguito funziona:

Eval(
			Substitute(
			Expr(
				gb = cdt << Graph Builder(
					Size( 600, 800 ),
					Show Control Panel( 0 ),
					vvv,
					Elements(Position( 1, 1 ),
						Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Legend( 3 ) ),
						Smoother( X, Y( 1 ), Y( 2 ), Y( 3 ), Legend( 4 ) )
					),
					Elements(
                    Position( 2, 1 ),
                    Box Plot( X, Y, Outliers( 0 ) ),
                    Points( X, Y ),
                    Bar( X, Y, Bar Style( "Float" ), Label( "Label by Value" ) ),
                    Legend( 6 )
                ),
                Elements(
                    Position( 2, 2 ),
                    Box Plot( X, Y, Outliers( 0 ) ),
                    Points( X, Y ),
                    Bar( X, Y, Bar Style( "Float" ), Label( "Label by Value" ) ),
                    Legend( 7 )
                ),
                Elements(
                    Position( 2, 3 ),
                    Box Plot( X, Y, Outliers( 0 ) ),
                    Points( X, Y ),
                    Bar( X, Y, Bar Style( "Float" ), Label( "Label by Value" ) ),
                    Legend( 8 )
                )
            )
        ),
        Expr( vvv ),
        Name Expr( var expr )
    )
);

Ma se usando un loop come questo si ottiene solo una barra, cosa manca in questo codice?

Eval(
			Substitute(
			Expr(
				gb = cdt << Graph Builder(
					Size( 600, 800 ),
					Show Control Panel( 0 ),
					vvv,
					Elements(Position( 1, 1 ),
						Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Legend( 3 ) ),
						Smoother( X, Y( 1 ), Y( 2 ), Y( 3 ), Legend( 4 ) )
					),
					For( j = 1, j <= n_mydatecol, j++,
						Elements(
							Position( 2, j ),
							Box Plot( X, Y, Outliers( 0 ) ),
							Points( X, Y ),
							Bar( X, Y, Bar Style( "Float" ), Label( "Label by Value" ) ),
							Legend(eval( 5 + j ))
						),
					),
				)
			),
			Expr( vvv ),
			Name Expr( var expr )
		)
	);

Automazione e scriptingFinestreRe: Funzione loop elemento generatore grafico

Potresti costruire le espressioni degli elementi separatamente e poi valutarle all'interno dell'espressione del generatore di grafici. Oppure in alcuni casi potrebbe essere più semplice se usi << Aggiungi elemento

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = Graph Builder(Variables(X(:height), Y(:weight)), Elements(Points(X, Y), Smoother(X, Y)));
Wait(0.5);
gb << Add Element(1, 1, {Type("Line Of Fit"), X, Y, Degree("Quadratic")});

Re: Funzione loop elemento generatore grafico

il mio grafico vuole essere così, devo definire la posizione?

Re: Funzione loop elemento generatore grafico

Aggiungi elemento ti consente di impostare le posizioni X e Y. Hai provato a vedere se funziona per il tuo caso d'uso?

Re: Funzione loop elemento generatore grafico

Ciao Jarmo,

Prova a usare il codice qui sotto, ma mostra comunque solo il box plot. Come posso mostrare la barra e l'etichetta?

Eval(
Substitute(
Expr(
gb = cdt << Graph Builder(
Size( 1200, 800 ),
Show Control Panel( 0 ),
vvv,
Elements(
Position( 1, 1 ),
Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Legend( 3 ) ),
Smoother( X, Y( 1 ), Y( 2 ), Y( 3 ), Legend( 4 ) )
)
);

// Loop to add repetitive elements
For( i = 2, i <= 10, i++,
gb << Add Elements(
Position( 2, i ),
Box Plot( X, Y( 1 ), Y( 2 ), Y( 3 ), Legend( 2 * i + 1 ) ),
Bar( X, Y, Legend( 2 * i + 2 ), Bar Style( "Float" ), Label( "Label by Value" ), Label Format( "Fixed Dec", 5, 2 ) )
);
);
),
Expr( vvv ),
Name Expr( var expr )
)
);

Re: Funzione loop elemento generatore grafico

Dovrò creare dati di esempio (o trovarne di appropriati) e ricreare il grafico, quindi ci vorrà del tempo

Re: Funzione loop elemento generatore grafico

Vedo che tutte le immagini sono cambiate in qualcosa di completamente diverso da prima... Non sono sicuro di quanto bene gli script forniti corrispondano a quelle nuove immagini. Quali colonne dovrebbero essere aggiunte dinamicamente e dove?

Script per la creazione di grafici per questo

sembra qualcosa del genere

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(528, 454),
	Show Control Panel(0),
	Variables(X(:height), X(:sex), Y(:weight)),
	Elements(
		Position(1, 1),
		Points(X, Y, Legend(5)),
		Smoother(X, Y, Legend(6)),
		Line Of Fit(X, Y, Legend(8))
	),
	Elements(
		Position(2, 1),
		Points(X, Y, Legend(18)),
		Bar(X, Y, Legend(19), Bar Style("Float"), Label("Label by Value"))
	)
);

Se hai un grafico come questo e desideri aggiungere un grafico a barre mobile sul lato destro con punti

Puoi usare aggiungi elemento

gb << Add Element(2, 1, {Type("Bar"), X, Y, Bar Style("Float"), Label("Label by Value")});

Vedi altro...

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(528, 454),
	Show Control Panel(0),
	Variables(X(:height), X(:sex), Y(:weight)),
	Elements(
		Position(1, 1),
		Points(X, Y, Legend(5)),
		Smoother(X, Y, Legend(6)),
		Line Of Fit(X, Y, Legend(8))
	),
	Elements(
		Position(2, 1),
		Points(X, Y, Legend(18))
	)
);

gb << Add Element(2, 1, {Type("Bar"), X, Y, Bar Style("Float"), Label("Label by Value")});

Re: Funzione loop elemento generatore grafico

Ciao Jarmo,
Grazie per l'aiuto, potrebbe funzionare anche se l'asse y ne avesse solo uno, ma quello che voglio è se ci sono più assi y, posso comunque usare la funzione loop per avere l'elemento con box plot e barre? Ho provato come il primo, ma mostrava solo box plot senza barre.

Re: Funzione loop elemento generatore grafico

Non sono sicuro di cosa stai tracciando, ma potrebbe (o potrebbe non) funzionare. Qui sto usando Add Element per aggiungere un grafico a barre all'asse X 2 e all'asse Y 1 e 2

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(528, 454),
	Show Control Panel(0),
	Variables(X(:height), X(:sex), Y(:name), Y(:weight)),
	Elements(Position(1, 1), Points(X, Y, Legend(20))),
	Elements(
		Position(1, 2),
		Points(X, Y, Legend(5)),
		Smoother(X, Y, Legend(6)),
		Line Of Fit(X, Y, Legend(8))
	),
	Elements(Position(2, 1), Points(X, Y, Legend(19))),
	Elements(Position(2, 2), Points(X, Y, Legend(18)))
);

gb << Add Element(2, 1, {Type("Bar"), X, Y, Bar Style("Float"), Label("Label by Value")});
gb << Add Element(2, 2, {Type("Bar"), X, Y, Bar Style("Float"), Label("Label by Value")});

Re: Funzione loop elemento generatore grafico

Funziona, e ci provo così.

Molte grazie

Eval(
			Substitute(
			Expr(
				gb = cdt << Graph Builder(
					Size( 600, 800 ),
					Show Control Panel( 0 ),
					vvv,
					Elements(Position( 1, 1 ),
						Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Legend( 3 ) ),
						Smoother( X, Y( 1 ), Y( 2 ), Y( 3 ), Legend( 4 ) )
					),
					);
				For( i = 1 , i <= n_mymetric , i++, 
					gb << Add Element(2, i, {Type("Bar"), X, Y, Bar Style("Float"), Label("Label by Value")});
				),
			),
			Expr( vvv ),
			Name Expr( var expr )
		)
	);