825799_it-IT

liliconcom

Filtri preimpostati come pulsanti

Sto cercando di creare delle caselle di pulsanti in cui posso impostare i parametri a cui viene assegnato il filtro globale.

Per l'esempio seguente vorrei un pulsante solo per le donne e un altro con uomini e altezza maggiore di 60

	dt = Open( "$SAMPLE_DATA/big class.jmp" );
	
	gra1=hlistbox(dt<<GRAPH builder=""></GRAPH>

<LINGO-LABS id="lingo-labs-825799" slang="en-US" mode="CREATE"><LINGO-LABEL>Automazione e scripting</LINGO-LABEL><LINGO-LABEL>Analisi e modellazione dei dati di base</LINGO-LABEL><LINGO-LABEL>Esplorazione e visualizzazione dei dati</LINGO-LABEL><LINGO-LABEL>Finestre</LINGO-LABEL></LINGO-LABS>Re: Filtri preimpostati come pulsanti

Potresti semplicemente utilizzare i Preferiti?

Se desideri avere dei pulsanti, puoi comunque utilizzare i preferiti (aggiungili prima e poi fai in modo che i pulsanti applichino quei preferiti). Cerca Data Filter (sulla sinistra) dall'indice di scripting per tutti i tipi di opzioni utili:

Utilizzo di preferito (questo esempio dà una buona idea di cosa potresti fare)

Utilizzo di Where:

https://www.jmp.com/support/help/en/18.0/#page/jmp/data-filter-messages.shtml#

E per i pulsanti puoi usare Button Box()

https://www.jmp.com/support/help/en/18.0/#page/jmp/construct-display-boxes-for-new-windows.shtml#ww496557

Re: Filtri preimpostati come pulsanti

Grazie, vorrei che fossero visibili i pulsanti anziché i preferiti.

Ho provato a usare le colonne filtro e a fare corrispondenze in una funzione, ma senza successo!

Ho esaminato l'indice degli script e ho cercato ovunque, ho utilizzato anche il nuovo learnbot dello store e ChatGPT!

Sembra strano che non sia stato implementato prima.

Re: Filtri preimpostati come pulsanti

Questo mostra alcune opzioni diverse

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/big class.jmp");
	
gra1 = H List Box(
	dt << Graph Builder(
		Size(528, 450),
		Show Control Panel(0),
		Variables(X(:height), Y(:weight), Overlay(:sex)),
		Elements(Points(X, Y, Legend(11)), Smoother(X, Y, Legend(12)))
	)
);

tab1 = H List Box(
	dt << Tabulate(
		Show Control Panel(0),
		Full Path Column Name(1),
		Add Table(Column Table(Analysis Columns(:height)), Row Table(Grouping Columns(:name, :sex)))
	)
);

fil1 = H List Box(
	df = dt << Data Filter(
		Auto clear(1),
		Show Histograms and Bars(0),
		Mode(Show(0)),
		Add Filter(columns(:sex, :age, :height), Display(:age, N Items(6)), Display(:height, Height(20)))
	)
);

df << Match(Filter Columns(:sex, :age, :height), Where(:sex == "F"));
df << add favorites("F only");
df << Clear;

win1 = New Window("Example", 
	V List Box(
		Lineup Box(N Col(2),
			Button Box("F Only",
				df << Apply Favorites("F only")
			),
			Button Box("M, height >= 60",
				df << (Filter Column(:sex) << Where(:sex == "M"));
				df << (Filter Column(:height) << Extend Where(:height >= 60));
			)
		),
		H List Box(
			fil1, 
			V List Box(
				gra1
				, tab1
			)
		)
	)
);

Re: Filtri preimpostati come pulsanti

Grazie mille!!!

Re: Filtri preimpostati come pulsanti

Grazie mille per la soluzione.