846357_de-DE

liliconcom

Verbinden Sie die gewünschten Punkte mit JSL

Wie im angehängten Bild dargestellt, möchte ich im Graph Builder die gewünschten Koordinatenwerte mit einer Linie verbinden.

Weiß jemand, wie das geht?

Ich möchte Maßstabsänderungen auf der Leiterplatte ausdrücken. Sagen Sie mir also bitte, wie ich dies auf die oben beschriebene Weise ausdrücken kann.

Datenexploration und -visualisierungVersuchsplanungMassenanpassungBetreff: Gewünschte Punkte mit JSL verbinden

Wie im beigefügten Bild gezeigt, möchte ich im Graph Builder eine Verbindung zu der gewünschten Koordinatenwertlinie herstellen.

Weiß jemand, wie das geht?



Ich möchte die Maßstabsänderung auf der Leiterplatte ausdrücken, aber geben Sie mir bitte eine Möglichkeit, dies auf die oben beschriebene Weise auszudrücken.

Betreff: Gewünschte Punkte mit JSL verbinden

Willkommen in der JMP-Community.

Möchten Sie dies interaktiv oder mit JSL tun?

Interaktiv

Mit den Anmerkungswerkzeugen können Sie Linien, Polygone, Kreise usw. zeichnen.

Sie können auch mit der rechten Maustaste auf das Diagrammfenster klicken und „Anpassen“ auswählen.

und fügen Sie Linien, Rechtecke usw. hinzu.

Verwenden von JSL

Das obige letzte Beispiel ist eigentlich eine Methode, die von der interaktiven Nutzung zum Schreiben eines Skripts mit JSL überbrückt. Wenn Sie nach einer JSL-Lösung suchen, bietet JMP einen vollständigen Satz grafischer Grundelemente, mit denen Sie beliebige Linien, Objekte, Texte usw. zeichnen können.

Diagrammbox

Es gibt ein Anzeigeobjekt namens „Graph Box“, dessen Zweck darin besteht, einen leeren Anzeigerahmen bereitzustellen, in dem man alles zeichnen kann, was man möchte.

Names Default To Here( 1 );
New Window( "Example",
	Graph Box(
		Frame Size( 300, 300 ),
		Marker( Marker State( 3 ), [11 44 77], [75 25 50] );
		Pen Color( "Blue" );
		Line( [10 30 70], [88 22 44] );
	)
);

Grafikskript hinzufügen

JMP bietet außerdem die Möglichkeit, über JSL Grafiken zu allen grafischen Ausgaben aller JMP-Plattformen hinzuzufügen. Graph Builder ist eine dieser JMP-Plattformen.

names default to here( 1 );
dt =
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

gb = Graph Builder(
	Variables( X( :weight ), Y( :height ) ),
	Elements( Points( X, Y, Legend( 3 ) ) ),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				3,
				Properties( 0, {Line Color( 2 )}, Item ID( "height", 1 ) )
			)}
		)
	)
);

framebox = report(gb)[frame box( 1 )];
framebox << Add Graphics Script(
	Transparency( 0.5 );
	Fill Color( {1.0, 0.5, 0.0} );
	Polygon( [60, 72, 57], [75, 120, 120] );
	
	Pen size( 3 );
	pen color ( 1 );
	line( {80,60}, {140,65});
);

Betreff: Gewünschte Punkte mit JSL verbinden

Ich werde Ihnen basierend auf Ihrer vorherigen Antwort auf die Frage einer anderen Person noch einmal eine Frage stellen.

Ich möchte die Punkte in den folgenden Daten in einer geschlossenen quadratischen Form verbinden und dabei dieselben Quads verbinden.
Wenn es eine Möglichkeit gibt, lassen Sie es mich bitte wissen.

Und ich möchte die Kategorieelemente in einem Diagramm überlagern, um anzuzeigen, wie stark der Maßstab verkleinert wurde.

