844055_es-ES

liliconcom

Creación de fórmulas de tablas de datos en tiempo de ejecución con JSL

De vez en cuando me encuentro con este problema y no he encontrado una solución que me satisfaga, así que me pregunto qué han hecho otras personas. Supongamos que el nombre de la columna y los valores de fórmula adicionales no se conocen hasta el momento de la ejecución. Como ejemplo simple, supongamos que quiero crear una fórmula que multiplique una columna por un valor proporcionado por el usuario.

Esto no funciona:

buildFormula = Function({tblRef,colName,mult},
	exprOut = Substitute(
		Expr(col*mult),
		Expr(col),Column(tblRef,colName),
		Expr(mult),mult
	);
	Name Expr(exprOut);
);

outExpr = buildFormula(tbl,"Minimum Price ($1000)",3);

Eval(Substitute(
	Expr(tbl << New Column("New Formula Column",Formula(form))),
	Expr(form),Name Expr(outExpr)
));

Tampoco esto:

tbl = Open("$sample_data/cars 1993.JMP");

buildFormula = Function({colRef,mult},
	exprOut = Substitute(
		Expr(col*mult),
		Expr(col),colRef,
		Expr(mult),mult
	);
	Name Expr(exprOut);
);

outExpr = buildFormula(Column(tbl,"Minimum Price ($1000)"),Name Expr(fExpr));

Eval(Substitute(
	Expr(tbl << New Column("New Formula Column",Formula(form))),
	Expr(form),Name Expr(outExpr)
));

Aunque parece que funcionan si ingresas a la fórmula (hasta que haces clic en Evaluar), ¿me estoy perdiendo algo? He estado usando este enfoque.

tbl = Open("$sample_data/cars 1993.JMP");

buildFormula = Function({colRef,mult},
	exprOut = Substitute(
		Expr(col[Row()]*mult),
		Expr(col),colRef,
		Expr(mult),mult
	);
	Name Expr(exprOut);
);

outExpr = buildFormula(Column(tbl,"Minimum Price ($1000)"),3);

Eval(Substitute(
	Expr(tbl << New Column("New Formula Column",Formula(form))),
	Expr(form),Name Expr(outExpr)
));

Pero no me gusta tener que usar Fila() para que la fórmula se evalúe correctamente. ¿El comportamiento en los dos primeros scripts es un error?

Re: Creación de fórmulas de tablas de datos en tiempo de ejecución con JSL

¿Funcionaría algo como esto? No utiliza la función row(), pero tampoco lo hace exactamente como estás intentando. Lo tomé de esta página (que tengo en favoritos para cuando necesite hacer trabajo de tipo eval/expr).

tbl = Open( "$sample_data/cars 1993.JMP" );

buildFormula = Function( {colRef, mult},
	Eval(
		Eval Expr(
			tbl << New Column( "New Formula Column", Formula( as column (expr (colRef)) * expr (num(mult)) ) )
		)
	)
);

outExpr = buildFormula( Column( tbl, "Minimum Price ($1000)" ), 3 );

Re: Creación de fórmulas de tablas de datos en tiempo de ejecución con JSL

Gracias Jed,

Esto es útil, al igual que el enlace. Debería haber sido más claro en la descripción del problema. La evaluación de la fórmula no puede ser parte de la función. Planeo usar la expresión de la fórmula en otras partes del código, por lo que no quiero que se evalúe de inmediato.

Re: Creación de fórmulas de tablas de datos en tiempo de ejecución con JSL

Aquí hay un extracto de un código que escribí para Chris. Tengo que crear una fórmula a partir de otras fórmulas y asegurarme de que sea compatible con el generador de perfiles. El uso de un subíndice vacío en las referencias ayudó, pero causó otros problemas. No estoy seguro de lo que quieres hacer, pero espero que este fragmento te brinde algunas buenas ideas que puedas usar.

