844982_ko-KR

liliconcom

그룹화된 열과 플롯과 다른 열 데이터의 왜도와 첨도를 구하는 방법은 무엇입니까?

다음 데이터를 사용하여 "로트 ID의 웨이퍼 ID"에 대한 모든 프로세스의 왜도와 첨도(y축)를 어떻게 표시합니까?

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

이 데이터 세트는 실제 데이터 세트와 유사하므로 목적에 부합합니다.

분포 플랫폼을 통해 비대칭도와 첨도를 대화형으로 얻는 방법은 알지만 "결합된 데이터 테이블 만들기"를 통해 "로트 ID의 웨이퍼 ID"에 대한 숫자를 얻을 수 없습니다. JSL을 통해 이를 수행하는 방법은 무엇입니까?

자동화 및 스크립팅기본 데이터 분석 및 모델링Re: 그룹화된 열과 플롯과 다른 열 데이터의 왜도와 첨도를 구하는 방법은 무엇인가요?

Make Combined Data table이 제게는 잘 작동하는 것 같습니다. JMP에서 스크립트를 생성했습니다.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

rpt = New Window("Semiconductor Capability - Distribution 2",
	Data Table("Semiconductor Capability") <<
	Distribution(
		Continuous Distribution(
			Column(:NPN1),
			Customize Summary Statistics(Skewness(1), Kurtosis(1)),
			Process Capability(0)
		),
		By(:lot_id)
	)
);
Wait(0);
rpt["Distributions", "lot_id=lot01", "NPN1", "Summary Statistics", Table Box(1)] <<
Make Combined Data Table;
rpt << Close Window;

Re: 그룹화된 열과 플롯과 다른 열 데이터의 왜도와 첨도를 구하는 방법은 무엇인가요?

JSL을 통해 모든 프로세스에 대한 분포, 왜도, 첨도 등을 얻을 수 있지만 데이터 테이블과 플롯에서 "로트 ID의 웨이퍼 ID"별로 이를 얻는 방법을 모릅니다. 여기서 약간의 지침이 필요합니다.

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
dist = dt << Distribution(
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
);

Re: 그룹화된 열과 플롯과 다른 열 데이터의 왜도와 첨도를 구하는 방법은 무엇인가요?

내가 이걸 처리할 방법은 다음과 같습니다.

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),<BR />        // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;

Re: 그룹화된 열과 플롯과 다른 열 데이터의 왜도와 첨도를 구하는 방법은 무엇인가요?

@txnelson 이게 효과가 있네요. 감사합니다. 결합된 데이터 테이블에 Cpk와 Ppk를 (lot_id, wafer)로 추가하고 싶습니다. 이를 달성하기 위해 JSL을 어떻게 업데이트해야 하나요?

(이를 위해 자동 생성된 JSL을 살펴보면 Cpk 및 Ppk에 대해 Outline Box를 선택해야 하는 것 같습니다)

Re: 그룹화된 열과 플롯과 다른 열 데이터의 왜도와 첨도를 구하는 방법은 무엇인가요?

맞습니다. 해야 할 일은 요약 통계의 데이터 테이블을 만드는 데 사용한 것과 똑같은 << 결합된 데이터 테이블 만들기 명령문을 추가하는 것뿐입니다. 하지만 이를 시그마 역량 내 보고서 테이블이나 전체 시그마 역량 표를 가리키도록 지정하면 됩니다.

Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;

물론 이는 스크립트가 프로세스 능력 보고서를 표시하도록 수정되었다는 것을 전제로 합니다.

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
		Process Capability( Use Column Property Specs ),       
		 // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;
Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;