824558_es-ES

liliconcom

Cree mapas de calor duplicados con diferentes estadísticas de resumen en Graph Builder

Dada la Gran Clase y esta trama:

Graph Builder(
	Size( 574, 613 ),
	Graph Spacing( 20 ),
	Variables(
		X( :sex ),
		X( :sex ),
		Y( :age ),
		Color( :height, Summary Statistic( "Min" ) )
	),
	Elements( Position( 1, 1 ), Heatmap( X, Y, Legend( 4 ) ) ),
	Elements( Position( 2, 1 ), Heatmap( X, Y, Legend( 5 ) ) )
)

¿Hay alguna manera de hacer que el gráfico de la izquierda utilice la estadística de resumen "Media" y el gráfico de la derecha utilice "Mín"?

Intenté agregar otra especificación Color() pero no parece funcionar en JMP 17.

Exploración y visualización de datosRe: Crear mapas de calor duplicados con diferentes estadísticas de resumen en Graph Builder

Lo que hice fue

1. Utilice Tablas=>Resumen para crear una nueva tabla con las estadísticas medias y mínimas agrupadas por sexo y edad
2. Utilice Tablas=>Pilar para apilar las columnas de media y mínimo
3. Ejecutar el generador de gráficos

names default to here(1);

dt =
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

// Data table summary
// → Data Table( "Summary of Big Class grouped by age, sex" )
Data Table( "Big Class" ) << Summary(
	Group( :age, :sex ),
	Mean( :height ),
	Min( :height ),
	Freq( "None" ),
	Weight( "None" ),
	statistics column name format( "stat" ),
	output table name( "Summary of Big Class grouped by age, sex" )
);

// Stack data table
// → Data Table( "Stack of Summary of Big Class grouped by age, sex (Mean, Min)" )
Data Table( "Summary of Big Class grouped by age, sex" ) <<
Stack(
	columns( :Mean, :Min ),
	Output Table( "Stack of Summary of Big Class grouped by age, sex (Mean, Min)" )
);

Graph Builder(
	X Group Edge( "Bottom" ),
	Variables( X( :sex ), Y( :age ), Group X( :Label ), Color( :Data ) ),
	Elements( Heatmap( X, Y, Legend( 4 ) ) )
);

Re: Crear mapas de calor duplicados con diferentes estadísticas de resumen en Graph Builder

Otra opción es crear dos informes de creación de gráficos y colocarlos uno al lado del otro en una nueva ventana de informe personalizado. Es posible que desee cambiar el título de los gráficos para que quede claro que uno tiene los valores Mín y Máx. A continuación, se muestra un ejemplo sencillo:

names default to here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

hm1 = expr( dt << Graph Builder(
	Size( 235, 613 ),
	Show Control Panel( 0 ),
	Variables(
		X( :sex ),
		Y( :age ),
		Color( :height, Summary Statistic( "Min" ) )
	),
	Elements( Heatmap( X, Y, Legend( 1 ) ) ),
));

hm2 = expr( dt << Graph Builder(
	Size( 235, 613 ),
	Show Control Panel( 0 ),	
	Variables(
		X( :sex ),
		Y( :age ),
		Color( :height, Summary Statistic( "Max" ) )
	),
	Elements( Heatmap( X, Y, Legend( 1 ) ) ),
));

new window( "Two Heat Maps", 
	h list box( hm1, hm2 )
);

Re: Crear mapas de calor duplicados con diferentes estadísticas de resumen en Graph Builder

Corriendo el riesgo de sobrediseñar esta solución, se podría generalizar para una lista de estadísticas.

names default to here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

statList = { "Mean", "Median", "Mode", "Min", "Max", "Range", "Median", "Std Dev" };

hm_fxn = function( { STAT },
	dt << Graph Builder(
		Size( 200, 300 ),				// Adjust size based on number of heatmaps
		Show Control Panel( 0 ),
		Variables(
			X( :sex ),
			Y( :age ),
			Color( :height, Summary Statistic( STAT ) )
		),
		Elements( Heatmap( X, Y, Legend( 1 ) ) ),
		SendToReport(
			Dispatch( {}, "Graph Builder", OutlineBox,
			{Set Title( "Color by " || STAT ), Image Export Display( Normal )}
			)
		)
	)
);

new window( "Heat Maps",
	outline box( dt << get name || " Heat Maps",
		lub = line up box( n col( 4 ) )	// Adjust n col() for number of heatmaps per row
	)
);

for each( { s }, statList,
	lub << append( hm_fxn( s ) )
)

Re: Crear mapas de calor duplicados con diferentes estadísticas de resumen en Graph Builder

---

@BHarris escribió:

Intenté agregar otra especificación Color() pero no parece funcionar en JMP 17.

---

-> añadir otro color
Funciona con JMP 17 (.2)

dt = Open( "$SAMPLE_DATA/Big Class Families.jmp" );
Graph Builder(
	Size( 574, 613 ),
	Summary Statistic( "Median" ),
	Graph Spacing( 20 ),
	Variables(
		X( :sex ),
		X( :sex ),
		Y( :age ),
		Color( :height, Summary Statistic( "N" ) ),
		Color( :height, Summary Statistic( "Max" ) )
	),
	Elements( Position( 1, 1 ), Heatmap( X, Y, Color( 1 ), Legend( 4 ) ) ),
	Elements( Position( 2, 1 ), Heatmap( X, Y, Color( 2 ), Legend( 5 ) ) )
);

Re: Crear mapas de calor duplicados con diferentes estadísticas de resumen en Graph Builder

¡Excelente! ¡Funcionó! Creo que me faltaba la variable X adicional cuando agregué la especificación de color. Sería bueno que GB admitiera esto con la interfaz de usuario, pero ya hace demasiado...

Aquí está el guión final que estaba buscando:

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Graph Builder(
	Size( 934, 824 ),
	Show Title( 1 ),
	Graph Spacing( 20 ),
	Variables(
		X( :sex ),
		X( :sex ),
		X( :sex ),
		Y( :age ),
		Color( :height, Summary Statistic( "Min" ) ),
		Color( :height, Summary Statistic( "Mean" ) ),
		Color( :height, Summary Statistic( "Max" ) )
	),
	Elements(
		Position( 1, 1 ),
		Heatmap( X, Y, Color( 1 ), Legend( 1 ), Label( "Label by Value" ) )
	),
	Elements(
		Position( 2, 1 ),
		Heatmap( X, Y, Color( 2 ), Legend( 2 ), Label( "Label by Value" ) )
	),
	Elements(
		Position( 3, 1 ),
		Heatmap( X, Y, Color( 3 ), Legend( 3 ), Label( "Label by Value" ) )
	),
	SendToReport(
		Dispatch(
			{},
			"graph title",
			TextEditBox,
			{Set Text( "Age vs. Sex, Colored on Height -- Min, Mean, Max" )}
		),
		Dispatch(
			{},
			"400",
			LegendBox,
			{Legend Position( {1, [0], 2, [-1], 3, [-1]} )}
		)
	)
)