824558_de-DE

liliconcom

Erstellen Sie doppelte Heatmaps mit unterschiedlichen Übersichtsstatistiken im Graph Builder

Angesichts der großen Klasse und dieser Handlung:

Graph Builder(
	Size( 574, 613 ),
	Graph Spacing( 20 ),
	Variables(
		X( :sex ),
		X( :sex ),
		Y( :age ),
		Color( :height, Summary Statistic( "Min" ) )
	),
	Elements( Position( 1, 1 ), Heatmap( X, Y, Legend( 4 ) ) ),
	Elements( Position( 2, 1 ), Heatmap( X, Y, Legend( 5 ) ) )
)

Gibt es eine Möglichkeit, im linken Diagramm den Mittelwert und im rechten Diagramm den Min-Wert zu verwenden?

Ich habe versucht, eine weitere Color()-Spezifikation hinzuzufügen, aber es scheint in JMP 17 nicht zu funktionieren.

Datenexploration und -visualisierungBetreff: Erstellen Sie doppelte Heatmaps mit unterschiedlichen Übersichtsstatistiken im Graph Builder

Ich habe Folgendes getan:

1. Verwenden Sie Tabellen=>Zusammenfassung, um eine neue Tabelle mit den Mittel- und Mindeststatistiken gruppiert nach Geschlecht und Alter zu erstellen.
2. Verwenden Sie Tabellen=>Stapeln, um die Mittelwert- und Minimumspalten zu stapeln.
3. Graph Builder ausführen

names default to here(1);

dt =
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

// Data table summary
// → Data Table( "Summary of Big Class grouped by age, sex" )
Data Table( "Big Class" ) << Summary(
	Group( :age, :sex ),
	Mean( :height ),
	Min( :height ),
	Freq( "None" ),
	Weight( "None" ),
	statistics column name format( "stat" ),
	output table name( "Summary of Big Class grouped by age, sex" )
);

// Stack data table
// → Data Table( "Stack of Summary of Big Class grouped by age, sex (Mean, Min)" )
Data Table( "Summary of Big Class grouped by age, sex" ) <<
Stack(
	columns( :Mean, :Min ),
	Output Table( "Stack of Summary of Big Class grouped by age, sex (Mean, Min)" )
);

Graph Builder(
	X Group Edge( "Bottom" ),
	Variables( X( :sex ), Y( :age ), Group X( :Label ), Color( :Data ) ),
	Elements( Heatmap( X, Y, Legend( 4 ) ) )
);

Betreff: Erstellen Sie doppelte Heatmaps mit unterschiedlichen Übersichtsstatistiken im Graph Builder

Eine weitere Möglichkeit besteht darin, zwei Diagrammerstellungsberichte zu erstellen und diese nebeneinander in einem neuen Fenster für benutzerdefinierte Berichte zu platzieren. Möglicherweise möchten Sie die Diagramme umbenennen, damit klar ist, dass eines in „Min“ und eines in „Max“ eingefärbt ist. Hier ist ein einfaches Beispiel:

names default to here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

hm1 = expr( dt << Graph Builder(
	Size( 235, 613 ),
	Show Control Panel( 0 ),
	Variables(
		X( :sex ),
		Y( :age ),
		Color( :height, Summary Statistic( "Min" ) )
	),
	Elements( Heatmap( X, Y, Legend( 1 ) ) ),
));

hm2 = expr( dt << Graph Builder(
	Size( 235, 613 ),
	Show Control Panel( 0 ),	
	Variables(
		X( :sex ),
		Y( :age ),
		Color( :height, Summary Statistic( "Max" ) )
	),
	Elements( Heatmap( X, Y, Legend( 1 ) ) ),
));

new window( "Two Heat Maps", 
	h list box( hm1, hm2 )
);

Betreff: Erstellen Sie doppelte Heatmaps mit unterschiedlichen Übersichtsstatistiken im Graph Builder

