844982_zh-TW

liliconcom

如何取得分組列的偏度和峰度並與另一列資料進行繪圖？

如何使用下列資料繪製所有製程相對於「批次 ID 中的晶圓 ID」的偏度和峰度（在 y 軸上）？

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

該數據集與我的實際數據集相似，因此可以達到目的。

我知道如何透過分銷平台互動地獲取偏度和峰度，但無法透過「製作組合資料表」來取得「批次 ID 中的晶圓 ID」對應的數字。如何透過 JSL 做到這一點？

自動化和腳本基礎資料分析與建模回覆：如何取得分組列的偏度和峰度並與另一列資料進行繪圖？

製作組合數據表對我來說似乎運作得很好。 JMP 建立腳本

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

rpt = New Window("Semiconductor Capability - Distribution 2",
	Data Table("Semiconductor Capability") <<
	Distribution(
		Continuous Distribution(
			Column(:NPN1),
			Customize Summary Statistics(Skewness(1), Kurtosis(1)),
			Process Capability(0)
		),
		By(:lot_id)
	)
);
Wait(0);
rpt["Distributions", "lot_id=lot01", "NPN1", "Summary Statistics", Table Box(1)] <<
Make Combined Data Table;
rpt << Close Window;

回覆：如何取得分組列的偏度和峰度並與另一列資料進行繪圖？

我可以透過 JSL 獲得所有流程的分佈、偏度和峰度等，但不知道如何在資料表和繪圖中根據「批次 ID 中的晶圓 ID」取得這些資訊。這裡需要一些指導。

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
dist = dt << Distribution(
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
);

回覆：如何取得分組列的偏度和峰度並與另一列資料進行繪圖？

以下是我的處理方法

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),<BR />        // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;

回覆：如何取得分組列的偏度和峰度並與另一列資料進行繪圖？

@txnelson這有效。謝謝。我想將 Cpk 和 Ppk (lot_id, wafer) 加入到組合資料表中。如何更新你的 JSL 來實現這一點？

（查看自動產生的 JSL，似乎需要為 Cpk 和 Ppk 選擇輪廓框）

回覆：如何取得分組列的偏度和峰度並與另一列資料進行繪圖？

你是對的，所要做的就是添加一個<<製作組合資料表語句，就像用於建立匯總統計資料表的語句一樣，但將其指向 Within Sigma 能力報告表或整體 Sigma 能力表。

Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;

當然，這假設腳本也已被修改以顯示製程能力報告。

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
		Process Capability( Use Column Property Specs ),       
		 // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;
Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;