846357_zh-TW

liliconcom

使用 JSL 連線所需點

如附圖所示，我想在圖形產生器中用一條線連接所需的座標值。

有人知道怎麼做嗎？

我想在PCB上表達尺度的變化，請告訴我如何用上述方式表達。

數據探索與視覺化實驗設計大規模客製化回覆：使用 JSL 連線所需點

如附圖所示，我想在圖形產生器中連接到所需的座標值線，

有人知道怎麼做嗎？



我想在PCB上表達尺度的變化，但請給我一個按照上述方式表達的方法。

回覆：使用 JSL 連線所需點

歡迎來到 JMP 社群。

您想以互動方式還是使用 JSL 來執行此操作？

互動方式

您可以使用註釋工具繪製線條、多邊形、圓形等。

您也可以右鍵單擊圖形視窗並選擇自訂

並添加線條、矩形等。

使用 JSL

上面的最後一個例子實際上是一種從互動式使用到使用 JSL 編寫腳本的方法。如果您正在尋找的是 JSL 解決方案，JMP 提供了一整套圖形基元，可用於繪製您需要的任何線條、物件、文字等。

圖錶框

有一個名為圖形框 (Graph Box) 的顯示對象，其目的是提供一個空白的顯示框來繪製任何想要的內容。

Names Default To Here( 1 );
New Window( "Example",
	Graph Box(
		Frame Size( 300, 300 ),
		Marker( Marker State( 3 ), [11 44 77], [75 25 50] );
		Pen Color( "Blue" );
		Line( [10 30 70], [88 22 44] );
	)
);

新增圖形腳本

JMP 也可以透過 JSL 將圖形新增到任何 JMP 平台的任何圖形輸出中。 Graph Builder 是 JMP 平台之一。

names default to here( 1 );
dt =
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

gb = Graph Builder(
	Variables( X( :weight ), Y( :height ) ),
	Elements( Points( X, Y, Legend( 3 ) ) ),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				3,
				Properties( 0, {Line Color( 2 )}, Item ID( "height", 1 ) )
			)}
		)
	)
);

framebox = report(gb)[frame box( 1 )];
framebox << Add Graphics Script(
	Transparency( 0.5 );
	Fill Color( {1.0, 0.5, 0.0} );
	Polygon( [60, 72, 57], [75, 120, 120] );
	
	Pen size( 3 );
	pen color ( 1 );
	line( {80,60}, {140,65});
);

回覆：使用 JSL 連線所需點

我將根據您之前對其他人的問題的回答再次向您提問。

我想把下面數據中的點以封閉的正方形連接起來，連接相同的四邊形。
如果有辦法的話請告訴我。

我想將類別項目疊加在一張圖表上，以顯示規模縮小了多少。

類別	四人	觀點	小路	X	Y
電腦輔助設計	問題 1	1	4	492.35	489.45
電腦輔助設計	問題 1	2	3	492.35	267.65
電腦輔助設計	問題 1	3	1	265.15	489.45
電腦輔助設計	問題 1	4	2	265.15	267.65
電腦輔助設計	第二季	5	4	492.35	247.35
電腦輔助設計	第二季	6	3	492.35	25.55
電腦輔助設計	第二季	7	1	265.15	247.35
電腦輔助設計	第二季	8	2	265.15	25.55
電腦輔助設計	第三季	9	4	244.85	489.45
電腦輔助設計	第三季	10	3	244.85	267.65
電腦輔助設計	第三季	11	1	17.65	489.45
電腦輔助設計	第三季	12	2	17.65	267.65
電腦輔助設計	Q4	十三	4	244.85	247.35
電腦輔助設計	Q4	14	3	244.85	25.55
電腦輔助設計	Q4	15	1	17.65	247.35
電腦輔助設計	Q4	16	2	17.65	25.55
木板	問題 1	1	4	492.336	489.438
木板	問題 1	2	3	492.339	267.64
木板	問題 1	3	1	265.143	489.445
木板	問題 1	4	2	265.149	267.649
木板	第二季	5	4	492.341	247.342
木板	第二季	6	3	492.352	25.544
木板	第二季	7	1	265.15	247.351
木板	第二季	8	2	265.159	25.554
木板	第三季	9	4	244.843	489.446
木板	第三季	10	3	244.85	267.65
木板	第三季	11	1	17.646	489.455
木板	第三季	12	2	17.657	267.658
木板	Q4	十三	4	244.851	247.352
木板	Q4	14	3	244.859	25.555
木板	Q4	15	1	17.658	247.359
木板	Q4	16	2	17.666	25.561
曝露	問題 1	1	4	492.339	489.441
曝露	問題 1	2	3	492.337	267.644
曝露	問題 1	3	1	265.146	489.442
曝露	問題 1	4	2	265.144	267.646
曝露	第二季	5	4	492.347	247.346
曝露	第二季	6	3	492.347	25.55
曝露	第二季	7	1	265.154	247.346
曝露	第二季	8	2	265.154	25.55
曝露	第三季	9	4	244.845	489.45
曝露	第三季	10	3	244.845	267.654
曝露	第三季	11	1	17.653	489.45
曝露	第三季	12	2	17.652	267.654
曝露	Q4	十三	4	244.855	247.355
曝露	Q4	14	3	244.855	25.559
曝露	Q4	15	1	17.662	247.354
曝露	Q4	16	2	17.662	25.558

回覆：使用 JSL 連線所需點

以下是使用您的資料並在 Graph Builder 上以線條形式顯示的範例

以下是使用圖形框顯示的數據

Names Default To Here( 1 );
dt = Current Data Table();

dt << Sort(
	By( :category, :Quad, :Path ),
	Order( Ascending, Ascending, Descending ),
	Replace Table( 1 )
);

dtPoly = dt << summary( group( :category, :quad ), link to original table(0) );

New Window( "Example",
	Graph Box(
		Frame Size( 300, 300 ),
		X Scale( Col Min( dt:x ) - 50, Col Max( dt:x ) + 50 ),
		Y Scale( Col Min( dt:y ) - 50, Col Max( dt:y ) + 50 ),
		Pen Color( "Black" );
		For( i = 1, i <= N Rows( dtPoly ), i++,
			theRows = dt << get rows where(
				dt:category == dtPoly:category[i] & dt:quad == dtPoly:quad[i]
			);
			theRows = theRows |/ Matrix( theRows[1] );
			Line( dt:X[theRows], dt:Y[theRows] );
		);
	)
);

我不確定你具體在尋找什麼。