847212_ja-JP

liliconcom

JSL のグラフレットからラベルを削除するにはヘルプが必要です

こんにちは、

グラフ ビルダーで複数のメトリック平均 (線) を表示し、個々のメトリック (ポイント) を含むグラフレットも生成するスクリプトがあります。

[1] - グラフレットからラベルを削除したいのですが、今のところ成功していません。

この例では (以下のスクリプト)、「Position2 および Mean()」ラベルを削除し、グラフのみ (独自の表記付き) を保持したいと思います。

スクリプト ガイドによると、Gridlet (P 704) が必要なようですが、私の試みはすべて失敗しました。

[2] - 最初のグラフの線が互いに近い場合 (例では :Speed と :Height)、マウスを動かしてクリックし、個々のデータを含むグラフ ビルダーを開こうとすると、グラフレットが消える傾向があります。「線をホバーしてからグラフレットをホバーしてクリック」ではなく、「クリック」して直接開くオプションはありますか? (スクリプト ガイド P696 に「クリック」オプションについて記載されていますが、明確ではありません)

これについて助けていただけませんか？

前もって感謝します

-説教者

最新の「安定版」バージョンを下記でご覧ください

Names Default To Here( 1 );

dt = Open( "$sample_data\Football.jmp" );

y_values = {"Height", "Weight", "Fat", "Speed"};

RelEventCol = "Position2";

variables_expr = Eval Expr( Variables( X( As Column( dt, Expr( RelEventCol ) ) ) ) );

Show( variables_expr );

For Each( {y_col}, y_values,
	temp_expr = Expr( Y() );
	Insert Into( temp_expr, Name Expr( As Column( dt, y_col ) ) );
	Insert Into( temp_expr, Name Expr( Position( 1 ) ) );
	Insert Into( variables_expr, Name Expr( temp_expr ) );
);

Show( variables_expr );

gb_expr = Expr(
	Graph Builder( Show Control Panel( 0 ) )
);

temp_expr3 = Expr( Line() );
Insert Into( temp_expr3, Name Expr( X ) );

For Each( {y_col, idx}, y_values,
	temp_expr2 = Expr( Y() );
	Insert Into( temp_expr2, idx );
	Insert Into( temp_expr3, Name Expr( temp_expr2 ) );
);
Show( temp_expr3 );
Insert Into( temp_expr3, Name Expr( Legend( 7 ) ) );
Show( temp_expr3 );

temp_expr4 = Expr( Elements() );
Insert Into( temp_expr4, Name Expr( temp_expr3 ) );
Show( temp_expr4 );

Insert Into( gb_expr, Name Expr( variables_expr ) );
Insert Into( gb_expr, Name Expr( temp_expr4 ) );

Insert Into(
	gb_expr,
	Name Expr(
		Dispatch(
			{},
			"Graph Builder",
			FrameBox,
			{Set Graphlet(
				Picture(
					dt << Graph Builder(
						Size( 800, 700 ),
						Show Control Panel( 0 ),
						Show Legend( 0 ),
						Variables( X( As Column( dt, Expr( RelEventCol ) ) ), Y( Column( local:_measurements ) ) ),
						Elements( X, Y )
					);
			
				),
				Skip Filters( 1, Column( dt, Name Expr( RelEventCol ) ) )
			)
		
			}
		)
	)
);

Show( gb_expr );

Eval( gb_expr );

自動化とスクリプト基本的なデータ分析とモデリングRe: JSL のグラフレットからラベルを削除するには助けが必要です

ホバーラベルはおそらくあなたが探しているものですhttps://www.jmp.com/support/help/en/18.1/index.shtml#page/jmp/hover-labels.shtml# 。クリックの目的は、ユーザーがホバーラベルのサムネイルをクリックしたときにトリガーすることです

Re: JSL のグラフレットからラベルを削除するには助けが必要です

数週間前に、ホバー ラベルの不要な部分を削除する方法を見つけました。その方法の 1 つを以下に示します。

Names Default To Here( 1 );

dt = Open( "$sample_data\Football.jmp" );

y_values = {"Height", "Weight", "Fat", "Speed"};

RelEventCol = "Position2";

variables_expr = Eval Expr( Variables( X( As Column( dt, Expr( RelEventCol ) ) ) ) );

Show( variables_expr );

For Each( {y_col}, y_values,
	temp_expr = Expr( Y() );
	Insert Into( temp_expr, Name Expr( As Column( dt, y_col ) ) );
	Insert Into( temp_expr, Name Expr( Position( 1 ) ) );
	Insert Into( variables_expr, Name Expr( temp_expr ) );
);

Show( variables_expr );

gb_expr = Expr(
	Graph Builder( Show Control Panel( 0 ) )
);

temp_expr3 = Expr( Line() );
Insert Into( temp_expr3, Name Expr( X ) );

For Each( {y_col, idx}, y_values,
	temp_expr2 = Expr( Y() );
	Insert Into( temp_expr2, idx );
	Insert Into( temp_expr3, Name Expr( temp_expr2 ) );
);
Show( temp_expr3 );
Insert Into( temp_expr3, Name Expr( Legend( 7 ) ) );
Show( temp_expr3 );

temp_expr4 = Expr( Elements() );
Insert Into( temp_expr4, Name Expr( temp_expr3 ) );
Show( temp_expr4 );

Insert Into( gb_expr, Name Expr( variables_expr ) );
Insert Into( gb_expr, Name Expr( temp_expr4 ) );

Insert Into(
	gb_expr,
	Name Expr(
		Dispatch( {}, "Graph Builder", FrameBox,
			{Set Graphlet(
				Picture(
					dt << Graph Builder(
						Size( 800, 700 ),
						Show Control Panel( 0 ),
						Show Legend( 0 ),
						Variables( X( As Column( dt, Expr( RelEventCol ) ) ), Y( Column( local:_measurements ) ) ),
						Elements( X, Y )
					);
			
				),
				Skip Filters( 1, Column( dt, Name Expr( RelEventCol ) ) )
			), Set Gridlet(
				Expunge(
					{{Matcher( "Position2" )}, {Matcher( "Mean(Height)" )}, {Matcher( "Mean(Weight)" )}, {Matcher( "Mean(Fat)" )},
					{Matcher( "Mean(Speed)" )}}
				)
			)	//Removes these from the default gridlet
		
			}
		)
	)
);

Show( gb_expr );

Eval( gb_expr );

Re: JSL のグラフレットからラベルを削除するには助けが必要です

「Mean(...」値のリストの代わりに、おそらくこれを使用する必要があります。名前に「Mean」が含まれるものはすべて削除されます。

{Matcher( Pat Regex( "Mean" ) )}

Re: JSL のグラフレットからラベルを削除するには助けが必要です

皆様のご協力に感謝します。

うまく機能する:)

- 説教者