Auf die Gefahr hin, diese Lösung zu technisch zu übertreiben, könnten Sie dies für eine Liste von Statistiken verallgemeinern.

names default to here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

statList = { "Mean", "Median", "Mode", "Min", "Max", "Range", "Median", "Std Dev" };

hm_fxn = function( { STAT },
	dt << Graph Builder(
		Size( 200, 300 ),				// Adjust size based on number of heatmaps
		Show Control Panel( 0 ),
		Variables(
			X( :sex ),
			Y( :age ),
			Color( :height, Summary Statistic( STAT ) )
		),
		Elements( Heatmap( X, Y, Legend( 1 ) ) ),
		SendToReport(
			Dispatch( {}, "Graph Builder", OutlineBox,
			{Set Title( "Color by " || STAT ), Image Export Display( Normal )}
			)
		)
	)
);

new window( "Heat Maps",
	outline box( dt << get name || " Heat Maps",
		lub = line up box( n col( 4 ) )	// Adjust n col() for number of heatmaps per row
	)
);

for each( { s }, statList,
	lub << append( hm_fxn( s ) )
)

Betreff: Erstellen Sie doppelte Heatmaps mit unterschiedlichen Übersichtsstatistiken im Graph Builder

---

@BHarris schrieb:

Ich habe versucht, eine weitere Color()-Spezifikation hinzuzufügen, aber es scheint in JMP 17 nicht zu funktionieren.

---

-> eine weitere Farbe hinzufügen
Funktioniert mit JMP 17 (.2)

dt = Open( "$SAMPLE_DATA/Big Class Families.jmp" );
Graph Builder(
	Size( 574, 613 ),
	Summary Statistic( "Median" ),
	Graph Spacing( 20 ),
	Variables(
		X( :sex ),
		X( :sex ),
		Y( :age ),
		Color( :height, Summary Statistic( "N" ) ),
		Color( :height, Summary Statistic( "Max" ) )
	),
	Elements( Position( 1, 1 ), Heatmap( X, Y, Color( 1 ), Legend( 4 ) ) ),
	Elements( Position( 2, 1 ), Heatmap( X, Y, Color( 2 ), Legend( 5 ) ) )
);

Betreff: Erstellen Sie doppelte Heatmaps mit unterschiedlichen Übersichtsstatistiken im Graph Builder

Ausgezeichnet, das hat funktioniert! Ich glaube, mir fehlte die zusätzliche X-Variable, als ich die Farbspezifikation hinzugefügt habe. Es wäre schön, wenn GB dies mit der Benutzeroberfläche unterstützen würde, aber es macht schon so viel ...

Hier ist das endgültige Skript, nach dem ich gesucht habe:

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Graph Builder(
	Size( 934, 824 ),
	Show Title( 1 ),
	Graph Spacing( 20 ),
	Variables(
		X( :sex ),
		X( :sex ),
		X( :sex ),
		Y( :age ),
		Color( :height, Summary Statistic( "Min" ) ),
		Color( :height, Summary Statistic( "Mean" ) ),
		Color( :height, Summary Statistic( "Max" ) )
	),
	Elements(
		Position( 1, 1 ),
		Heatmap( X, Y, Color( 1 ), Legend( 1 ), Label( "Label by Value" ) )
	),
	Elements(
		Position( 2, 1 ),
		Heatmap( X, Y, Color( 2 ), Legend( 2 ), Label( "Label by Value" ) )
	),
	Elements(
		Position( 3, 1 ),
		Heatmap( X, Y, Color( 3 ), Legend( 3 ), Label( "Label by Value" ) )
	),
	SendToReport(
		Dispatch(
			{},
			"graph title",
			TextEditBox,
			{Set Text( "Age vs. Sex, Colored on Height -- Min, Mean, Max" )}
		),
		Dispatch(
			{},
			"400",
			LegendBox,
			{Legend Position( {1, [0], 2, [-1], 3, [-1]} )}
		)
	)
)