842738_zh-TW

liliconcom

處理 JSL 中 Y 軸變數的條件顯示以進行圖形構建

使用「建立圖形」時，如何在 JSL 中描述這樣的要求：某些 Y 軸變數（可能不會總是出現）如果有值則顯示，如果沒有值則不顯示？以下兩種方法均無效。

1.

dt = Open("$SAMPLE_DATA/Big Class.jmp");
Graph Builder(
	Size( 534, 450 ),
	Show Control Panel( 0 ),
	Variables( X( :sex ), try(Y( :bbb )), Y( :height ), Y( :weight ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 13 ) ) ),
	Elements( Position( 1, 2 ), Points( X, Y, Legend( 14 ) ) ),
	Elements( Position( 1, 3 ), Points( X, Y, Legend( 15 ) ) )
);

2.

dt = Open("$SAMPLE_DATA/Big Class.jmp");
Graph Builder(
	Size( 534, 450 ),
	Show Control Panel( 0 ),
	Variables( X( :sex ), Y( :bbb ), Y( :height ), Y( :weight ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 13 ) ) ),
	Elements( Position( 1, 2 ), Points( X, Y, Legend( 14 ) ) ),
	Elements( Position( 1, 3 ), Points( X, Y, Legend( 15 ) ) )
);

自動化和腳本回覆：處理 JSL 中 Y 軸變數的條件顯示以進行圖形構建

你好@BabyDoragon ，bbb 是一個存在或不存在的列，這是我們需要檢查的，或者 bbb 一直存在，但缺少一些值（行）？

回覆：處理 JSL 中 Y 軸變數的條件顯示以進行圖形構建

bbb的預設值為{}，有時也可能以變數形式存儲，例如以下兩種情況。

1.

dt = Open("$SAMPLE_DATA/Big Class.jmp");
bbb={};
bbb="age";
Graph Builder(
	Size( 534, 450 ),
	Show Control Panel( 0 ),
	Variables( X( :sex ), Y( as column(bbb)), Y( :height ), Y( :weight ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 13 ) ) ),
	Elements( Position( 1, 2 ), Points( X, Y, Legend( 14 ) ) ),
	Elements( Position( 1, 3 ), Points( X, Y, Legend( 15 ) ) )
);

2.

dt = Open("$SAMPLE_DATA/Big Class.jmp");
bbb={};
//bbb="age";
Graph Builder(
	Size( 534, 450 ),
	Show Control Panel( 0 ),
	Variables( X( :sex ), Y( as column(bbb)), Y( :height ), Y( :weight ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 13 ) ) ),
	Elements( Position( 1, 2 ), Points( X, Y, Legend( 14 ) ) ),
	Elements( Position( 1, 3 ), Points( X, Y, Legend( 15 ) ) )
);

我希望能夠根據 bbb 中目前是否存在任何變數來使圖表自動包含或排除此項目。

回覆：處理 JSL 中 Y 軸變數的條件顯示以進行圖形構建

您可以稍後建立表達式或新增變數

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(534, 450),
	Show Control Panel(0),
	Variables(X(:sex), Y(:height), Y(:weight)),
	Elements(Position(1, 1), Points(X, Y, Legend(13))),
	Elements(Position(1, 2), Points(X, Y, Legend(14)))
);
dt << new column("A", Numeric, Continuous, Formula(Row()));

extra_cols = {"height", "A"};

For Each({extra_col}, extra_cols,
	Eval(EvalExpr(
		gb << Add Variable({Expr(NameExpr(AsColumn(dt, extra_col))), Role("Y")});
	));
);

根據您要做的事情，可能會有很多事情需要考慮（順序、情節類型、圖例...）

如果我沒記錯的話，這可能與這個主題Scripters Club 錄音：Graph Builder 中的 JSL有關