825799_es-ES

liliconcom

Filtros preestablecidos como cuadros de botones

Estoy intentando crear cuadros de botones donde pueda establecer parámetros a los que se asigna el filtro global.

Para el ejemplo a continuación me gustaría un botón solo para mujeres y otro para hombres y con una altura mayor a 60.

	dt = Open( "$SAMPLE_DATA/big class.jmp" );
	
	gra1=hlistbox(dt<<GRAPH builder=""></GRAPH>

<LINGO-LABS id="lingo-labs-825799" slang="en-US" mode="CREATE"><LINGO-LABEL>Automatización y scripting</LINGO-LABEL><LINGO-LABEL>Análisis y modelado de datos básicos</LINGO-LABEL><LINGO-LABEL>Exploración y visualización de datos</LINGO-LABEL><LINGO-LABEL>Ventanas</LINGO-LABEL></LINGO-LABS>Re: Filtros preestablecidos como cuadros de botones

¿Podrías simplemente utilizar Favoritos?

Si desea tener botones, puede utilizar los favoritos (agregarlos primero y luego hacer que los botones apliquen esos favoritos). Busque Filtro de datos (a la izquierda) en el índice de scripts para obtener todo tipo de opciones útiles:

Uso de favoritos (este ejemplo da una idea bastante clara de lo que podría hacer)

Usando Where:

https://www.jmp.com/support/help/en/18.0/#page/jmp/data-filter-messages.shtml#

Y para los botones puedes usar Button Box()

https://www.jmp.com/support/help/en/18.0/#page/jmp/construct-display-boxes-for-new-windows.shtml#ww496557

Re: Filtros preestablecidos como cuadros de botones

Gracias, me gustaría tener botones visibles en lugar de favoritos.

¡Estaba intentando usar columnas de filtro y hacer coincidir en una función pero sin éxito!

Revisé el índice de scripts y busqué en todas partes, utilicé el nuevo learnbot de la tienda y también ChatGPT.

Parece extraño que no se haya implementado antes.

Re: Filtros preestablecidos como cuadros de botones

Esto muestra algunas opciones diferentes.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/big class.jmp");
	
gra1 = H List Box(
	dt << Graph Builder(
		Size(528, 450),
		Show Control Panel(0),
		Variables(X(:height), Y(:weight), Overlay(:sex)),
		Elements(Points(X, Y, Legend(11)), Smoother(X, Y, Legend(12)))
	)
);

tab1 = H List Box(
	dt << Tabulate(
		Show Control Panel(0),
		Full Path Column Name(1),
		Add Table(Column Table(Analysis Columns(:height)), Row Table(Grouping Columns(:name, :sex)))
	)
);

fil1 = H List Box(
	df = dt << Data Filter(
		Auto clear(1),
		Show Histograms and Bars(0),
		Mode(Show(0)),
		Add Filter(columns(:sex, :age, :height), Display(:age, N Items(6)), Display(:height, Height(20)))
	)
);

df << Match(Filter Columns(:sex, :age, :height), Where(:sex == "F"));
df << add favorites("F only");
df << Clear;

win1 = New Window("Example", 
	V List Box(
		Lineup Box(N Col(2),
			Button Box("F Only",
				df << Apply Favorites("F only")
			),
			Button Box("M, height >= 60",
				df << (Filter Column(:sex) << Where(:sex == "M"));
				df << (Filter Column(:height) << Extend Where(:height >= 60));
			)
		),
		H List Box(
			fil1, 
			V List Box(
				gra1
				, tab1
			)
		)
	)
);

Re: Filtros preestablecidos como cuadros de botones

¡¡¡Muchas gracias!!!

Re: Filtros preestablecidos como cuadros de botones

Muchas gracias por la solución.