844982_fr-FR

liliconcom

Comment obtenir l'asymétrie et la kurtose pour les colonnes groupées et tracer par rapport aux données d'une autre colonne ?

Comment tracer l'asymétrie et la kurtosis (sur l'axe des Y) pour tous les processus par rapport à « l'ID de plaquette dans l'ID de lot » à l'aide des données suivantes ?

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

Cet ensemble de données est similaire à mon ensemble de données réel, il fera donc l'affaire.

Je sais comment obtenir l'asymétrie et la courbure via la plateforme de distribution de manière interactive, mais je ne parviens pas à obtenir les chiffres par rapport à « ID de plaquette dans l'ID de lot » via « Créer un tableau de données combiné ». Comment faire cela via JSL ?

Automatisation et scriptsAnalyse et modélisation de données de baseRe : Comment obtenir l'asymétrie et la kurtosis pour les colonnes groupées et tracer par rapport aux données d'une autre colonne ?

Créer un tableau de données combinées semble bien fonctionner pour moi. Script créé par JMP

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

rpt = New Window("Semiconductor Capability - Distribution 2",
	Data Table("Semiconductor Capability") <<
	Distribution(
		Continuous Distribution(
			Column(:NPN1),
			Customize Summary Statistics(Skewness(1), Kurtosis(1)),
			Process Capability(0)
		),
		By(:lot_id)
	)
);
Wait(0);
rpt["Distributions", "lot_id=lot01", "NPN1", "Summary Statistics", Table Box(1)] <<
Make Combined Data Table;
rpt << Close Window;

Re : Comment obtenir l'asymétrie et la kurtosis pour les colonnes groupées et tracer par rapport aux données d'une autre colonne ?

Je peux obtenir la distribution, l'asymétrie et la kurtosis, etc. pour tous les processus via JSL, mais je ne sais pas comment obtenir cela par « ID de plaquette dans l'ID de lot » dans une table de données et un graphique. J'ai besoin d'une direction ici.

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
dist = dt << Distribution(
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
);

Re : Comment obtenir l'asymétrie et la kurtosis pour les colonnes groupées et tracer par rapport aux données d'une autre colonne ?

Voici comment je gérerais cela

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),<BR />        // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;

Re : Comment obtenir l'asymétrie et la kurtosis pour les colonnes groupées et tracer par rapport aux données d'une autre colonne ?

@txnelson Cela fonctionne. Merci. Je voudrais ajouter Cpk et Ppk par (lot_id, wafer) dans la table de données combinées. Comment mettre à jour votre JSL pour y parvenir ?

(en regardant le JSL généré automatiquement pour cela, il semble que la boîte de contour doit être sélectionnée pour Cpk et Ppk)

Re : Comment obtenir l'asymétrie et la kurtosis pour les colonnes groupées et tracer par rapport aux données d'une autre colonne ?

Vous avez raison, tout ce qui doit être fait est d'ajouter une instruction << Make Combined Data Table (Créer un tableau de données combiné) identique à celle utilisée pour créer le tableau de données pour les statistiques récapitulatives, mais en le pointant vers le tableau de rapport Within Sigma Capability (Dans les capacités Sigma) ou vers le tableau Comprehensive Sigma Capability (Capacité Sigma globale).

Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;

Cela suppose bien sûr que le script a également été modifié pour afficher les rapports de capacité de processus.

Names Default To Here(1);
Clear Log(); 
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");
cnames = dt << get column names( string, continuous );
// for simplicity, only use 5 of the columns
remove from(cnames,6,nitems(cnames));
//col_names = dt << get column group ("Processes");
cnames = cnames[1::N Items (cnames)];
// Use the invisible element to hide output.  
dist = dt << Distribution(invisible,
            Columns(evalList(cnames)),
		    Summary Statistics(1),
		    Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
		Process Capability( Use Column Property Specs ),       
		 // Add a By group to get results for each wafer within each lot
		by(lot_id,wafer)
);
current report()["Summary Statistics", Table Box( 1 )] << Make Combined Data Table;
Current Report()["Within Sigma Capability", Table Box( 1 )] << Make Combined Data Table;