844982_de-DE

liliconcom

Wie erhält man Schiefe und Kurtosis für gruppierte Spalten und stellt sie im Vergleich zu anderen Spaltendaten dar?

Wie stelle ich anhand der folgenden Daten die Schiefe und Kurtosis (auf der Y-Achse) für alle Prozesse im Vergleich zur „Wafer-ID in der Lot-ID“ dar?

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

Dieser Datensatz ähnelt meinem tatsächlichen Datensatz und erfüllt daher seinen Zweck.

Ich weiß, wie ich die Schiefe und Kurtosis interaktiv über die Verteilungsplattform ermitteln kann, kann die Zahlen aber nicht über „Kombinierte Datentabelle erstellen“ für „Wafer-ID in Lot-ID“ ermitteln. Wie geht das über JSL?

Automatisierung und SkriptingGrundlegende Datenanalyse und ModellierungBetreff: Wie erhält man Schiefe und Kurtosis für gruppierte Spalten und stellt sie im Vergleich zu anderen Spaltendaten dar?

Die Erstellung einer kombinierten Datentabelle scheint bei mir gut zu funktionieren. Mit JMP erstelltes Skript

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

rpt = New Window("Semiconductor Capability - Distribution 2",
	Data Table("Semiconductor Capability") <<
	Distribution(
		Continuous Distribution(
			Column(:NPN1),
			Customize Summary Statistics(Skewness(1), Kurtosis(1)),
			Process Capability(0)
		),
		By(:lot_id)
	)
);
Wait(0);
rpt["Distributions", "lot_id=lot01", "NPN1", "Summary Statistics", Table Box(1)] <<
Make Combined Data Table;
rpt << Close Window;

Betreff: Wie erhält man Schiefe und Kurtosis für gruppierte Spalten und stellt sie im Vergleich zu anderen Spaltendaten dar?

Ich kann die Verteilung, Schiefe und Kurtosis usw. für alle Prozesse über JSL abrufen, weiß aber nicht, wie ich dies pro „Wafer-ID in Lot-ID“ in eine Datentabelle und ein Diagramm bekomme. Brauche hier eine Anleitung.

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
dist = dt << Distribution(
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
);

Betreff: Wie erhält man Schiefe und Kurtosis für gruppierte Spalten und stellt sie im Vergleich zu anderen Spaltendaten dar?

So würde ich damit umgehen

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),<BR />        // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;

Betreff: Wie erhält man Schiefe und Kurtosis für gruppierte Spalten und stellt sie im Vergleich zu anderen Spaltendaten dar?

@txnelson Das funktioniert. Danke. Ich möchte Cpk und Ppk nach (lot_id, wafer) in die kombinierte Datentabelle einfügen. Wie aktualisiere ich mein JSL, um dies zu erreichen?

(Wenn man sich das automatisch generierte JSL hierfür ansieht, scheint es, dass die Outline-Box für Cpk und Ppk ausgewählt werden muss)

Betreff: Wie erhält man Schiefe und Kurtosis für gruppierte Spalten und stellt sie im Vergleich zu anderen Spaltendaten dar?

Sie haben Recht. Alles, was getan werden muss, ist, eine Anweisung << „Kombinierte Datentabelle erstellen“ hinzuzufügen, genau wie die, die zum Erstellen der Datentabelle für die zusammenfassenden Statistiken verwendet wurde, aber verweisen Sie damit auf die Berichtstabelle „Innerhalb der Sigma-Fähigkeit“ oder auf die Tabelle „Gesamt-Sigma-Fähigkeit“.

Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;

Dies setzt natürlich voraus, dass das Skript auch so geändert wurde, dass die Prozessfähigkeitsberichte angezeigt werden.

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
		Process Capability( Use Column Property Specs ),       
		 // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;
Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;