844055_fr-FR

liliconcom

Création de formules de table de données d'exécution avec JSL

Je rencontre ce problème de temps en temps et je n'ai pas trouvé de solution qui me convienne, alors je me demande ce que les autres ont fait. Supposons que le nom de la colonne et les valeurs de formule supplémentaires ne soient pas connus avant l'exécution. À titre d'exemple simple, supposons que je souhaite créer une formule qui multiplie une colonne par une valeur fournie par l'utilisateur.

Cela ne fonctionne pas :

buildFormula = Function({tblRef,colName,mult},
	exprOut = Substitute(
		Expr(col*mult),
		Expr(col),Column(tblRef,colName),
		Expr(mult),mult
	);
	Name Expr(exprOut);
);

outExpr = buildFormula(tbl,"Minimum Price ($1000)",3);

Eval(Substitute(
	Expr(tbl << New Column("New Formula Column",Formula(form))),
	Expr(form),Name Expr(outExpr)
));

Ce n'est pas non plus le cas :

tbl = Open("$sample_data/cars 1993.JMP");

buildFormula = Function({colRef,mult},
	exprOut = Substitute(
		Expr(col*mult),
		Expr(col),colRef,
		Expr(mult),mult
	);
	Name Expr(exprOut);
);

outExpr = buildFormula(Column(tbl,"Minimum Price ($1000)"),Name Expr(fExpr));

Eval(Substitute(
	Expr(tbl << New Column("New Formula Column",Formula(form))),
	Expr(form),Name Expr(outExpr)
));

même si cela semble fonctionner si vous entrez dans la formule (jusqu'à ce que vous cliquiez sur Évaluer). Ai-je raté quelque chose ? J'ai utilisé cette approche

tbl = Open("$sample_data/cars 1993.JMP");

buildFormula = Function({colRef,mult},
	exprOut = Substitute(
		Expr(col[Row()]*mult),
		Expr(col),colRef,
		Expr(mult),mult
	);
	Name Expr(exprOut);
);

outExpr = buildFormula(Column(tbl,"Minimum Price ($1000)"),3);

Eval(Substitute(
	Expr(tbl << New Column("New Formula Column",Formula(form))),
	Expr(form),Name Expr(outExpr)
));

Mais je n'aime pas devoir utiliser Rangée() pour que la formule soit correctement évaluée. Le comportement des deux premiers scripts est-il un bug ?

Re : Création de formules de table de données d'exécution avec JSL

Est-ce que quelque chose comme ça fonctionnerait ? Il n'utilise pas la fonction row(), mais n'accomplit pas non plus exactement ce que vous essayez de faire. Je l'ai volé sur cette page (que j'ai mise en favoris pour chaque fois que j'ai besoin d'effectuer un travail de type eval/expr).

tbl = Open( "$sample_data/cars 1993.JMP" );

buildFormula = Function( {colRef, mult},
	Eval(
		Eval Expr(
			tbl << New Column( "New Formula Column", Formula( as column (expr (colRef)) * expr (num(mult)) ) )
		)
	)
);

outExpr = buildFormula( Column( tbl, "Minimum Price ($1000)" ), 3 );

Re : Création de formules de table de données d'exécution avec JSL

Merci Jed,

C'est utile, tout comme le lien. J'aurais dû être plus clair dans la description du problème. L'évaluation de la formule ne peut pas faire partie de la fonction. Je prévois d'utiliser l'expression de la formule dans d'autres parties du code, donc je ne veux pas qu'elle soit évaluée immédiatement.

Re : Création de formules de table de données d'exécution avec JSL

Voici un extrait de code que j'ai écrit pour Chris. Je dois créer une formule à partir d'autres formules et m'assurer qu'elle prend en charge le profileur. L'utilisation d'un indice vide sur les références a aidé mais a causé d'autres problèmes. Je ne suis pas sûr de ce que vous voulez faire, mais j'espère que cet extrait vous fournira de bonnes idées que vous pourrez utiliser.

