847212_it-IT

liliconcom

Ho bisogno di aiuto per rimuovere le etichette da un graphlet in JSL

Ciao,

Ho uno script che visualizza diverse medie di metriche (linee) in un generatore di grafici e genera anche un grafico con singole metriche (punti).

[1] - Vorrei rimuovere le etichette dal graphlet, ma finora non ci sono riuscito.

In questo esempio (script qui sotto), vorrei rimuovere le etichette "Position2 e Mean()", mantenendo solo il grafico (con le sue notazioni).

Dalla guida allo scripting, sembra che sia necessario un Gridlet (P 704), ma tutti i miei tentativi sono falliti.

[2] - quando le linee sul primo grafico sono vicine tra loro (ad esempio:Speed ​​e :Height), il graphlet tende a scomparire quando muovo il mouse per provare a cliccarci sopra per aprire il generatore di grafici con i singoli dati. C'è un'opzione "clicca" per aprirlo direttamente invece di "Passa il mouse sulla linea, poi passa il graphlet, poi clicca"? (La guida di scripting P696 menziona l'opzione "Clicca" ma non è chiara)

Potresti aiutarmi con questo?

grazie in anticipo

-Predicatore

Vedi sotto la mia ultima versione "stabile"

Names Default To Here( 1 );

dt = Open( "$sample_data\Football.jmp" );

y_values = {"Height", "Weight", "Fat", "Speed"};

RelEventCol = "Position2";

variables_expr = Eval Expr( Variables( X( As Column( dt, Expr( RelEventCol ) ) ) ) );

Show( variables_expr );

For Each( {y_col}, y_values,
	temp_expr = Expr( Y() );
	Insert Into( temp_expr, Name Expr( As Column( dt, y_col ) ) );
	Insert Into( temp_expr, Name Expr( Position( 1 ) ) );
	Insert Into( variables_expr, Name Expr( temp_expr ) );
);

Show( variables_expr );

gb_expr = Expr(
	Graph Builder( Show Control Panel( 0 ) )
);

temp_expr3 = Expr( Line() );
Insert Into( temp_expr3, Name Expr( X ) );

For Each( {y_col, idx}, y_values,
	temp_expr2 = Expr( Y() );
	Insert Into( temp_expr2, idx );
	Insert Into( temp_expr3, Name Expr( temp_expr2 ) );
);
Show( temp_expr3 );
Insert Into( temp_expr3, Name Expr( Legend( 7 ) ) );
Show( temp_expr3 );

temp_expr4 = Expr( Elements() );
Insert Into( temp_expr4, Name Expr( temp_expr3 ) );
Show( temp_expr4 );

Insert Into( gb_expr, Name Expr( variables_expr ) );
Insert Into( gb_expr, Name Expr( temp_expr4 ) );

Insert Into(
	gb_expr,
	Name Expr(
		Dispatch(
			{},
			"Graph Builder",
			FrameBox,
			{Set Graphlet(
				Picture(
					dt << Graph Builder(
						Size( 800, 700 ),
						Show Control Panel( 0 ),
						Show Legend( 0 ),
						Variables( X( As Column( dt, Expr( RelEventCol ) ) ), Y( Column( local:_measurements ) ) ),
						Elements( X, Y )
					);
			
				),
				Skip Filters( 1, Column( dt, Name Expr( RelEventCol ) ) )
			)
		
			}
		)
	)
);

Show( gb_expr );

Eval( gb_expr );

Automazione e scriptingAnalisi e modellazione dei dati di baseRe: Ho bisogno di aiuto per rimuovere le etichette da un graphlet in JSL

Le etichette al passaggio del mouse sono molto probabilmente ciò che stai cercando https://www.jmp.com/support/help/en/18.1/index.shtml#page/jmp/hover-labels.shtml# . Lo scopo di Click è di attivarsi quando l'utente fa clic sulla miniatura sull'etichetta al passaggio del mouse

Re: Ho bisogno di aiuto per rimuovere le etichette da un graphlet in JSL

Ho scoperto come rimuovere le parti indesiderate dell'etichetta hover qualche settimana fa. Ecco un modo per farlo.

Names Default To Here( 1 );

dt = Open( "$sample_data\Football.jmp" );

y_values = {"Height", "Weight", "Fat", "Speed"};

RelEventCol = "Position2";

variables_expr = Eval Expr( Variables( X( As Column( dt, Expr( RelEventCol ) ) ) ) );

Show( variables_expr );

For Each( {y_col}, y_values,
	temp_expr = Expr( Y() );
	Insert Into( temp_expr, Name Expr( As Column( dt, y_col ) ) );
	Insert Into( temp_expr, Name Expr( Position( 1 ) ) );
	Insert Into( variables_expr, Name Expr( temp_expr ) );
);

Show( variables_expr );

gb_expr = Expr(
	Graph Builder( Show Control Panel( 0 ) )
);

temp_expr3 = Expr( Line() );
Insert Into( temp_expr3, Name Expr( X ) );

For Each( {y_col, idx}, y_values,
	temp_expr2 = Expr( Y() );
	Insert Into( temp_expr2, idx );
	Insert Into( temp_expr3, Name Expr( temp_expr2 ) );
);
Show( temp_expr3 );
Insert Into( temp_expr3, Name Expr( Legend( 7 ) ) );
Show( temp_expr3 );

temp_expr4 = Expr( Elements() );
Insert Into( temp_expr4, Name Expr( temp_expr3 ) );
Show( temp_expr4 );

Insert Into( gb_expr, Name Expr( variables_expr ) );
Insert Into( gb_expr, Name Expr( temp_expr4 ) );

Insert Into(
	gb_expr,
	Name Expr(
		Dispatch( {}, "Graph Builder", FrameBox,
			{Set Graphlet(
				Picture(
					dt << Graph Builder(
						Size( 800, 700 ),
						Show Control Panel( 0 ),
						Show Legend( 0 ),
						Variables( X( As Column( dt, Expr( RelEventCol ) ) ), Y( Column( local:_measurements ) ) ),
						Elements( X, Y )
					);
			
				),
				Skip Filters( 1, Column( dt, Name Expr( RelEventCol ) ) )
			), Set Gridlet(
				Expunge(
					{{Matcher( "Position2" )}, {Matcher( "Mean(Height)" )}, {Matcher( "Mean(Weight)" )}, {Matcher( "Mean(Fat)" )},
					{Matcher( "Mean(Speed)" )}}
				)
			)	//Removes these from the default gridlet
		
			}
		)
	)
);

Show( gb_expr );

Eval( gb_expr );

Re: Ho bisogno di aiuto per rimuovere le etichette da un graphlet in JSL

Invece dell'elenco di valori "Mean(...", probabilmente si dovrebbe usare questo. Rimuoverà qualsiasi cosa con "Mean" nel nome.

{Matcher( Pat Regex( "Mean" ) )}

Re: Ho bisogno di aiuto per rimuovere le etichette da un graphlet in JSL

Grazie a tutti per il vostro aiuto.

Funziona bene:)

- Predicatore