827212_zh-CN

liliconcom

应用程序和仪表板的数据表

大家好，

我想为应用程序/仪表板构建代码。代码的第一部分导入一些表格，进行一些过滤和格式化，然后构建一些图表和报告。

在此之后，我希望有通用代码来构建一个应用程序/仪表板，以显示我之前使用现有数据表（过滤和格式化后）制作的报告。我无法通过脚本解决这个问题，而无需提示选择用于分析的数据表或已经嵌入但不正确的数据表。基本上，数据表 1 使用当前数据表名称，这很好，但需要的第二个数据表被嵌入，但本质上它默认为未格式化和未过滤的数据表，即使作为变量格式化被覆盖到原始数据表上。

我还尝试保存格式化的表格，然后使用完整路径（全局变量）来调用它们，但是当我尝试运行代码时，仍然会提示我选择要构建应用程序的表格。

总的来说，我试图使其尽可能通用并编写脚本，因为每次运行时所使用的数据表都会有不同的数据（相同或几乎相同的列但不同的数据）。

除了在仪表板构建器中构建仪表板并且没有完全编写脚本之外，我没有大量的仪表板使用经验。

谢谢

自动化和脚本视窗回复：应用程序和仪表盘的数据表

您使用的是应用程序/仪表板构建器还是仅使用 JSL？

回复：应用程序和仪表盘的数据表

我最终更愿意使用 JSL 来完成所有事情。但是，现在我使用 JSL 导入表格并重新格式化它们，但为了构建应用程序的一些代码，我使用了应用程序/仪表板构建器

回复：应用程序和仪表盘的数据表

您能否提供脚本的 JSL 部分并标记/解释您遇到问题的部分？您从哪里获取路径？用户在运行脚本之前是否打开了表（使用当前数据表（）是强制性的吗）？此外，您是否尝试过使用工作流生成器执行此操作？

回复：应用程序和仪表盘的数据表

dt1 = Open( "XXXXX.csv" );
If( Not( Is Scriptable( dt1 ) ),
	dt1 = Open( "XXXXX.csv" ),);
