847617_fr-FR

liliconcom

Le d de Cohen

Bonjour

J'ai réalisé une ANOVA à un facteur pour comparer la moyenne d'une variable sur trois groupes. L'examinateur de mon article m'a demandé le test d de Cohen pour mesurer l'ampleur de l'effet. Comment puis-je obtenir cette mesure dans JMP ? J'utilise JMP Pro V17.

Modélisation statistique avancéeRe: Cohen's d

Le d de Cohen n'est pas directement disponible dans JMP 17. Cependant, il est dans JMP 18 sous

Analyser => Ajuster Y par X => Moyennes/Anova/T groupé

Dans JMP 17, ce calcul doit être effectué en JSL. Voici un exemple de script générant le d de Cohen pour toutes les paires de groupes.

ou

Names Default To Here( 1 );
dt = open("$SAMPLE_DATA/big class.jmp");

var = "height";
grp = "sex";
Eval(
	Parse(
		"Summarize(
		dt,
		bygp = by( :" || grp || " ),
		stds = Std Dev( :" || var
		 || " ),
		ns = Count( :" || var || " ),
		means = Mean( :" || var || " )
	);"
	)
);

nw = New Window( "Cohen's d", vlb = V List Box() );
For( i = 1, i <= N Items( bygp ) - 1, i++,
	For( k = i + 1, k <= N Items( bygp ), k++,
		pooled = Sqrt(
			(stds[i] ^ 2 * (ns[i] - 1) + stds[k] ^ 2 * (ns[k] - 1)) / (ns[i] + ns[k] - 2)
		);
		dif = Abs( means[i] - means[k] );
		cohen = (dif / pooled);
		stats = Matrix( dif ) |/ Matrix( pooled ) |/ Matrix( cohen );
		compare = {};
		insert into( compare, bygp[i] || " vs. " || bygp[k]);
		ob = Outline Box( grp || "=" || bygp[i] || " vs. " || grp || "=" || bygp[k],
			Table Box(
				String Col Box( "", compare ),
				String Col Box( "", {"Difference", "Pooled Std Dev", "Cohen's d"} ),
				Number Col Box( "", stats )
			)
		);
		vlb << append( ob );
	)
);

Re: Cohen's d

Merci

C'était utile. Je me demande s'il est possible de l'obtenir dans JMP 18 pour trois groupes, et non deux. Le t groupé n'est disponible que pour comparer les moyennes de deux groupes. Cependant, dans mon cas, j'ai effectué une ANOVA à un facteur pour comparer les moyennes de trois groupes.

Re: Cohen's d

Salut @Samira ,

En dehors de deux groupes, cette option n'est pas disponible nativement avec JMP 18. Vous pouvez consulter la liste de souhaits : ce besoin a déjà été exprimé et reconnu : le d de Cohen pour « Ajuster Y par X ».

Espérons une sortie dans une future version 18.X ou JMP 19.

Re: Cohen's d

Salut @Samira : Pour info, pour 2 groupes ou plus dans l'ANOVA, le RMSE (Root Mean Squared Error) est l'écart type groupé.

Re: Cohen's d

Merci

Cela m'a beaucoup aidé à calculer manuellement le d de Cohen. Pour plus de précisions, j'ai trouvé la RMSE dans le résumé du tableau d'ajustement.