J'ai un grand ensemble de données provenant d'une longue session au cours de laquelle de nombreuses tâches ont été effectuées pour chaque sujet. De nombreuses tâches impliquaient les mêmes 4 à 5 types et plusieurs évaluations et résultats comportementaux de ces types. Cependant, chaque variable de résultat est nommée un peu différemment en termes de la manière dont le « type » est reflété dans le nom. J'essaie d'empiler les « types » pour chaque résultat et de les combiner dans une seule feuille de calcul. Jusqu'à présent, j'ai pu empiler une seule variable, puis j'ai pu joindre deux feuilles dans lesquelles différentes variables avaient été empilées en fusionnant et en faisant correspondre l'ID du sujet et une colonne « type » recodée. Est-ce la bonne séquence ? Empiler une variable, enregistrer la table résultante, empiler une autre à partir d'une autre feuille de calcul, enregistrer la table résultante, joindre/fusionner des tables, puis empiler et fusionner d'autres ? 5 tables peuvent-elles être fusionnées/assorties en même temps ? J'ai essayé d'ajouter une nouvelle variable empilée au résultat de deux tables fusionnées et le résultat semblait incorrect. Merci !
Avez-vous essayé d'empiler plusieurs séries ? Vous pouvez empiler plusieurs colonnes.
Je ne suis pas sûr que cette fonction fonctionnera. Pour l'instant, mes données sont analogues à :
Tâche 1 bras ; Tâche 1 jambe ; Tâche 2 bras ; Tâche 2 jambe ; Tâche 3 bras ; Tâche 3 jambe ; Tâche 3 visage
Sauf que les noms des variables divergent du format ci-dessus et ne sont pas tous cohérents. Je souhaite empiler les valeurs de la tâche 1, ainsi que séparément les valeurs de la tâche 2 et également séparément les valeurs de la tâche 3, mais toutes jointes par la variable Body Site :
Valeur de la tâche 1 du bras Valeur de la tâche 2. (aucune donnée)
Valeur de la tâche 1 de la jambe Valeur de la tâche 2. (aucune donnée)
Visage Valeur de la tâche 1 Valeur de la tâche 2 Valeur de la tâche 3
Un script peut être écrit pour tester les différentes variations d'un nom de colonne, puis changer le nom en forme standard.
Une fois dans la forme standard, au fur et à mesure que vous décrivez les noms, le script suivant prend la forme standard
Et le convertir dans le nouveau format pour la table
names default to here(1);
dt = new table("Example",
add rows(20),
New column("Task 1 arm", set each value(random integer(1,100))),
New column("Task 1 leg", set each value(random integer(1,100))),
New column("Task 2 arm", set each value(random integer(1,100))),
New column("Task 2 leg", set each value(random integer(1,100))),
New column("Task 3 arm", set each value(random integer(1,100))),
New column("Task 3 leg", set each value(random integer(1,100))),
New column("Task 3 face", set each value(random integer(1,100)))
);
dt << new column("Row", set each value(Row()));
dtStack = dt << Stack(
columns(
:Task 1 arm, :Task 1 leg, :Task 2 arm, :Task 2 leg, :Task 3 arm, :Task 3 leg,
:Task 3 face
),
Output Table( "Stack" )
);
dtStack << new column("Body Part", character, formula( word(-1, :label, " ")));
dtStack << new column( "Task", character, formula( substr(:Label, 1 ,length(:label)-length(:body part)-1)));
dtFinal = dtStack << Split(
Split By( :Task ),
Split( :Data ),
Group( :Body Part, :row ),
Output Table( "Final" ),
Remaining Columns( Drop All ),
Sort by Column Property
);
dtFinal << Sort( By(:row, :Body Part), Replace Table(1));
dtFinal << delete columns(:row);
dt << delete columns(:row);
close( dtStack, nosave );