Wait( 2 );
dt2=Data Table( dt1 ) << Subset(
			Rows(
				Data Table( dt1 ) <<
				Select Where (
					:X == "1" & :"Y"n == "2" &
					:Z == "3)), All Columns);
Wait( 2 );
dt3 = Open( "YYYY.csv" );
If( Not( Is Scriptable( dt3 ) ),
	dt3 = Open( "YYYY.csv" ),);
dt2 << Set Name("MainDataTable");
dt3 << Set Name("SpecTable");<BR />::saveloc_dt2 = Concat Items( {new_folder, "\MainDataTable",".csv"}, "" );<BR />dt2 << Save(saveloc_dt2);<BR />::saveloc_dt3 = Concat Items( {new_folder, "\SpecTable",".csv"}, "" );<BR />dt3 << Save(saveloc_dt3);

Current Data Table( dt2 );
cc = Control Chart Builder(Show Control Panel(0),Show Capability(0),Size(700,450),Show Excluded Region( 0 ),
	Variables( Y( :X ) ),
	Local Data Filter(
		Add Filter(
			columns( :Z),
			Display( :A, Find( Set Text( "" ) ) ))),
	Chart( Position( 1 ), Limits( Shade Zones( 0 ) ) )););

Current Data Table( dt2 );
process_screening = Process Screening(
	Process Variables(
		:A, :B, :C,
		Grouping( :Y ),Control Chart Type( "Indiv and MR" ),Within Sigma( 0 ),Overall Sigma( 0 ),Stability Index( 0 ),Show Tests( 0 ),Out of Spec Count( 1 ),Out of Spec Rate( 1 ),
		Latest Out of Spec( 0 ),N Subgroups (0 ),Ppk( 1 ),Cp( 1 ),Cpk(1),Cpm(1),Spec Limits( 1 ),
							Use Limits Table(
								1,
								Data Table( "SpecTable" ),
								Process Variables( :Process ),
								Grouping( :Z ),
								LSL( :LSL ),
								USL( :USL ),
								Target( :Target ),
								Go
							),
							Goal Plot( 0, Capability Lines( 1.33 ), Shade Levels( 0 ) ),
	Process Performance Graph( 0 ));


JMP App(
	Set Name( "Application" ),
	Set Description(
		"An empty workspace for creating custom applications with one or more windows and scripts"
	),
	Auto Launch( 1 ),
	Snap To Grid( 1 ),
	Show Grid( 1 ),
	Show Properties( 1 ),
	Show Sources( 1 ),
	Group By Category( 1 ),
	Dashboard Mode( 0 ),
	Parameters,
	Tables(
		DataTable2 = GuiTable(
			Set Path( saveloc_dt2 ),
			Set Label( "MainDataTable" ),
			Location( "Full Path" ),
			Invisible( 0 )
		),
		DataTable3 = GuiTable(
			Set Path( saveloc_dt3 ),
			Set Label( "SpecTable" ),
			Location( "Full Path" ),
			Invisible( 1 ))),<BR />. . . . 

我以为这样我就可以引用我刚刚在应用程序中格式化（并保存）的数据表，但我却看到一个窗口提示我选择要使用的表。这是我希望避免的部分。

我想另一个选择就是制作我想要的报告并使用合并窗口功能将它们放在仪表板类型的窗口中，然后尝试获得正确的间距等。

回复：应用程序和仪表盘的数据表

我对脚本的第一部分做了一些清理，希望它能给你提供一些关于脚本和编写 JSL 的想法

Names Default To Here(1);

new_folder = "MYFOLDER";

// Checking for scriptable should be unnecessary
dt1 = Open("XXXXX.csv"); 

// Datatable(dt1) is unnecessary in 99% of cases
// Use << Get Rows Where instead of Select Where with Rows() in subset
// Use output table() to make debugging much easier
dt2 = dt1 << Subset(Rows(dt1 << Get Rows Where(:X == "1" & :"Y"n == "2" & :Z == "3")), Selected Columns(0), Output Table("MainDataTable"));

dt3 = Open("YYYY.csv");
dt3 << Set Name("SpecTable");

// simpler in this case
saveloc_dt2 = new_folder || "\MainDataTable.csv";
dt2 << Save(saveloc_dt2);

saveloc_dt3 = new_folder || "\SpecTable.csv";
dt3 << Save(saveloc_dt3);

// You can send messages directly to data table, do not use current data table() if possible
cc_expr = Expr(dt2 << Control Chart Builder(
	Show Control Panel(0),
	Show Capability(0),
	Size(700, 450),
	Show Excluded Region(0),
	Variables(Y(:X)),
	Local Data Filter(Add Filter(columns(:Z), Display(:A, Find(Set Text(""))))),
	Chart(Position(1), Limits(Shade Zones(0)))
));

ps_expr = Expr(dt2 << Process Screening(
	Process Variables(
		:A,
		:B,
		:C,
		Grouping(:Y),
		Control Chart Type("Indiv and MR"),
		Within Sigma(0),
		Overall Sigma(0),
		Stability Index(0),
		Show Tests(0),
		Out of Spec Count(1),
		Out of Spec Rate(1),
		Latest Out of Spec(0),
		N Subgroups(0),
		Ppk(1),
		Cp(1),
		Cpk(1),
		Cpm(1),
		Spec Limits(1),
		Use Limits Table(1, Data Table("SpecTable"), Process Variables(:Process), Grouping(:Z), LSL(:LSL), USL(:USL), Target(:Target), Go),
		Goal Plot(0, Capability Lines(1.33), Shade Levels(0)),
		Process Performance Graph(0)
	)
));

nw = New Window("My report",
	V List Box(
		cc = cc_expr,
		ps = ps_expr
	)
);

构建报告的一个选项是使用 Expr() 包装平台调用，然后在新窗口中调用这些表达式。您还可以跳过表达式，只使用平台调用构建窗口（或使用其他一些方法）

nw = New Window("My report",
	V List Box(
		cc = dt2 << Control Chart Builder(
			Show Control Panel(0),
			Show Capability(0),
			Size(700, 450),
			Show Excluded Region(0),
			Variables(Y(:X)),
			Local Data Filter(Add Filter(columns(:Z), Display(:A, Find(Set Text(""))))),
			Chart(Position(1), Limits(Shade Zones(0)))
		),
		ps = dt2 << Process Screening(
			Process Variables(
				:A,
				:B,
				:C,
				Grouping(:Y),
				Control Chart Type("Indiv and MR"),
				Within Sigma(0),
				Overall Sigma(0),
				Stability Index(0),
				Show Tests(0),
				Out of Spec Count(1),
				Out of Spec Rate(1),
				Latest Out of Spec(0),
				N Subgroups(0),
				Ppk(1),
				Cp(1),
				Cpk(1),
				Cpm(1),
				Spec Limits(1),
				Use Limits Table(1, Data Table("SpecTable"), Process Variables(:Process), Grouping(:Z), LSL(:LSL), USL(:USL), Target(:Target), Go),
				Goal Plot(0, Capability Lines(1.33), Shade Levels(0)),
				Process Performance Graph(0)
			)
		)
	)
);

我建议你查看JMP 帮助中的脚本指南。无需通读所有内容，只需浏览一下其中的内容即可。

回复：应用程序和仪表盘的数据表

非常感谢。我会看看这些