842738_ko-KR

liliconcom

그래프 구축을 위한 JSL에서 Y축 변수의 조건부 표시 처리

`graph built`를 사용할 때, 항상 나타나지 않을 수 있는 특정 Y축 변수가 값이 있으면 표시되고 값이 없으면 표시되지 않아야 한다는 JSL의 요구 사항을 어떻게 설명할 수 있습니까? 다음 두 가지 방법은 효과적이지 않았습니다.

1.

dt = Open("$SAMPLE_DATA/Big Class.jmp");
Graph Builder(
	Size( 534, 450 ),
	Show Control Panel( 0 ),
	Variables( X( :sex ), try(Y( :bbb )), Y( :height ), Y( :weight ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 13 ) ) ),
	Elements( Position( 1, 2 ), Points( X, Y, Legend( 14 ) ) ),
	Elements( Position( 1, 3 ), Points( X, Y, Legend( 15 ) ) )
);

2.

dt = Open("$SAMPLE_DATA/Big Class.jmp");
Graph Builder(
	Size( 534, 450 ),
	Show Control Panel( 0 ),
	Variables( X( :sex ), Y( :bbb ), Y( :height ), Y( :weight ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 13 ) ) ),
	Elements( Position( 1, 2 ), Points( X, Y, Legend( 14 ) ) ),
	Elements( Position( 1, 3 ), Points( X, Y, Legend( 15 ) ) )
);

자동화 및 스크립팅Re: 그래프 구축을 위한 JSL에서 Y축 변수의 조건부 표시 처리

안녕하세요 @베이비도라곤 , bbb는 존재하는 열인지 아닌지 확인해야 하는 것인지, 아니면 bbb는 항상 존재하지만 일부 값(행)이 누락된 것인지요?

Re: 그래프 구축을 위한 JSL에서 Y축 변수의 조건부 표시 처리

bbb의 기본값은 {}이며, 때로는 변수로 저장될 수도 있습니다. 예를 들어 다음 두 가지 경우입니다.

1.

dt = Open("$SAMPLE_DATA/Big Class.jmp");
bbb={};
bbb="age";
Graph Builder(
	Size( 534, 450 ),
	Show Control Panel( 0 ),
	Variables( X( :sex ), Y( as column(bbb)), Y( :height ), Y( :weight ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 13 ) ) ),
	Elements( Position( 1, 2 ), Points( X, Y, Legend( 14 ) ) ),
	Elements( Position( 1, 3 ), Points( X, Y, Legend( 15 ) ) )
);

2.

dt = Open("$SAMPLE_DATA/Big Class.jmp");
bbb={};
//bbb="age";
Graph Builder(
	Size( 534, 450 ),
	Show Control Panel( 0 ),
	Variables( X( :sex ), Y( as column(bbb)), Y( :height ), Y( :weight ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 13 ) ) ),
	Elements( Position( 1, 2 ), Points( X, Y, Legend( 14 ) ) ),
	Elements( Position( 1, 3 ), Points( X, Y, Legend( 15 ) ) )
);

현재 bbb에 변수가 있는지 여부에 따라 그래프에서 이 항목을 자동으로 포함하거나 제외할 수 있기를 바랍니다.

Re: 그래프 구축을 위한 JSL에서 Y축 변수의 조건부 표시 처리

나중에 표현식을 작성하거나 변수를 추가할 수 있습니다.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(534, 450),
	Show Control Panel(0),
	Variables(X(:sex), Y(:height), Y(:weight)),
	Elements(Position(1, 1), Points(X, Y, Legend(13))),
	Elements(Position(1, 2), Points(X, Y, Legend(14)))
);
dt << new column("A", Numeric, Continuous, Formula(Row()));

extra_cols = {"height", "A"};

For Each({extra_col}, extra_cols,
	Eval(EvalExpr(
		gb << Add Variable({Expr(NameExpr(AsColumn(dt, extra_col))), Role("Y")});
	));
);

무엇을 하려고 하는지에 따라 고려해야 할 사항이 꽤 많을 수 있습니다(순서, 줄거리 유형, 전설 등).

제 기억이 맞다면 이것은 Scripters Club 레코딩: Graph Builder의 JSL 주제와 관련이 있을 수 있습니다.