844982_es-ES

liliconcom

¿Cómo obtener asimetría y curtosis para columnas agrupadas y graficarlas frente a los datos de otra columna?

¿Cómo puedo trazar la asimetría y la curtosis (en el eje y) para todos los procesos frente a la "ID de oblea en la ID de lote" utilizando los siguientes datos?

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

Este conjunto de datos es similar a mi conjunto de datos real, por lo que servirá para el propósito.

Sé cómo obtener la asimetría y la curtosis a través de la plataforma de distribución de forma interactiva, pero no puedo obtener los números en relación con el "ID de oblea en el ID de lote" a través de "crear tabla de datos combinados". ¿Cómo puedo hacer esto a través de JSL?

Automatización y scriptingAnálisis y modelado de datos básicosRe: ¿Cómo obtener asimetría y curtosis para columnas agrupadas y graficarlas frente a los datos de otra columna?

La creación de una tabla de datos combinados parece funcionar bien para mí. Script creado por JMP

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

rpt = New Window("Semiconductor Capability - Distribution 2",
	Data Table("Semiconductor Capability") <<
	Distribution(
		Continuous Distribution(
			Column(:NPN1),
			Customize Summary Statistics(Skewness(1), Kurtosis(1)),
			Process Capability(0)
		),
		By(:lot_id)
	)
);
Wait(0);
rpt["Distributions", "lot_id=lot01", "NPN1", "Summary Statistics", Table Box(1)] <<
Make Combined Data Table;
rpt << Close Window;

Re: ¿Cómo obtener asimetría y curtosis para columnas agrupadas y graficarlas frente a los datos de otra columna?

Puedo obtener la distribución, asimetría y curtosis, etc. para todos los procesos a través de JSL, pero no sé cómo obtener esto por "ID de oblea en ID de lote" en una tabla de datos y un gráfico. Necesito alguna orientación aquí.

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
dist = dt << Distribution(
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
);

Re: ¿Cómo obtener asimetría y curtosis para columnas agrupadas y graficarlas frente a los datos de otra columna?

Así es como yo manejaría esto

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),<BR />        // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;

Re: ¿Cómo obtener asimetría y curtosis para columnas agrupadas y graficarlas frente a los datos de otra columna?

@txnelson Esto funciona. Gracias. Me gustaría agregar Cpk y Ppk por (lot_id, wafer) en la tabla de datos combinados. ¿Cómo actualizo mi JSL para lograr esto?

(Al observar el JSL generado automáticamente para esto, parece que el cuadro de esquema debe seleccionarse para Cpk y Ppk)

Re: ¿Cómo obtener asimetría y curtosis para columnas agrupadas y graficarlas frente a los datos de otra columna?

Tiene razón, todo lo que hay que hacer es agregar una declaración << Crear tabla de datos combinados como la que se usó para crear la tabla de datos para las estadísticas de resumen, pero apúntela a la tabla de informe Capacidad dentro de Sigma o a la tabla Capacidad general de Sigma.

Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;

Por supuesto, esto supone que el script también se ha modificado para mostrar los informes de capacidad del proceso.

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
		Process Capability( Use Column Property Specs ),       
		 // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;
Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;