847212_zh-TW

liliconcom

需要協助從 JSL 中的圖元中刪除標籤

你好，

我有一個腳本，可以在圖形產生器中顯示幾個指標平均值（線），也可以產生具有單獨指標（點）的圖形。

[1] — 我想從圖基元中刪除標籤，但到目前為止還沒有成功。

在這個例子（下面的腳本）中，我想刪除「Position2 和 Mean()」標籤，只保留圖形（帶有它自己的符號）。

從腳本指南來看，它似乎需要一個 Gridlet（P 704），但我所有的嘗試都失敗了。

[2] - 當第一個圖表上的線條彼此接近時（例如：速度和：高度），當我移動滑鼠嘗試單擊它以打開帶有單獨資料的圖表產生器時，圖表往往會消失。是否有一個選項“單擊”來直接打開它，而不是“將滑鼠懸停在線上，然後將滑鼠懸停在小圖形上，然後單擊”？ （腳本指南 P696 提到了「點擊」選項，但不清楚）

你能幫我一下嗎？

先致謝

-牧師

請參閱我的最後一個“穩定”版本

Names Default To Here( 1 );

dt = Open( "$sample_data\Football.jmp" );

y_values = {"Height", "Weight", "Fat", "Speed"};

RelEventCol = "Position2";

variables_expr = Eval Expr( Variables( X( As Column( dt, Expr( RelEventCol ) ) ) ) );

Show( variables_expr );

For Each( {y_col}, y_values,
	temp_expr = Expr( Y() );
	Insert Into( temp_expr, Name Expr( As Column( dt, y_col ) ) );
	Insert Into( temp_expr, Name Expr( Position( 1 ) ) );
	Insert Into( variables_expr, Name Expr( temp_expr ) );
);

Show( variables_expr );

gb_expr = Expr(
	Graph Builder( Show Control Panel( 0 ) )
);

temp_expr3 = Expr( Line() );
Insert Into( temp_expr3, Name Expr( X ) );

For Each( {y_col, idx}, y_values,
	temp_expr2 = Expr( Y() );
	Insert Into( temp_expr2, idx );
	Insert Into( temp_expr3, Name Expr( temp_expr2 ) );
);
Show( temp_expr3 );
Insert Into( temp_expr3, Name Expr( Legend( 7 ) ) );
Show( temp_expr3 );

temp_expr4 = Expr( Elements() );
Insert Into( temp_expr4, Name Expr( temp_expr3 ) );
Show( temp_expr4 );

Insert Into( gb_expr, Name Expr( variables_expr ) );
Insert Into( gb_expr, Name Expr( temp_expr4 ) );

Insert Into(
	gb_expr,
	Name Expr(
		Dispatch(
			{},
			"Graph Builder",
			FrameBox,
			{Set Graphlet(
				Picture(
					dt << Graph Builder(
						Size( 800, 700 ),
						Show Control Panel( 0 ),
						Show Legend( 0 ),
						Variables( X( As Column( dt, Expr( RelEventCol ) ) ), Y( Column( local:_measurements ) ) ),
						Elements( X, Y )
					);
			
				),
				Skip Filters( 1, Column( dt, Name Expr( RelEventCol ) ) )
			)
		
			}
		)
	)
);

Show( gb_expr );

Eval( gb_expr );

自動化和腳本基礎資料分析與建模回覆：需要協助從 JSL 中的圖元中刪除標籤

懸停標籤很可能是您正在尋找的https://www.jmp.com/support/help/en/18.1/index.shtml#page/jmp/hover-labels.shtml# 。點擊的目的是當使用者點擊懸停標籤上的縮圖時觸發

回覆：需要協助從 JSL 中的圖元中刪除標籤

幾週前我發現瞭如何刪除懸停標籤中不需要的部分。這是實現此目的的一種方法。

Names Default To Here( 1 );

dt = Open( "$sample_data\Football.jmp" );

y_values = {"Height", "Weight", "Fat", "Speed"};

RelEventCol = "Position2";

variables_expr = Eval Expr( Variables( X( As Column( dt, Expr( RelEventCol ) ) ) ) );

Show( variables_expr );

For Each( {y_col}, y_values,
	temp_expr = Expr( Y() );
	Insert Into( temp_expr, Name Expr( As Column( dt, y_col ) ) );
	Insert Into( temp_expr, Name Expr( Position( 1 ) ) );
	Insert Into( variables_expr, Name Expr( temp_expr ) );
);

Show( variables_expr );

gb_expr = Expr(
	Graph Builder( Show Control Panel( 0 ) )
);

temp_expr3 = Expr( Line() );
Insert Into( temp_expr3, Name Expr( X ) );

For Each( {y_col, idx}, y_values,
	temp_expr2 = Expr( Y() );
	Insert Into( temp_expr2, idx );
	Insert Into( temp_expr3, Name Expr( temp_expr2 ) );
);
Show( temp_expr3 );
Insert Into( temp_expr3, Name Expr( Legend( 7 ) ) );
Show( temp_expr3 );

temp_expr4 = Expr( Elements() );
Insert Into( temp_expr4, Name Expr( temp_expr3 ) );
Show( temp_expr4 );

Insert Into( gb_expr, Name Expr( variables_expr ) );
Insert Into( gb_expr, Name Expr( temp_expr4 ) );

Insert Into(
	gb_expr,
	Name Expr(
		Dispatch( {}, "Graph Builder", FrameBox,
			{Set Graphlet(
				Picture(
					dt << Graph Builder(
						Size( 800, 700 ),
						Show Control Panel( 0 ),
						Show Legend( 0 ),
						Variables( X( As Column( dt, Expr( RelEventCol ) ) ), Y( Column( local:_measurements ) ) ),
						Elements( X, Y )
					);
			
				),
				Skip Filters( 1, Column( dt, Name Expr( RelEventCol ) ) )
			), Set Gridlet(
				Expunge(
					{{Matcher( "Position2" )}, {Matcher( "Mean(Height)" )}, {Matcher( "Mean(Weight)" )}, {Matcher( "Mean(Fat)" )},
					{Matcher( "Mean(Speed)" )}}
				)
			)	//Removes these from the default gridlet
		
			}
		)
	)
);

Show( gb_expr );

Eval( gb_expr );

回覆：需要協助從 JSL 中的圖元中刪除標籤

可能應該使用這個，而不是“Mean(...)”值列表。

{Matcher( Pat Regex( "Mean" ) )}

回覆：需要協助從 JSL 中的圖元中刪除標籤

謝謝大家的幫忙。

效果很好:)

- 傳教士