826932_zh-CN

liliconcom

更新函数内部的列表

嘿，大家好，

我尝试在每次调用该函数时向函数内部的列表中添加一个新值（变量值）。

无论我怎么尝试，该列表都没有得到任何价值。

有什么建议吗？

添加代码示例

自动化和脚本基础数据分析与建模回复：更新函数内部的列表

我认为更好的想法是返回新列，然后将其添加到函数调用之外

Names Default To Here(1);

dt = Open("\\VMSPFSFSLC001\F28_PLI\SQL\FE SQL\Data\Oxide .CSV");

op_list = List();

add_new_operation = Function({dt, col_name, op, PLmin, PLmax}, {Default Local},
	new_col = dt << New Column(col_name,
		Character,
		"Nominal",
		Formula(
			If(/*some conditions for the value*/
			)
 		
		)
	);
	
	return(new_col);
);

sticol = add_new_operation(dt, "STI", 201405, 80, 2000);
Insert Into(op_list, sticol);

Show(op_list);


// This should also work
// Insert into(op_list, add_new_operation(dt, "STI", 201405, 80, 2000));

完整示例

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

op_list = {};

add_new_operation = Function({dt, col_name}, {Default Local},
	new_col = dt << New Column(col_name,
		Character,
		"Nominal",
		Formula(
			col_name
		)
	);
	
	return(new_col);
);

Show(op_list); // op_list = {};
Insert into(op_list, add_new_operation(dt, "name"));
Insert into(op_list, add_new_operation(dt, "age"));
Show(op_list); // op_list = {Column("name 2"), Column("age 2")};
 

回复：更新函数内部的列表

如果你真的想插入函数外部创建的列表，请从函数中删除 {Default Local}（还有其他方法），但我不建议这样做。原因之一是现在你必须在调用函数之前始终创建 op_list。

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

op_list = {};

add_new_operation = Function({dt, col_name},
	new_col = dt << New Column(col_name,
		Character,
		"Nominal",
		Formula(
			col_name
		)
	);
	
	Insert Into(op_list, new_col);
);

Show(op_list); // op_list = {};
add_new_operation(dt, "name");
add_new_operation(dt, "age");
Show(op_list); // op_list = {Column("name 2"), Column("age 2")};