819591_de-DE

liliconcom

Wie ändere ich die Datenpunktbeschriftungen des Graph Builders automatisch?

Hallo zusammen,

Ich muss die Beschriftungspositionen der Datenpunkte ändern. Mein Problem besteht darin, dass ich die neuen Beschriftungspositionen (siehe Variable LabelPosText ) innerhalb der Ausdrucksanweisung definieren muss. Ich weiß, dass dies im folgenden Beispiel nicht notwendig wäre, aber ich möchte Ihnen die Mühe ersparen, meinen langen Code durchzuarbeiten, also zeige ich Ihnen ein vereinfachtes Beispiel.

Ich schaffe es jetzt nicht, den Inhalt der Variable LabelPosText in den Graph Builder-Ausdrucksteil zu bekommen (die entsprechende Zeile ist mit //hier brauche ich Hilfe beschriftet;) ). Ich habe verschiedene Kombinationen von Eval(), Eval Expr() usw. ausprobiert, aber nichts hat bei mir funktioniert.

Vielen Dank für Ihre Hilfe!

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

Eval( 
	Parse(
		"dt  << New Script(\!"test script\!",
		    <BR />            //defining new label positions for some data points
			Rows = dt << get rows where( :Sex == \!"F\!" );
			LabelPosText = \!"\!";
			For Each({row, idx}, Rows,
				WeightValue = Column( dt, \!"weight\!")[row];
				HeightValue = Column( dt, \!"height\!")[row];
				LabelPosText = LabelPosText || \!"{\!"|| char(row-1) ||\!", -5, 12, \!"|| char(WeightValue) ||\!", \!"|| char(HeightValue) ||\!"}\!";
				if(idx < N Items(Rows),
					LabelPosText = LabelPosText || \!", \!"
				)
			);
			
			Graph Builder(
				Size( 528, 456 ),
				Show Control Panel( 0 ),
				Variables( X( :weight ), Y( :height ) ),
				Elements( Points( X, Y, Legend( 5 ) ) ),
				SendToReport(
					Dispatch( {}, \!"Graph Builder\!", FrameBox,
						{DispatchSeg(
							Marker Seg( 1 ),
							{Label Offset( LabelPosText ), //here I need help ;)
							Set Force Labels( \!"Label by Row\!" )}
						)}
					)
				)
			)
		)"
	)

Automatisierung und SkriptingBetreff: Wie ändere ich die Datenpunktbeschriftungen des Graph Builders automatisch?

Was versuchen Sie zu tun? Soll die Berechnung für LabelPosText im Tabellenskript oder nur im Diagramm erfolgen?

Betreff: Wie ändere ich die Datenpunktbeschriftungen des Graph Builders automatisch?

Hallo, ja, der LabelPosText soll im Tabellenskript stehen. Ist das grundsätzlich möglich? Oder muss ich mir eine Möglichkeit überlegen, ihn rauszunehmen?

Betreff: Wie ändere ich die Datenpunktbeschriftungen des Graph Builders automatisch?

Es ist möglich, sie darin zu berechnen. Wenn die Möglichkeit besteht, dass sie sich zwischen verschiedenen Tabellenskriptläufen ändern, sollten sie darin enthalten sein, andernfalls würde ich sie nach außen verschieben und den Wert innerhalb des Skripts auswerten.

Im Allgemeinen würde ich die Verwendung von EvilParse (Eval(Parse()) immer vermeiden, da das Debuggen ein Albtraum ist und es meiner Meinung nach fast nie einen Grund gibt, es zu verwenden. Das sieht zwar kompliziert aus, aber ich würde es mit etwas wie diesem angehen

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Label Offset has very annoying format to build as it isn't list with lists
// but just something with lists
table_script = Expr(
	Names Default To Here(1);
	
	Rows = Current Data Table() << get rows where(:Sex == "F");
	offsets = Expr(Label Offset());
	
	For Each({row, idx}, Rows,
		WeightValue = :weight[row];
		HeightValue = :height[row];
		l = Eval List({row - 1, -5, 12, WeightValue, HeightValue});
		Insert Into(offsets, l);
	);
	
	Eval(Substitute(
		Expr(Graph Builder(
			Size(528, 456),
			Show Control Panel(0),
			Variables(X(:weight), Y(:height)),
			Elements(Points(X, Y, Legend(5))),
			SendToReport(
				Dispatch({}, "Graph Builder", FrameBox,
					{DispatchSeg(
						Marker Seg(1),
						{_labeloffset_,
						Set Force Labels("Label by Row")}
					)}
				)
			)
		)),
		Expr(_labeloffset_), Name Expr(offsets)
	));	
);

Eval(EvalExpr(
	dt << New Script("test script", 
		Expr(Name Expr(table_script));
	);	
));

Sie können den Label-Offset auch außerhalb des Graph Builders verschieben und die Nachricht an den Graph Builder senden, nachdem dieser erstellt wurde (ich bin nicht sicher, ob dadurch „Set Force Labels“ richtig eingestellt wird).

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Label Offset has very annoying format to build as it isn't list with lists
// but just something with lists
table_script = Expr(
	Names Default To Here(1);
	
	Rows = Current Data Table() << get rows where(:Sex == "F");
	offsets = Expr(Label Offset());
	
	For Each({row, idx}, Rows,
		WeightValue = :weight[row];
		HeightValue = :height[row];
		l = Eval List({row - 1, -5, 12, WeightValue, HeightValue});
		Insert Into(offsets, l);
	);
	
	gb = Graph Builder(
		Size(528, 456),
		Show Control Panel(0),
		Variables(X(:weight), Y(:height)),
		Elements(Points(X, Y, Legend(5))),
		SendToReport(
			Dispatch({}, "Graph Builder", FrameBox,
				{DispatchSeg(
					Marker Seg(1),
					{Set Force Labels("Label by Row")}
				)}
			)
		)
	);
	
	ms = Report(gb)[FrameBox(1)] << Find Seg(MarkerSeg(1));
	Eval(EvalExpr(Send(ms, Expr(Name Expr(offsets)))));
	wait(0);
);

Eval(EvalExpr(
	dt << New Script("test script", 
		Expr(Name Expr(table_script));
	);	
));

Das endgültige Tabellenskript sollte folgendermaßen aussehen

Names Default To Here(1);
Rows = Current Data Table() << get rows where(:Sex == "F");
offsets = Expr(Label Offset());
For Each({row, idx}, Rows,
	WeightValue = :weight[row];
	HeightValue = :height[row];
	l = Eval List({row - 1, -5, 12, WeightValue, HeightValue});
	Insert Into(offsets, l);
);
gb = Graph Builder(
	Size(528, 456),
	Show Control Panel(0),
	Variables(X(:weight), Y(:height)),
	Elements(Points(X, Y, Legend(5))),
	SendToReport(
		Dispatch({}, "Graph Builder", FrameBox,
			{DispatchSeg(Marker Seg(1), {Set Force Labels("Label by Row")})}
		)
	)
);
ms = Report(gb)[FrameBox(1)] << Find Seg(Marker Seg(1));
Eval(Eval Expr(ms << Expr(Name Expr(offsets))));
Wait(0);

und das Skript, das Sie vom Graph Builder erhalten

Graph Builder(
	Size(528, 456),
	Show Control Panel(0),
	Variables(X(:weight), Y(:height)),
	Elements(Points(X, Y, Legend(5))),
	SendToReport(
		Dispatch({}, "Graph Builder", FrameBox,
			{DispatchSeg(
				Marker Seg(1),
				{Label Offset(
					{8, -5, 12, 112, 60},
					{0, -5, 12, 95, 59},
					{9, -5, 12, 107, 61},
					{1, -5, 12, 123, 61},
					{10, -5, 12, 67, 56},
					{2, -5, 12, 74, 55},
					{3, -5, 12, 145, 66},
					{4, -5, 12, 64, 52},
					{15, -5, 12, 81, 61},
					{16, -5, 12, 91, 62},
					{17, -5, 12, 142, 65},
					{18, -5, 12, 84, 63},
					{19, -5, 12, 85, 62},
					{27, -5, 12, 92, 62},
					{28, -5, 12, 112, 64},
					{34, -5, 12, 112, 65},
					{35, -5, 12, 115, 60},
					{37, -5, 12, 116, 62}
				), Set Force Labels("Label by Row")}
			)}
		)
	)
);

Betreff: Wie ändere ich die Datenpunktbeschriftungen des Graph Builders automatisch?

ganz neu, danke für die Info – besonders bei No Labels kann das wirklich nützlich sein!!

Zum Label Offset konnte ich nicht viel Dokumentation finden - anscheinend gibt es keine Funktionalität, die für die Verwendung durch Benutzer vorgesehen ist?

Interessant:
- die x/y-Koordinaten scheinen nur zur Kontrolle zu dienen. Dies kann zur Vereinfachung des Befehls verwendet werden:
Geben Sie einfach falsche Werte für MALE ein, um sie loszuwerden.

- Welches Koordinatensystem wird für die Offsets verwendet? Ein konstanter Offset führt nicht zu einer konstanten Verschiebung für jedes Etikett.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

LabelPosOffsets = Expr(Label Offset());
For Each row(
	Insert Into(LabelPosOffsets,Eval List({row() - 1, -100,100,:weight+if( sex=="F", 0,1),:height}))
);

Eval (Eval Expr(Graph Builder(
	Size( 528, 456 ),
	Show Control Panel( 0 ),
	Variables( X( :weight ), Y( :height ), Color( :sex ) ),
	Elements( Points( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch( {}, "Graph Builder", FrameBox,
			{DispatchSeg(
				Marker Seg( 1 ),
				{ Expr(Name Expr(LabelPosOffsets) ), Set Force Labels( "Label by Row" )}
			)}
		)
	)
)));