844982_zh-CN

liliconcom

如何获取分组列的偏度和峰度并与另一列数据进行绘图？

如何使用以下数据绘制所有工艺相对于“批次 ID 中的晶圆 ID”的偏度和峰度（在 y 轴上）？

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

该数据集与我的实际数据集相似，因此可以达到目的。

我知道如何通过分销平台以交互方式获取偏度和峰度，但无法通过“制作组合数据表”获取“批次 ID 中的晶圆 ID”对应的数字。如何通过 JSL 做到这一点？

自动化和脚本基础数据分析与建模回复：如何获取分组列的偏度和峰度并与另一列数据进行绘图？

制作组合数据表对我来说似乎很好用。JMP 创建脚本

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

rpt = New Window("Semiconductor Capability - Distribution 2",
	Data Table("Semiconductor Capability") <<
	Distribution(
		Continuous Distribution(
			Column(:NPN1),
			Customize Summary Statistics(Skewness(1), Kurtosis(1)),
			Process Capability(0)
		),
		By(:lot_id)
	)
);
Wait(0);
rpt["Distributions", "lot_id=lot01", "NPN1", "Summary Statistics", Table Box(1)] <<
Make Combined Data Table;
rpt << Close Window;

回复：如何获取分组列的偏度和峰度并与另一列数据进行绘图？

我可以通过 JSL 获取所有工艺的分布、偏度和峰度等，但不知道如何在数据表和图中按“批次 ID 中的晶圆 ID”获取这些信息。这里需要一些指导。

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
dist = dt << Distribution(
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
);

回复：如何获取分组列的偏度和峰度并与另一列数据进行绘图？

以下是我的处理方法

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),<BR />        // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;

回复：如何获取分组列的偏度和峰度并与另一列数据进行绘图？

@txnelson这有效。谢谢。我想将 Cpk 和 Ppk (lot_id, wafer) 添加到组合数据表中。如何更新您的 JSL 来实现这一点？

（查看自动生成的 JSL，似乎需要为 Cpk 和 Ppk 选择轮廓框）

回复：如何获取分组列的偏度和峰度并与另一列数据进行绘图？

你是对的，所要做的就是添加一个<<制作组合数据表语句，就像用于创建汇总统计数据表的语句一样，但将其指向 Within Sigma 能力报告表或整体 Sigma 能力表。

Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;

当然，这假设脚本也已被修改以显示过程能力报告。

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
		Process Capability( Use Column Property Specs ),       
		 // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;
Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;