For( r = 1, r <= nResponses, r++,

	// convert a column reference to a column name for substitution

	Col Ref to Name = Function( {colref, qualified? = 0 },
		If( qualified?,
			Parse(Eval Insert("^colref << Get Data Table^:\!"^colref << Get Name^\!"n")),
			Parse(Eval Insert(":\!"^colref << Get Name^\!"n"))
		)
	);

	// create expected improvement column formula

	limits = Column( dt, y col[r] ) << Get Property( "Response Limits" );
	goal[r] = Char( limits["Goal"] );
	Match( goal[r],

		"Maximize",	// apply standard EI formula
			Eval(
				Substitute(
					Expr(
						ei = dt << New Column( y col[r] || " Expected Improvement", "Numeric", "Continuous",
							Formula(
								(:pppfff - yyy) * Normal Distribution( (:pppfff - yyy) / Sqrt( :vvvfff ))
								+ Sqrt( :vvvfff ) * Normal Density( (:pppfff - yyy) / Sqrt( :vvvfff ) )
							)
						)
					),
					Expr( vvvfff ), Col Ref To Name(vf),
					Expr( pppfff ), Col Ref To Name(pf),
					Expr( yyy ), refY[r] = predOptY[r]
				)
			),

		"Minimize",	// negate standard EI formula
			Eval(
				Substitute(
					Expr(
						ei = dt << New Column( y col[r] || " Expected Improvement", "Numeric", "Continuous",
							Formula(
								(yyy - :pppfff) * Normal Distribution( (yyy - :pppfff) / Sqrt( :vvvfff ))
								+ Sqrt( :vvvfff ) * Normal Density( (yyy - :pppfff) / Sqrt( :vvvfff ) )
							)						)
					),
					Expr( vvvfff ), Col Ref To Name(vf),
					Expr( pppfff ), Col Ref To Name(pf),
					Expr( yyy ), refY[r] = predOptY[r]
				)
			),

		"Match Target",	// apply joint EI formula
			Eval(
				Substitute(
					Expr(
						ei = dt << New Column( y col[r] || " Expected Improvement", "Numeric", "Continuous",
							Formula(
								deltaMin = Abs( ttt - yyy );
								deltaMin * (Normal Distribution( (deltaMin + ttt - :pppfff) / Sqrt( :vvvfff ) )
									- Normal Distribution( (-deltaMin + ttt - :pppfff) / Sqrt( :vvvfff ) )
								)
								+ Sqrt( :vvvfff ) * (
									Normal Density( (deltaMin + ttt - :pppfff) / Sqrt( :vvvfff ) )
									+ Normal Density( (-deltaMin + ttt - :pppfff) / Sqrt( :vvvfff ) )
									- 2 * Normal Density( ttt - :pppfff) / Sqrt( :vvvfff )
								)
								- (:pppfff - ttt) * (
									(Normal Distribution( (deltaMin + ttt - :pppfff)) / Sqrt( :vvvfff ) )
									+ Normal Distribution( (-deltaMin + ttt - :pppfff) / Sqrt( :vvvfff ) )
									- 2 * Normal Distribution( (ttt - :pppfff) / Sqrt( :vvvfff )  )
								)
			
							)
						)
					),
					Expr( vvvfff ), Col Ref To Name(vf),
					Expr( pppfff ), Col Ref To Name(pf),
					Expr( ttt ),
					target[r] = If( Contains( Char( limits ), "Middle" ),
						limits["Middle"],
						(limits["Lower"] + limits["Upper"]) / 2
					),
					Expr( yyy ),
					/*
					yDiff = (Column( dt, y col ) << Get as Matrix) - target[r];
					pDiff = (pf << Get As Matrix) - target[r];
					refY[r] = If( Min( Abs( yDiff ) ) < Min( Abs( pDiff ) ),
						Column( dt, y col )[Loc Min( Abs( yDiff ) )],
						pf[Loc Min( Abs( pDiff ) )]
					)
					*/
					predOptY[r]
				)
			),

		"None",	// unexpected condition
			Throw( "Disallowed: response with Goal of None" ),

		// unexpected condition

			gp << Close Window;
			dt << Delete Columns( { pf, vf } );
			Throw( "Disallowed: No response goal found. Response Limits column property is missing" )
	);

	ei	<< Set Property( "Response Limits", {Goal( Maximize ), Importance( 1 ), Show Limits( 0 )} )
		<< Hide( 1 );
	Wait( 0 );

	Eval(
		Substitute(
			Expr(
				Insert Into( utilityCols, eee, iii );
			),
			Expr( eee ), Eval( ei ),
			Expr( iii ), 3*(r-1) + 1
		)
	);
);

Re: Creación de fórmulas de tablas de datos en tiempo de ejecución con JSL

Parece que seguí un camino similar al de Mark. Puedes construir la fórmula como una cadena y luego evaluar insert() y eval( parse() ) cuando estés listo para aplicarla a la columna. ¿Funcionaría esto para tu script?

tbl = Open("$sample_data/cars 1993.JMP");
colName = "Minimum Price ($1000)";
mult = 3;

formulaString = ":\!"^colName^\!"n * ^mult^";
formula = eval insert( formulaString );

newColumnString = "^tbl^ << new column( \!"New Formula\!", formula( ^formula^ ) )";
newColumn = eval insert( newColumnString );
eval( parse( newColumn ) );

Re: Creación de fórmulas de tablas de datos en tiempo de ejecución con JSL

Hace años, cuando hablé con @JosephMorgan sobre este tipo de cosas, desaconsejó enfáticamente el uso de la concatenación o sustitución de cadenas e indicó que todo se podía lograr mediante el manejo de expresiones con la excepción de una cosa que no recuerdo y que tal vez ya no sea un problema. El uso de cadenas hace que el código sea mucho más difícil de leer y mantener. Probablemente haya otras razones más fundamentales, pero no las recuerdo.

Resulta que hay una solución sencilla usando la función Como ámbito() (gracias a @brady_brady )

 </CODE></PRE>
<PRE><CODE class=" language-jsl">tbl = Open("$sample_data/cars 1993.JMP");

buildFormula = Function({colRef,mult},
	exprOut = Substitute(
		Expr(col*mult),
		Expr(col),Name Expr(As Scoped(colRef)),
		Expr(mult),mult
	);
	Name Expr(exprOut);
);

outExpr = buildFormula(Column(tbl,"Minimum Price ($1000)"),3);

Eval(Substitute(
	Expr(tbl << New Column("New Formula Column",Formula(form))),
	Expr(form),Name Expr(outExpr)
));<BR />