For( r = 1, r <= nResponses, r++,

	// convert a column reference to a column name for substitution

	Col Ref to Name = Function( {colref, qualified? = 0 },
		If( qualified?,
			Parse(Eval Insert("^colref << Get Data Table^:\!"^colref << Get Name^\!"n")),
			Parse(Eval Insert(":\!"^colref << Get Name^\!"n"))
		)
	);

	// create expected improvement column formula

	limits = Column( dt, y col[r] ) << Get Property( "Response Limits" );
	goal[r] = Char( limits["Goal"] );
	Match( goal[r],

		"Maximize",	// apply standard EI formula
			Eval(
				Substitute(
					Expr(
						ei = dt << New Column( y col[r] || " Expected Improvement", "Numeric", "Continuous",
							Formula(
								(:pppfff - yyy) * Normal Distribution( (:pppfff - yyy) / Sqrt( :vvvfff ))
								+ Sqrt( :vvvfff ) * Normal Density( (:pppfff - yyy) / Sqrt( :vvvfff ) )
							)
						)
					),
					Expr( vvvfff ), Col Ref To Name(vf),
					Expr( pppfff ), Col Ref To Name(pf),
					Expr( yyy ), refY[r] = predOptY[r]
				)
			),

		"Minimize",	// negate standard EI formula
			Eval(
				Substitute(
					Expr(
						ei = dt << New Column( y col[r] || " Expected Improvement", "Numeric", "Continuous",
							Formula(
								(yyy - :pppfff) * Normal Distribution( (yyy - :pppfff) / Sqrt( :vvvfff ))
								+ Sqrt( :vvvfff ) * Normal Density( (yyy - :pppfff) / Sqrt( :vvvfff ) )
							)						)
					),
					Expr( vvvfff ), Col Ref To Name(vf),
					Expr( pppfff ), Col Ref To Name(pf),
					Expr( yyy ), refY[r] = predOptY[r]
				)
			),

		"Match Target",	// apply joint EI formula
			Eval(
				Substitute(
					Expr(
						ei = dt << New Column( y col[r] || " Expected Improvement", "Numeric", "Continuous",
							Formula(
								deltaMin = Abs( ttt - yyy );
								deltaMin * (Normal Distribution( (deltaMin + ttt - :pppfff) / Sqrt( :vvvfff ) )
									- Normal Distribution( (-deltaMin + ttt - :pppfff) / Sqrt( :vvvfff ) )
								)
								+ Sqrt( :vvvfff ) * (
									Normal Density( (deltaMin + ttt - :pppfff) / Sqrt( :vvvfff ) )
									+ Normal Density( (-deltaMin + ttt - :pppfff) / Sqrt( :vvvfff ) )
									- 2 * Normal Density( ttt - :pppfff) / Sqrt( :vvvfff )
								)
								- (:pppfff - ttt) * (
									(Normal Distribution( (deltaMin + ttt - :pppfff)) / Sqrt( :vvvfff ) )
									+ Normal Distribution( (-deltaMin + ttt - :pppfff) / Sqrt( :vvvfff ) )
									- 2 * Normal Distribution( (ttt - :pppfff) / Sqrt( :vvvfff )  )
								)
			
							)
						)
					),
					Expr( vvvfff ), Col Ref To Name(vf),
					Expr( pppfff ), Col Ref To Name(pf),
					Expr( ttt ),
					target[r] = If( Contains( Char( limits ), "Middle" ),
						limits["Middle"],
						(limits["Lower"] + limits["Upper"]) / 2
					),
					Expr( yyy ),
					/*
					yDiff = (Column( dt, y col ) << Get as Matrix) - target[r];
					pDiff = (pf << Get As Matrix) - target[r];
					refY[r] = If( Min( Abs( yDiff ) ) < Min( Abs( pDiff ) ),
						Column( dt, y col )[Loc Min( Abs( yDiff ) )],
						pf[Loc Min( Abs( pDiff ) )]
					)
					*/
					predOptY[r]
				)
			),

		"None",	// unexpected condition
			Throw( "Disallowed: response with Goal of None" ),

		// unexpected condition

			gp << Close Window;
			dt << Delete Columns( { pf, vf } );
			Throw( "Disallowed: No response goal found. Response Limits column property is missing" )
	);

	ei	<< Set Property( "Response Limits", {Goal( Maximize ), Importance( 1 ), Show Limits( 0 )} )
		<< Hide( 1 );
	Wait( 0 );

	Eval(
		Substitute(
			Expr(
				Insert Into( utilityCols, eee, iii );
			),
			Expr( eee ), Eval( ei ),
			Expr( iii ), 3*(r-1) + 1
		)
	);
);

Re : Création de formules de table de données d'exécution avec JSL

Il semble que j'ai suivi un chemin similaire à celui de Mark. Vous pouvez construire la formule sous forme de chaîne, puis évaluer insert() et eval( parse() ) lorsque vous êtes prêt à appliquer à la colonne. Cela fonctionnerait-il pour votre script ?

tbl = Open("$sample_data/cars 1993.JMP");
colName = "Minimum Price ($1000)";
mult = 3;

formulaString = ":\!"^colName^\!"n * ^mult^";
formula = eval insert( formulaString );

newColumnString = "^tbl^ << new column( \!"New Formula\!", formula( ^formula^ ) )";
newColumn = eval insert( newColumnString );
eval( parse( newColumn ) );

Re : Création de formules de table de données d'exécution avec JSL

Il y a quelques années, lorsque j'ai parlé à @JosephMorgan de ce genre de chose, il a fortement déconseillé l'utilisation de la concaténation ou de la substitution de chaînes et a indiqué que tout pouvait être accompli via la gestion des expressions, à l'exception d'une chose dont je ne me souviens pas et qui n'est peut-être plus un problème. L'utilisation de chaînes rend le code beaucoup plus difficile à lire et à maintenir. Il y a probablement d'autres raisons plus fondamentales, mais je ne m'en souviens pas.

Il s'avère qu'il existe une solution simple utilisant la fonction Comme Scoped() (merci à @brady_brady )

 </CODE></PRE>
<PRE><CODE class=" language-jsl">tbl = Open("$sample_data/cars 1993.JMP");

buildFormula = Function({colRef,mult},
	exprOut = Substitute(
		Expr(col*mult),
		Expr(col),Name Expr(As Scoped(colRef)),
		Expr(mult),mult
	);
	Name Expr(exprOut);
);

outExpr = buildFormula(Column(tbl,"Minimum Price ($1000)"),3);

Eval(Substitute(
	Expr(tbl << New Column("New Formula Column",Formula(form))),
	Expr(form),Name Expr(outExpr)
));<BR />