819591_zh-TW

liliconcom

如何以自動方式變更圖形產生器的點數據點標籤？

大家好，

我需要更改資料點標籤位置。我的問題是我需要在表達式語句內定義新的標籤位置（請參閱變數LabelPosText ）。我知道在下面的範例中這不是必需的，但我想讓您省去處理我的長程式碼的精力，因此我向您展示一個簡化的範例。

我現在無法將變數LabelPosText的內容取得到圖形產生器表達式部分（對應的行標有//here I need help ）。我嘗試了 Eval()、Eval Expr() 等的幾種組合，但沒有任何效果。

非常感謝您的幫忙！

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

Eval( 
	Parse(
		"dt  << New Script(\!"test script\!",
		    <BR />            //defining new label positions for some data points
			Rows = dt << get rows where( :Sex == \!"F\!" );
			LabelPosText = \!"\!";
			For Each({row, idx}, Rows,
				WeightValue = Column( dt, \!"weight\!")[row];
				HeightValue = Column( dt, \!"height\!")[row];
				LabelPosText = LabelPosText || \!"{\!"|| char(row-1) ||\!", -5, 12, \!"|| char(WeightValue) ||\!", \!"|| char(HeightValue) ||\!"}\!";
				if(idx < N Items(Rows),
					LabelPosText = LabelPosText || \!", \!"
				)
			);
			
			Graph Builder(
				Size( 528, 456 ),
				Show Control Panel( 0 ),
				Variables( X( :weight ), Y( :height ) ),
				Elements( Points( X, Y, Legend( 5 ) ) ),
				SendToReport(
					Dispatch( {}, \!"Graph Builder\!", FrameBox,
						{DispatchSeg(
							Marker Seg( 1 ),
							{Label Offset( LabelPosText ), //here I need help ;)
							Set Force Labels( \!"Label by Row\!" )}
						)}
					)
				)
			)
		)"
	)

自動化和腳本編寫回覆：如何以自動方式變更圖形產生器的點數據點標籤？

你想做什麼？ LabelPosText 的計算應該在表格腳本內還是僅在圖形內？

回覆：如何以自動方式變更圖形產生器的點數據點標籤？

您好，是的，LabelPosText 應該位於表格腳本內。這一般可以嗎？還是我應該想個辦法把它取出來？

回覆：如何以自動方式變更圖形產生器的點數據點標籤？

可以在裡面計算它們。如果它們有可能在不同的表腳本運行之間發生變化，它們應該位於其中，否則我會將它們移到外面並評估腳本內的值。

