817109_de-DE

liliconcom

JSL: Layout ('In Zeilen anordnen') geht beim Journalisieren per Scripting verloren

Liebe JMP-Community,

Beim Skripting bin ich auf das folgende Problem gestoßen (Beispiel beigefügt):

• Verwende ich nun folgendes Script, so erfolgt mit „jrn1 << Journal;“ die Übernahme ins Journal, allerdings ohne „Group Options( Layout( 'Anordnen in Zeilen', N Across( 2 ) ) ),“.
• Wenn ich die manuelle Option verwende (Bearbeiten >> Journal oder Strg + J), bleibt das zweispaltige Layout erhalten .

Gibt es eine andere „Journal-Syntax“, die das Layout beibehält, die ich nicht kenne, oder handelt es sich hier um einen Fehler?

Habe ich eine andere Möglichkeit als das Journal-Layout über „H List Box ()“ zu formatieren?

Am besten,

Steffi

kin1 = current data table();<BR /><BR />jrn1 = kin1 << Bivariate(
	Y( :response ),
	X( :time),
	Size(400, 325),
	Fit Each Value( {Line Color( {212, 73, 88} )} ),
	By( :ID ),
	Group Options( Layout( "Arrange in Rows", N Across( 2 ) ) ),
);
Current Report()[OutlineBox(1)] << setTitle("Kinetics"); //Adjust the header retroperspectively 
jrn1 << Journal;

jr

Automatisierung und SkriptingBetreff: JSL: Layout ('In Zeilen anordnen') geht beim Journalisieren per Scripting verloren

jrn1 enthält mehrere Referenzen der bivariaten Plattform, Sie möchten nur eine davon verwenden (oder besser noch eine höhere Ebene). Sie können Ihr Skript beispielsweise wie folgt ändern

Names Default To Here(1);

kin1 = Current Data Table();
jrn1 = kin1 << Bivariate(
	Y(:response),
	X(:time),
	Size(400, 325),
	Fit Each Value({Line Color({212, 73, 88})}),
	By(:ID),
	Group Options(Layout("Arrange in Rows", N Across(2))),

);
Current Report()[Outline Box(1)] << setTitle("Kinetics"); //Adjust the header retroperspectively 
(jrn1[1] << Top Parent)<< Journal;

Betreff: JSL: Layout ('In Zeilen anordnen') geht beim Journalisieren per Scripting verloren

„Journal speichern überschreibt die Diagramme der Fit Group“ ist ein ähnlicher Beitrag wie dieser, aber wenn ich mich recht erinnere, gibt es eine noch bessere Methode, ABER sie ist äußerst schwer zu finden oder sich daran zu erinnern ... wenn ich sie finde, werde ich diese Antwort bearbeiten.

Edit: Endlich habe ich es gefunden. Es ist (meiner Meinung nach) extrem schwierig zu finden, aber hier ist es: Verwenden Sie Return Group(1) bei Group Options (Ich habe dies zu meiner persönlichen Tipps&Tricks-Datei hinzugefügt, sodass ich es hoffentlich leichter finde, wenn jemand das nächste Mal ein ähnliches Problem hat).

Names Default To Here(1);

kin1 = Current Data Table();
jrn1 = kin1 << Bivariate(
	Y(:response),
	X(:time),
	Size(400, 325),
	Fit Each Value({Line Color({212, 73, 88})}),
	By(:ID),
	Group Options(Layout("Arrange in Rows", N Across(2)), Return Group(1)),

);
Current Report()[Outline Box(1)] << setTitle("Kinetics"); //Adjust the header retroperspectively 
jrn1 << Journal;

Names Default To Here(1);
Open Help(
	"Scripting Index",
	Search(
		Term("Group Options"),
		Match(
				{"Contains Terms",
				"Match All Terms",
				"Ignore Case"}
		)
	),
	IndexContext(
		Category("All Categories"),
		Object("Search results"),
		Method("Group Options")
	)
);