Kategorie	Quad	Punkt	Weg	X	Y
CAD	Frage 1	1	4	492,35	489,45
CAD	Frage 1	2	3	492,35	267,65
CAD	Frage 1	3	1	265,15	489,45
CAD	Frage 1	4	2	265,15	267,65
CAD	Fragebogen	5	4	492,35	247,35
CAD	Fragebogen	6	3	492,35	25,55
CAD	Fragebogen	7	1	265,15	247,35
CAD	Fragebogen	8	2	265,15	25,55
CAD	Drittes Quartal	9	4	244,85	489,45
CAD	Drittes Quartal	10	3	244,85	267,65
CAD	Drittes Quartal	11	1	17,65	489,45
CAD	Drittes Quartal	12	2	17,65	267,65
CAD	Viertes Quartal	13	4	244,85	247,35
CAD	Viertes Quartal	14	3	244,85	25,55
CAD	Viertes Quartal	15	1	17,65	247,35
CAD	Viertes Quartal	16	2	17,65	25,55
Planke	Frage 1	1	4	492.336	489.438
Planke	Frage 1	2	3	492.339	267,64
Planke	Frage 1	3	1	265.143	489.445
Planke	Frage 1	4	2	265.149	267.649
Planke	Fragebogen	5	4	492.341	247.342
Planke	Fragebogen	6	3	492.352	25.544
Planke	Fragebogen	7	1	265,15	247.351
Planke	Fragebogen	8	2	265.159	25.554
Planke	Drittes Quartal	9	4	244.843	489.446
Planke	Drittes Quartal	10	3	244,85	267,65
Planke	Drittes Quartal	11	1	17.646	489.455
Planke	Drittes Quartal	12	2	17.657	267.658
Planke	Viertes Quartal	13	4	244.851	247.352
Planke	Viertes Quartal	14	3	244.859	25.555
Planke	Viertes Quartal	15	1	17.658	247.359
Planke	Viertes Quartal	16	2	17.666	25.561
Belichtung	Frage 1	1	4	492.339	489.441
Belichtung	Frage 1	2	3	492.337	267.644
Belichtung	Frage 1	3	1	265.146	489.442
Belichtung	Frage 1	4	2	265.144	267.646
Belichtung	Fragebogen	5	4	492.347	247.346
Belichtung	Fragebogen	6	3	492.347	25,55
Belichtung	Fragebogen	7	1	265.154	247.346
Belichtung	Fragebogen	8	2	265.154	25,55
Belichtung	Drittes Quartal	9	4	244.845	489,45
Belichtung	Drittes Quartal	10	3	244.845	267.654
Belichtung	Drittes Quartal	11	1	17.653	489,45
Belichtung	Drittes Quartal	12	2	17.652	267.654
Belichtung	Viertes Quartal	13	4	244.855	247.355
Belichtung	Viertes Quartal	14	3	244.855	25.559
Belichtung	Viertes Quartal	15	1	17.662	247.354
Belichtung	Viertes Quartal	16	2	17.662	25.558

Betreff: Gewünschte Punkte mit JSL verbinden

Hier ist ein Beispiel, in dem Ihre Daten verwendet und in Linien im Graph Builder angezeigt werden

Hier werden Ihre Daten mithilfe einer Diagrammbox angezeigt

Names Default To Here( 1 );
dt = Current Data Table();

dt << Sort(
	By( :category, :Quad, :Path ),
	Order( Ascending, Ascending, Descending ),
	Replace Table( 1 )
);

dtPoly = dt << summary( group( :category, :quad ), link to original table(0) );

New Window( "Example",
	Graph Box(
		Frame Size( 300, 300 ),
		X Scale( Col Min( dt:x ) - 50, Col Max( dt:x ) + 50 ),
		Y Scale( Col Min( dt:y ) - 50, Col Max( dt:y ) + 50 ),
		Pen Color( "Black" );
		For( i = 1, i <= N Rows( dtPoly ), i++,
			theRows = dt << get rows where(
				dt:category == dtPoly:category[i] & dt:quad == dtPoly:quad[i]
			);
			theRows = theRows |/ Matrix( theRows[1] );
			Line( dt:X[theRows], dt:Y[theRows] );
		);
	)
);

Ich bin nicht sicher, wonach Sie konkret suchen.