一般來說，我總是會避免使用EvilParse (Eval(Parse()) ，因為調試起來是一場噩夢，而且在我看來，幾乎沒有理由使用它。這看起來確實很複雜，但我會用一些東西來解決這個問題就像這樣

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Label Offset has very annoying format to build as it isn't list with lists
// but just something with lists
table_script = Expr(
	Names Default To Here(1);
	
	Rows = Current Data Table() << get rows where(:Sex == "F");
	offsets = Expr(Label Offset());
	
	For Each({row, idx}, Rows,
		WeightValue = :weight[row];
		HeightValue = :height[row];
		l = Eval List({row - 1, -5, 12, WeightValue, HeightValue});
		Insert Into(offsets, l);
	);
	
	Eval(Substitute(
		Expr(Graph Builder(
			Size(528, 456),
			Show Control Panel(0),
			Variables(X(:weight), Y(:height)),
			Elements(Points(X, Y, Legend(5))),
			SendToReport(
				Dispatch({}, "Graph Builder", FrameBox,
					{DispatchSeg(
						Marker Seg(1),
						{_labeloffset_,
						Set Force Labels("Label by Row")}
					)}
				)
			)
		)),
		Expr(_labeloffset_), Name Expr(offsets)
	));	
);

Eval(EvalExpr(
	dt << New Script("test script", 
		Expr(Name Expr(table_script));
	);	
));

您還可以將標籤偏移移到圖形生成器之外，並在構建後將訊息發送到圖形生成器（我不確定這是否正確設置了“設置強制標籤”）

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Label Offset has very annoying format to build as it isn't list with lists
// but just something with lists
table_script = Expr(
	Names Default To Here(1);
	
	Rows = Current Data Table() << get rows where(:Sex == "F");
	offsets = Expr(Label Offset());
	
	For Each({row, idx}, Rows,
		WeightValue = :weight[row];
		HeightValue = :height[row];
		l = Eval List({row - 1, -5, 12, WeightValue, HeightValue});
		Insert Into(offsets, l);
	);
	
	gb = Graph Builder(
		Size(528, 456),
		Show Control Panel(0),
		Variables(X(:weight), Y(:height)),
		Elements(Points(X, Y, Legend(5))),
		SendToReport(
			Dispatch({}, "Graph Builder", FrameBox,
				{DispatchSeg(
					Marker Seg(1),
					{Set Force Labels("Label by Row")}
				)}
			)
		)
	);
	
	ms = Report(gb)[FrameBox(1)] << Find Seg(MarkerSeg(1));
	Eval(EvalExpr(Send(ms, Expr(Name Expr(offsets)))));
	wait(0);
);

Eval(EvalExpr(
	dt << New Script("test script", 
		Expr(Name Expr(table_script));
	);	
));

決賽桌腳本應該如下所示

Names Default To Here(1);
Rows = Current Data Table() << get rows where(:Sex == "F");
offsets = Expr(Label Offset());
For Each({row, idx}, Rows,
	WeightValue = :weight[row];
	HeightValue = :height[row];
	l = Eval List({row - 1, -5, 12, WeightValue, HeightValue});
	Insert Into(offsets, l);
);
gb = Graph Builder(
	Size(528, 456),
	Show Control Panel(0),
	Variables(X(:weight), Y(:height)),
	Elements(Points(X, Y, Legend(5))),
	SendToReport(
		Dispatch({}, "Graph Builder", FrameBox,
			{DispatchSeg(Marker Seg(1), {Set Force Labels("Label by Row")})}
		)
	)
);
ms = Report(gb)[FrameBox(1)] << Find Seg(Marker Seg(1));
Eval(Eval Expr(ms << Expr(Name Expr(offsets))));
Wait(0);

以及您從圖形生成器獲得的腳本

Graph Builder(
	Size(528, 456),
	Show Control Panel(0),
	Variables(X(:weight), Y(:height)),
	Elements(Points(X, Y, Legend(5))),
	SendToReport(
		Dispatch({}, "Graph Builder", FrameBox,
			{DispatchSeg(
				Marker Seg(1),
				{Label Offset(
					{8, -5, 12, 112, 60},
					{0, -5, 12, 95, 59},
					{9, -5, 12, 107, 61},
					{1, -5, 12, 123, 61},
					{10, -5, 12, 67, 56},
					{2, -5, 12, 74, 55},
					{3, -5, 12, 145, 66},
					{4, -5, 12, 64, 52},
					{15, -5, 12, 81, 61},
					{16, -5, 12, 91, 62},
					{17, -5, 12, 142, 65},
					{18, -5, 12, 84, 63},
					{19, -5, 12, 85, 62},
					{27, -5, 12, 92, 62},
					{28, -5, 12, 112, 64},
					{34, -5, 12, 112, 65},
					{35, -5, 12, 115, 60},
					{37, -5, 12, 116, 62}
				), Set Force Labels("Label by Row")}
			)}
		)
	)
);

回覆：如何以自動方式變更圖形產生器的點數據點標籤？

非常新，感謝您提供此資訊 - 特別是對於無標籤，它非常有用！

對於Label Offset ，我找不到很多文件 - 似乎沒有供用戶使用的功能？

有趣的：
- x /y 座標似乎只是用於雙重檢查。這可以用來簡化命令：
只需為 MALE 提供錯誤的值即可擺脫它們。

- 偏移使用什麼座標系？恆定的偏移量不會導致每個標籤的恆定偏移。

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

LabelPosOffsets = Expr(Label Offset());
For Each row(
	Insert Into(LabelPosOffsets,Eval List({row() - 1, -100,100,:weight+if( sex=="F", 0,1),:height}))
);

Eval (Eval Expr(Graph Builder(
	Size( 528, 456 ),
	Show Control Panel( 0 ),
	Variables( X( :weight ), Y( :height ), Color( :sex ) ),
	Elements( Points( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch( {}, "Graph Builder", FrameBox,
			{DispatchSeg(
				Marker Seg( 1 ),
				{ Expr(Name Expr(LabelPosOffsets) ), Set Force Labels( "Label by Row" )}
			)}
		)
	)
)));