844982_ja-JP

liliconcom

グループ化された列の歪度と尖度を取得し、別の列のデータと比較してプロットするにはどうすればよいですか?

次のデータを使用して、すべてのプロセスと「ロット ID 内のウェーハ ID」の歪度と尖度 (y 軸) をプロットするにはどうすればよいですか?

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

このデータ セットは私の実際のデータ セットに似ているため、目的にかなうでしょう。

配布プラットフォームを介して対話的に歪度と尖度を取得する方法はわかっていますが、「結合データ テーブルの作成」を介して「ロット ID 内のウェーハ ID」に対する数値を取得できません。JSL でこれを行うにはどうすればよいでしょうか?

自動化とスクリプト基本的なデータ分析とモデリングRe: グループ化された列の歪度と尖度を取得し、別の列のデータと比較してプロットするにはどうすればよいですか?

結合データテーブルの作成は私にとってはうまく機能しているようです。JMPが作成したスクリプト

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

rpt = New Window("Semiconductor Capability - Distribution 2",
	Data Table("Semiconductor Capability") <<
	Distribution(
		Continuous Distribution(
			Column(:NPN1),
			Customize Summary Statistics(Skewness(1), Kurtosis(1)),
			Process Capability(0)
		),
		By(:lot_id)
	)
);
Wait(0);
rpt["Distributions", "lot_id=lot01", "NPN1", "Summary Statistics", Table Box(1)] <<
Make Combined Data Table;
rpt << Close Window;

Re: グループ化された列の歪度と尖度を取得し、別の列のデータと比較してプロットするにはどうすればよいですか?

JSL を介してすべてのプロセスの分布、歪度、尖度などを取得できますが、これを「ロット ID 内のウェーハ ID」ごとにデータ テーブルとプロットに出力する方法がわかりません。何らかの指示が必要です。

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
dist = dt << Distribution(
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
);

Re: グループ化された列の歪度と尖度を取得し、別の列のデータと比較してプロットするにはどうすればよいですか?

私はこう対処します

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),<BR />        // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;

Re: グループ化された列の歪度と尖度を取得し、別の列のデータと比較してプロットするにはどうすればよいですか?

翻訳者これはうまくいきました。ありがとうございます。結合データ テーブルに (lot_id、ウェハー) による Cpk と Ppk を追加したいと思います。これを実現するには、JSL をどのように更新すればよいでしょうか。

(これに対して自動生成された JSL を見ると、Cpk と Ppk に対してアウトライン ボックスを選択する必要があるようです)

Re: グループ化された列の歪度と尖度を取得し、別の列のデータと比較してプロットするにはどうすればよいですか?

おっしゃる通り、必要なのは、要約統計のデータ テーブルを作成するために使用したのと同じ << Make Combined Data Table ステートメントを追加することだけです。ただし、そのステートメントを Within Sigma Capability レポート テーブルまたは Overall Sigma Capability テーブルにポイントします。

Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;

もちろん、これは、スクリプトがプロセス能力レポートを表示するように変更されていることも前提としています。

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
		Process Capability( Use Column Property Specs ),       
		 // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;
Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;